terminator-bzr/PKGBUILD

   1 # Maintainer:  TDY <tdy@gmx.com>
   2 # Contributor: zhuqin <zhuqin83@gmail.com>
   3
   4 pkgname=terminator-bzr
   5 pkgver=1150
   6 pkgrel=1
   7 pkgdesc="A tool for arranging multiple terminals in a single window"
   8 arch=('i686' 'x86_64')
   9 url="http://www.tenshu.net/terminator/"
  10 license=('GPL')
  11 depends=('hicolor-icon-theme' 'pygtk' 'vte' 'xdg-utils')
  12 makedepends=('bzr' 'desktop-file-utils' 'gettext' 'intltool')
  13 optdepends=('gnome-python: gnome-terminal profile support')
  14 provides=('terminator=0.13')
  15 conflicts=('terminator')
  16 install=terminator.install
  17
  18 _bzrtrunk=http://bazaar.launchpad.net/~gnome-terminator/terminator/trunk
  19 _bzrmod=terminator
  20
  21 build() {
  22   cd "$srcdir"
  23
  24   msg "Connecting to $_bzrtrunk..."
  25   if [[ -d $_bzrmod ]]; then
  26     bzr up $_bzrtrunk
  27     msg2 "Local files updated"
  28   else
  29     bzr co $_bzrtrunk $_bzrmod -r $pkgver
  30     msg2 "BZR checkout done"
  31   fi
  32
  33   rm -rf $_bzrmod-build
  34   cp -r $_bzrmod $_bzrmod-build
  35   cd $_bzrmod-build
  36
  37   msg "Starting make..."
  38   python2 setup.py build
  39 }
  40
  41 package() {
  42   cd "$srcdir/$_bzrmod-build"
  43   python2 setup.py install --prefix=/usr --root="$pkgdir"
  44   rm -f "$pkgdir/usr/share/icons/hicolor/icon-theme.cache"
  45 }