gaphor/PKGBUILD

   1 # Maintainer : SpepS <dreamspepser at yahoo dot it>
   2 # Contributor: Cilyan Olowen <gaknar@gmail.com>
   3 # Contributor: G_Syme
   4 # Contributor: encelo
   5
   6 pkgname=gaphor
   7 pkgver=0.17.0
   8 pkgrel=1
   9 pkgdesc="An easy to use modeling environment for UML design"
  10 arch=('any')
  11 url="http://gaphor.sourceforge.net"
  12 license=('GPL')
  13 depends=('gaphas' 'python2-zope-component' 'python2-distribute' 'etk-docking')
  14 makedepends=('python2-nose' 'python-sphinx')
  15 install="$pkgname.install"
  16 source=("http://pypi.python.org/packages/source/g/$pkgname/$pkgname-$pkgver.tar.gz")
  17 md5sums=('d29e686d6d1743775c4ba43b652196fe')
  18
  19 build() {
  20   cd "$srcdir/$pkgname-$pkgver"
  21
  22   # zope-component fix
  23   sed -i "/self/s/\.\(registry\)/\.global\1/" \
  24     gaphor/services/componentregistry.py
  25
  26   python2 setup.py build
  27 }
  28
  29 package() {
  30   cd "$srcdir/$pkgname-$pkgver"
  31
  32   python2 setup.py install --root="$pkgdir/"
  33
  34   # desktop
  35   install -Dm644 $pkgname.desktop \
  36     "$pkgdir/usr/share/applications/$pkgname.desktop"
  37
  38   # icon
  39   install -Dm644 iconsrc/$pkgname.svg \
  40     "$pkgdir/usr/share/pixmaps/$pkgname.svg"
  41
  42   # python2 fix
  43   sed -i "s/\(#\!.*python\).*/\12/" \
  44     `grep -rl "#\!.*python" "$pkgdir"`
  45 }