pcgen/PKGBUILD

   1 # Maintainer: Anton Bazhenov <anton.bazhenov at gmail>
   2 # Contributor: Jaroslav Lichtblau <tu@dragonlord.cz>
   3 # Contributor: Michael Liptrap <xenobrain@gmail.com
   4
   5 pkgname=pcgen
   6 pkgver=5.16.4
   7 pkgrel=1
   8 pkgdesc="An open source RPG character generator and maintenance program"
   9 arch=('any')
  10 url="http://pcgen.sourceforge.net/"
  11 license=('LGPL' 'custom')
  12 depends=('java-runtime')
  13 source=("http://downloads.sourceforge.net/${pkgname}/${pkgname}${pkgver//./}_full.zip"
  14         "${pkgname}.sh"
  15         "${pkgname}.png"
  16         "${pkgname}.desktop")
  17 md5sums=('9c0c0694bb5d81743261dfa31b1a9bc5'
  18          '24ac58619b0f435ea032aef2c0cdee56'
  19          '74f84ab162a7c9237ae3395300659dab'
  20          '811ec47d177116db1d46bb1a24912641')
  21
  22 package() {
  23   cd "${srcdir}/${pkgname}${pkgver//./}"
  24
  25 # Install program files
  26   rm -f *.bat *.exe
  27   mkdir -p "${pkgdir}/opt/${pkgname}"
  28   cp -rf * "${pkgdir}/opt/${pkgname}"
  29
  30 # Set file permissions
  31   find "${pkgdir}/opt/${pkgname}" -type d -exec chmod 755 '{}' \;
  32   find "${pkgdir}/opt/${pkgname}" -type f -exec chmod 644 '{}' \;
  33   chmod 755 "${pkgdir}/opt/${pkgname}/"*.sh
  34   chmod 666 "${pkgdir}/opt/${pkgname}/"*.{ini,properties}
  35
  36 # Install launcher
  37   install -Dm755 "../${pkgname}.sh" "${pkgdir}/usr/bin/${pkgname}"
  38
  39 # Install icon
  40   install -Dm644 "../${pkgname}.png" "${pkgdir}/usr/share/pixmaps/${pkgname}.png"
  41
  42 # Install .desktop file
  43   install -Dm644 "${srcdir}/${pkgname}.desktop" \
  44     "${pkgdir}/usr/share/applications/${pkgname}.desktop"
  45
  46 # Install licenses
  47   cd docs/acknowledgments
  48   mkdir -p "${pkgdir}/usr/share/licenses/${pkgname}"
  49   install -Dm644 {ogllicense,publishersandsources,skinlflicense}.html \
  50     "${pkgdir}/usr/share/licenses/${pkgname}"
  51 }