thunderbird-beta/PKGBUILD

   1 # Maintainer: Det <nimetonmaili at gmail a-dot com>
   2 # Based on [extra]'s thunderbird
   3
   4 # NOTE: Here you choose whether you want a PGO (Profile-Guided Optimization) build. See: http://en.wikipedia.org/wiki/Profile-guided_optimization
   5 _pgo="0"  # "1" to enable
   6
   7 pkgname=thunderbird-beta
   8 pkgver=10.0b4
   9 pkgrel=1
  10 pkgdesc="Standalone Mail/News reader - Bleeding edge version with optional PGO"
  11 arch=('i686' 'x86_64')
  12 license=('MPL' 'GPL')
  13 url="http://www.mozilla.org/thunderbird"
  14 depends=('alsa-lib' 'cairo' 'dbus-glib' 'desktop-file-utils' 'fontconfig' 'freetype2' 'gtk2' 'hicolor-icon-theme' 'hunspell' 'libevent' 'libjpeg' 'libmng' 'libpng' 'libvpx' 'libxt' 'mozilla-common' 'nspr' 'nss' 'shared-mime-info' 'sqlite3' 'startup-notification')
  15 makedepends=('libgnomeui' 'libnotify' 'mesa' 'python2' 'unzip' 'yasm' 'zip')
  16 optdepends=('libcanberra: for sound support')
  17 provides=("thunderbird=$pkgver")
  18 install=$pkgname.install
  19 # In case releases.mozilla.org is not responding or the file(s) aren't yet uploaded there:
  20 # source=(http://releases.mozilla.org/pub/mozilla.org/thunderbird/releases/$pkgver/source/thunderbird-$pkgver.source.tar.bz2
  21 source=(ftp://ftp.mozilla.org/pub/mozilla.org/thunderbird/releases/$pkgver/source/thunderbird-$pkgver.source.tar.bz2
  22         mozconfig
  23         $pkgname.desktop)
  24 md5sums=(`curl -s ${source/so*}/MD5SUMS | grep source | cut -d " " -f1`
  25          'ca98c2bf1017b33e19dae22fdcef2e73'
  26          'f8a9b91202e8c85ad7b8f23fb82a4d7b')
  27
  28 build() {
  29   cd comm-*
  30   cp ../mozconfig .mozconfig
  31
  32   export LDFLAGS="$LDFLAGS -Wl,-rpath,/opt/$pkgname"
  33   export PYTHON="/usr/bin/python2"
  34
  35   if [[ "$_pgo" = "1" ]]; then
  36      sed -i '/^NO_PROFILE_GUIDED_OPTIMIZE = 1$/d' mozilla/memory/jemalloc/Makefile.in
  37      echo 'LDFLAGS += -lX11 -lXrender' >> mozilla/layout/build/Makefile.in
  38      LD_PRELOAD="" /usr/bin/Xvfb -nolisten tcp -extension GLX -screen 0 1280x1024x24 :99 &
  39      LD_PRELOAD="" DISPLAY=:99 make -j1 -f client.mk profiledbuild MOZ_MAKE_FLAGS="$MAKEFLAGS"
  40   else
  41      make -j1 -f client.mk build MOZ_MAKE_FLAGS="$MAKEFLAGS"
  42   fi
  43 }
  44
  45 package() {
  46   cd comm-*/obj-*
  47   make -j1 package MOZ_MAKE_FLAGS="$MAKEFLAGS"
  48
  49   cd mozilla/dist/
  50   bsdtar -x -f thunderbird-*.tar.bz2
  51   mkdir -p "$pkgdir"/{opt,usr/bin}
  52   cp -r thunderbird/ "$pkgdir/opt/$pkgname/"
  53   ln -sf /opt/$pkgname/thunderbird "$pkgdir/usr/bin/$pkgname"
  54
  55   for i in 16x16 22x22 24x24 32x32 48x48 256x256; do
  56       install -Dm644 "$srcdir"/comm-*/other-licenses/branding/thunderbird/mailicon${i/x*/}.png "$pkgdir/usr/share/icons/hicolor/$i/apps/$pkgname.png"
  57   done
  58
  59   install -Dm644 "$srcdir/$pkgname.desktop" "$pkgdir/usr/share/applications/$pkgname.desktop"
  60
  61   rm -rf "$pkgdir/opt/$pkgname/dictionaries"
  62   ln -sf /usr/share/hunspell "$pkgdir/opt/$pkgname/dictionaries"
  63
  64   # A fix for the (redundant) "Package contains reference to $srcdir" warning
  65   sed -i 1d "$pkgdir/opt/$pkgname/defaults/pref/channel-prefs.js"
  66 }