schismtracker/PKGBUILD

   1 # Maintainer : SpepS <dreamspepser at yahoo dot it>
   2 # Contributor: Vesa Kaihlavirta <vegai@iki.fi>
   3 # Contributor: Jacek Poplawski <jacekpoplawski@gmail.com>
   4
   5 pkgname=schismtracker
   6 pkgver=20110101
   7 pkgrel=1
   8 pkgdesc="A free reimplementation of Impulse Tracker"
   9 arch=('i686' 'x86_64')
  10 url="http://rigelseven.com/schism/"
  11 license=('GPL')
  12 depends=('libxv' 'sdl' 'hicolor-icon-theme')
  13 makedepends=('mesa')
  14 install="$pkgname.install"
  15 source=("http://schismtracker.org/dl/${pkgname}-${pkgver}.tar.bz2")
  16 md5sums=('86b588402407fbccbfd7d7def422aa51')
  17
  18 build() {
  19   cd "${srcdir}/${pkgname}-${pkgver}"
  20
  21   ./configure --prefix=/usr
  22   make
  23 }
  24
  25 package() {
  26   cd "${srcdir}/${pkgname}-${pkgver}"
  27
  28   make DESTDIR="${pkgdir}" install
  29
  30   # Install icons
  31   for i in 16 22 24 32 36 48 64 72 96 128 192; do
  32     install -Dm 644 icons/schism-icon-${i}.png \
  33       "${pkgdir}/usr/share/icons/hicolor/${i}x${i}/apps/${pkgname}.png"
  34     install -Dm 644 icons/schism-itf-icon-${i}.png \
  35       "${pkgdir}/usr/share/icons/hicolor/${i}x${i}/apps/${pkgname}-itf.png"
  36   done;
  37   install -Dm 644 icons/schism-icon.svg \
  38     "${pkgdir}/usr/share/icons/hicolor/scalable/${pkgname}.svg"
  39   install -Dm 644 icons/schism-itf-icon.svg \
  40     "${pkgdir}/usr/share/icons/hicolor/scalable/${pkgname}-itf.svg"
  41
  42   # Install docs
  43   install -d "${pkgdir}/usr/share/doc/${pkgname}"
  44   install -Dm 644 helptext/* "${pkgdir}/usr/share/doc/${pkgname}"
  45
  46   # Install desktop files
  47   sed -i "s|\(schism\)\(-itf\)*.*128|\1tracker\2|" sys/fd.org/*.desktop
  48   install -Dm 644 sys/fd.org/schism.desktop \
  49     "${pkgdir}/usr/share/applications/${pkgname}.desktop"
  50   install -Dm 644 sys/fd.org/itf.desktop \
  51     "${pkgdir}/usr/share/applications/${pkgname}-itf.desktop"
  52 }