file-roller2-nn/PKGBUILD

   1 # Maintainer: Nikita Nikishin <nnikishi@emich.edu>
   2
   3 pkgname=file-roller2-nn
   4 pkgver=2.32.2
   5 pkgrel=1
   6 provides=('file-roller')
   7 conflicts=('file-roller' 'nautilus')
   8 pkgdesc="Archive manipulator for GNOME without nautilus dependency. (no nautilus)"
   9 arch=('i686' 'x86_64')
  10 license=('GPL')
  11 depends=('desktop-file-utils' 'gconf>=2.32.0' 'hicolor-icon-theme')
  12 makedepends=('gnome-doc-utils' 'intltool')
  13 optdepends=('unrar: the RAR uncompression program'
  14             'zip: creates PKZIP-compatible .zip files'
  15             'unzip: unpacks .zip archives'
  16             'p7zip: 7zip compression utility'
  17             'xz: managing LZMA and XZ compressed files'
  18             'arj: ARJ archiver'
  19             'unace: extraction tool for the proprietary ace archive format')
  20 options=('!libtool' '!emptydirs')
  21 install=file-roller.install
  22 url="http://www.gnome.org"
  23 source=(http://ftp.gnome.org/pub/gnome/sources/file-roller/${pkgver%.*}/file-roller-${pkgver}.tar.bz2
  24         http://git.gnome.org/browse/nautilus/plain/libnautilus-private/org.gnome.nautilus.gschema.xml.in)
  25
  26
  27 build() {
  28   cd "${srcdir}/file-roller-${pkgver}"
  29   ./configure --prefix=/usr --sysconfdir=/etc \
  30       --libexecdir=/usr/lib/file-roller \
  31       --localstatedir=/var --disable-static \
  32       --disable-scrollkeeper \
  33       --disable-nautilus-actions
  34       # Configure file-roller without nautilus-actions
  35   make
  36 }
  37
  38 package() {
  39     cd "${srcdir}/file-roller-${pkgver}"
  40     make DESTDIR="${pkgdir}" install
  41
  42     # Hack to run file-roller without nautilus
  43     sed -i 's/_summary/summary/g;s/_description/description/g;' ${srcdir}/org.gnome.nautilus.gschema.xml.in
  44     install -Dm755 ${srcdir}/org.gnome.nautilus.gschema.xml.in ${pkgdir}/usr/share/glib-2.0/schemas/org.gnome.nautilus.gschema.xml
  45 }
  46
  47 md5sums=('2ec596e237c2f3af1d7d3f5b9c12884f'
  48          '6feef53e9782d21b9f63472d36490ea7')