gloobus-preview-bzr/PKGBUILD

   1 # Maintainer: Alessio Sergi <asergi at archlinux dot us>
   2
   3 pkgname=gloobus-preview-bzr
   4 _pkgname=gloobus-preview
   5 pkgver=282
   6 pkgrel=1
   7 pkgdesc="A quicklook for GNU/Linux"
   8 arch=('i686' 'x86_64')
   9 url="https://launchpad.net/gloobus-preview"
  10 license=('GPL3')
  11 depends=('desktop-file-utils' 'djvulibre' 'gstreamer0.10-base' \
  12          'gtksourceview3' 'libspectre' 'poppler-glib' 'python2-gconf' \
  13          'taglib')
  14 makedepends=('boost' 'bzr' 'intltool')
  15 optdepends=('gdk-pixbuf-psd: PSD images support'
  16             'gdk-pixbuf-xcf: XCF images support'
  17             'gloobus-sushi-bzr: nautilus 3.x support'
  18             'libicns: ICNS files support'
  19             'marlin-bzr: file manager integration support'
  20             'nautilus-actions: nautilus menu integration'
  21             'nautilus-elementary-bzr: file manager integration support'
  22             'unoconv: LibO files support')
  23 provides=(${_pkgname})
  24 conflicts=(${_pkgname})
  25 options=('!libtool')
  26 install=${pkgname}.install
  27
  28 _bzrtrunk="lp:${_pkgname}"
  29 _bzrmod="${_pkgname}"
  30
  31 build() {
  32   cd "${srcdir}"
  33
  34   msg "Connecting to the server...."
  35
  36   if [ -d ${_bzrmod} ]; then
  37     bzr up ${_bzrmod}
  38     msg "The local files are updated."
  39   else
  40     bzr co ${_bzrtrunk} ${_bzrmod}
  41   fi
  42
  43   msg "BZR checkout done or server timeout"
  44   msg "Starting make..."
  45
  46   rm -rf "${_bzrmod}-build"
  47   cp -r "${_bzrmod}" "${_bzrmod}-build"
  48   cd "${_bzrmod}-build"
  49
  50   # no psd and xcf loaders
  51   sed -i '/loaders/d' src/Makefile.am
  52   sed -i '/src\/loaders/d' configure.ac
  53
  54   # python2 fix
  55   sed -i 's_python_&2_' "src/${_pkgname}-configuration"
  56
  57   ./autogen.sh
  58   ./configure --prefix=/usr
  59   make
  60 }
  61
  62 package() {
  63   cd "${srcdir}/${_bzrmod}-build"
  64
  65   make DESTDIR="${pkgdir}" install
  66 }
  67
  68 # vim:set ts=2 sw=2 et: