xf86-input-synaptics-clickpad/PKGBUILD

   1 # Maintainer:  Jesse Jaara       <gmail.com: jesse.jaara
   2 # Contributor: Matt Monaco       <0x01b.net: dgbaley27>
   3 # Contributor: Jan de Groot      <archlinux.org: jgc>
   4 # Contributor: Tobias Powalowski <archlinux.org: tpowa>
   5 # Contributor: Thomas Bächler    <archlinux.org: thomas>
   6 # Contributor: Alexander Baldeck <archlinux.org: alexander>
   7
   8 _realname=xf86-input-synaptics
   9 _suseurl='FILE::https://api.opensuse.org/public/source/openSUSE:Factory/xorg-x11-driver-input/FILE?rev=67f06298aa561ce2152cad26f92cf4ae&'
  10 pkgname=$_realname-clickpad
  11 pkgver=1.5.0
  12 pkgrel=3
  13 pkgdesc="Synaptics driver for notebook touchpads (with clickpad and led support)"
  14 arch=('i686' 'x86_64')
  15 license=('custom')
  16 url="http://xorg.freedesktop.org/"
  17 depends=('libxtst')
  18 makedepends=('xorg-server-devel>=1.10.99.902' 'libxi' 'libx11')
  19 optdepends=('synaptics-led')
  20 conflicts=('xorg-server<1.10.99.902')
  21 replaces=('synaptics')
  22 provides=('synaptics' $_realname)
  23 conflicts=('synaptics' $_realname)
  24 groups=('xorg-drivers' 'xorg')
  25 options=(!libtool)
  26 backup=('etc/X11/xorg.conf.d/10-synaptics.conf')
  27 source=(http://xorg.freedesktop.org/releases/individual/driver/${_realname}-${pkgver}.tar.bz2
  28         ${_suseurl//FILE/xf86-input-synaptics-wait.diff}
  29         ${_suseurl//FILE/xf86-input-synaptics-settings.diff}
  30         ${_suseurl//FILE/xf86-input-synaptics-add-clickpad-support.diff}
  31         ${_suseurl//FILE/xf86-input-synaptics-clickpad-doc-update.diff}
  32         ${_suseurl//FILE/xf86-input-synaptics-add-led-support.diff}
  33         ${_suseurl//FILE/xf86-input-synaptics-led-double-tap.diff}
  34         ${_suseurl//FILE/xf86-input-synaptics-fix-clickpad-capabilities.diff}
  35         ${_suseurl//FILE/xf86-input-synaptics-clickpad-threshold.diff}
  36         ${_suseurl//FILE/xf86-input-synaptics-move-threshold.diff}
  37         ${_suseurl//FILE/xf86-input-synaptics-filter-bogus-coord.diff}
  38         10-synaptics.conf)
  39
  40 build() {
  41   cd "${srcdir}/${_realname}-${pkgver}"
  42
  43   for p in "${source[@]}"; do
  44     p="${p%%::*}"
  45     [[ "$p" =~ ^.+\.diff$ ]] || continue
  46     msg2 "Applying patch: $p"
  47     patch -p1 -i "../$p"
  48   done
  49
  50   ./configure --prefix=/usr
  51   make
  52 }
  53
  54 package() {
  55   cd "${srcdir}/${_realname}-${pkgver}"
  56
  57   make DESTDIR="${pkgdir}" install
  58
  59   install -m755 -d "${pkgdir}/etc/X11/xorg.conf.d"
  60   install -m644 "${srcdir}/10-synaptics.conf" "${pkgdir}/etc/X11/xorg.conf.d/"
  61   install -m755 -d "${pkgdir}/usr/share/licenses/${pkgname}"
  62   install -m644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/"
  63
  64   rm -rf "${pkgdir}/usr/share/X11"
  65 }
  66
  67 md5sums=('41ee749ecbfef98f7fba708cb2afae87'
  68          '3be2279df8d5c37b631b5dd16ecdf90e'
  69          'a33569b9953881d35b58fc233a87a145'
  70          '19ba0a59d3946933f038ff656549c6c3'
  71          'b0b62d0c7b2e0f0b0c25e37a8e45e332'
  72          '549f9e6b6837c25dfa742e5dd0ae3988'
  73          '6e8189aed09097f28046e66682a62fd8'
  74          'e75ae28038ce2cb76175fb178a261561'
  75          '33aada7d6f9f427b2df0f8cf281b1a70'
  76          '097d0776943d61cfa5373b5c87dc717b'
  77          'e25a610a879faa4138c46524be2d49cc'
  78          '3b81a81b958dfe3cac3cdef7ee85f1ce')