ratpoison-git/PKGBUILD

   1 pkgname=ratpoison-git
   2 pkgver=20111226
   3 pkgrel=1
   4 pkgdesc="Ratpoison from git"
   5 arch=('i686' 'x86_64')
   6 url="http://www.nongnu.org/ratpoison/"
   7 license=('GPL')
   8 depends=('libxinerama' 'readline' 'bash' 'perl' 'libxtst' 'libxft')
   9 makedepends=('git')
  10 provides=('ratpoison')
  11 replaces=('ratpoison')
  12 conflicts=('ratpoison')
  13 source=()
  14 md5sums=()
  15
  16 _gitroot="git://git.savannah.nongnu.org/ratpoison.git"
  17 _gitname="ratpoison"
  18
  19 build() {
  20
  21   cd "$srcdir"
  22   if [[ -d $_gitname ]]
  23   then
  24     msg "Git checkout:  Updating existing tree"
  25     (cd "$_gitname"; git pull origin)
  26     msg "Git checkout:  Tree has been updated"
  27   else
  28     msg "Git checkout:  Retrieving sources"
  29     git clone "$_gitroot"
  30   fi
  31   msg "Checkout completed"
  32
  33   rm -rf "${_gitname}-build"
  34   git clone "$_gitname" "$_gitname-build"
  35   cd "$_gitname-build"
  36
  37   ./autogen.sh
  38   ./configure --prefix=/usr
  39   make
  40
  41   cd contrib
  42   ./genrpbindings
  43 }
  44
  45 package() {
  46   cd "$srcdir/$_gitname-build"
  47
  48   install -d "$pkgdir/usr/share/ratpoison/bindings"
  49
  50   make DESTDIR="$pkgdir" install
  51   install -m 644 contrib/{Ratpoison.pm,ratpoison-cmd.el,ratpoison.rb,ratpoison.lisp,ratpoison.py} \
  52             "$pkgdir/usr/share/ratpoison/bindings"
  53
  54   chmod a+x "$pkgdir/usr/share/ratpoison/"{allwindows.sh,clickframe.pl,rpshowall.sh,rpws,split.sh}
  55   rm -rf "$pkgdir/usr/share/info/dir"
  56 }