thunderbird-branded/PKGBUILD

   1 # Contributor: WAntilles <wantilles@adslgr.com>
   2
   3 pkgname=thunderbird-branded
   4 realname=thunderbird
   5 lightningID="{e2fda1a4-762b-4020-b5ad-a41df1933103}"
   6 pkgver=3.1.11
   7 thundermajorver=3.1
   8 pkgrel=1
   9 pkgdesc="Standalone Mail/News reader"
  10 arch=('i686' 'x86_64')
  11 license=('MPL' 'GPL')
  12 url="http://www.mozilla.org/projects/thunderbird"
  13 replaces=('mozilla-thunderbird')
  14 conflicts=('mozilla-thunderbird' 'thunderbird' 'thunderbird3' 'thunderbird-rc' 'thunderbird-beta')
  15 provides=("mozilla-thunderbird=${pkgver}" "thunderbird=${pkgver}")
  16 depends=('gtk2>=2.22.1' 'gcc-libs>=4.5' 'mozilla-common' 'nss>=3.12.8' 'libxt'
  17          'shared-mime-info' 'alsa-lib>=1.0.23' 'dbus-glib>=0.92' 'hunspell'
  18          'sqlite3>=3.7.4' 'libcanberra' 'desktop-file-utils')
  19 makedepends=('zip' 'pkg-config' 'libgnomeui' 'python2' 'libidl2' 'wireless_tools'
  20              'autoconf2.13' 'imagemagick>=6.6.4.10')
  21 install=thunderbird.install
  22 source=(ftp://ftp.mozilla.org/pub/mozilla.org/thunderbird/releases/${pkgver}/source/thunderbird-${pkgver}.source.tar.bz2
  23         mozconfig
  24         thunderbird.desktop
  25         thunderbird-3.0-lang.patch
  26         thunderbird-appversion.patch
  27         thunderbird-shared-error.patch
  28         xulrunner-png14.patch
  29         python2.7.patch
  30         gcc46.patch)
  31 md5sums=('25833b3f90925d96285630d22c85cd5c'
  32          'f38264fcf3853935a9786b82b8905851'
  33          'af3e5b344d2edf1c7d61bb0a5a96de9a'
  34          '25b6fe16ac24cd5c852213e5c1adb272'
  35          '48ffcdb877a69d383b7d354e330f7658'
  36          '3dca714ee8054634e6dfdb059464dc42'
  37          '989b15f6bc9e2e9233fe4c6b23f412b1'
  38          '78a4d0c920cbb8ec6a9a36974cd775ef'
  39          'a2bced1791fb8eca978d31b129f92a28')
  40
  41 build() {
  42   cd "${srcdir}/comm-1.9.2"
  43   patch -Np1 -i "${srcdir}/thunderbird-3.0-lang.patch"
  44   patch -Np1 -i "${srcdir}/thunderbird-appversion.patch"
  45   patch -Np1 -i "${srcdir}/thunderbird-shared-error.patch"
  46   patch -Np1 -i "${srcdir}/gcc46.patch"
  47   patch -Np0 -i "${srcdir}/xulrunner-png14.patch"
  48   patch -Np0 -i "${srcdir}/python2.7.patch"
  49
  50   cp "${srcdir}/mozconfig" .mozconfig
  51
  52   echo "ac_cv_visibility_pragma=no" >> .mozconfig
  53
  54   export MOZ_PROJECT=mail
  55   unset CXXFLAGS
  56   unset CFLAGS
  57
  58   export CXXFLAGS="-fpermissive"
  59   export LDFLAGS="-Wl,-rpath,/usr/lib/thunderbird-3.1"
  60
  61   make -f client.mk build MOZ_MAKE_FLAGS="${MAKEFLAGS}"
  62 }
  63
  64 package() {
  65   cd "${srcdir}/comm-1.9.2"
  66
  67   make -j1 DESTDIR="${pkgdir}" install
  68
  69   #Remove included dictionaries, add symlink to system myspell path.
  70   #Note: this will cause file conflicts when users have installed dictionaries in the old location
  71   rm -rf "${pkgdir}/usr/lib/$realname-$thundermajorver/dictionaries"
  72   ln -sf /usr/share/myspell/dicts "${pkgdir}/usr/lib/$realname-$thundermajorver/dictionaries"
  73
  74   rm -rf "${pkgdir}/usr/bin/defaults"
  75
  76   install -m755 -d "${pkgdir}/usr/share/applications"
  77   install -m755 -d "${pkgdir}/usr/share/pixmaps"
  78
  79   install -m644 "${srcdir}/comm-1.9.2/other-licenses/branding/thunderbird/mailicon48.png" \
  80         "${pkgdir}/usr/share/pixmaps/thunderbird.png"
  81
  82   install -m644 "${srcdir}/thunderbird.desktop" \
  83       "${pkgdir}/usr/share/applications/"
  84
  85   rm -f ${pkgdir}/usr/lib/pkgconfig/thunderbird-ns{s,pr}.pc
  86
  87   #Install lightning manually as for some reason it does not get installed
  88   mkdir -p ${pkgdir}/usr/lib/$realname-$thundermajorver/extensions/$lightningID
  89   cd ${pkgdir}/usr/lib/$realname-$thundermajorver/extensions/$lightningID
  90   bsdtar -x -f ${srcdir}/comm-1.9.2/mozilla/dist/xpi-stage/lightning.xpi
  91
  92   # Fix permissions
  93   find -type d -exec chmod 0755 \{\} \+
  94   find -type f -exec chmod 0644 \{\} \+
  95   find -name '*.so' -exec chmod 0755 \{\} \+
  96 }
  97