soci-git/PKGBUILD

   1 # Maintainer: Mika Fischer <mika.fischer@zoopnet.de>
   2 pkgname=soci-git
   3 pkgver=20120109
   4 pkgrel=1
   5 pkgdesc="Database access library for C++"
   6 arch=('i686' 'x86_64')
   7 url="http://soci.sf.net"
   8 license=('custom:boost')
   9 depends=('gcc-libs')
  10 makedepends=('cmake' 'libmysqlclient' 'postgresql-libs' 'sqlite3' 'unixodbc')
  11 optdepends=('instantclient-basic: support for oracle databases'
  12             'libmysqlclient: support for mysql databases'
  13             'postgresql-libs: support for postgresql databases'
  14             'sqlite3: support for sqlite databases'
  15             'unixodbc: support for ODBC databases')
  16 provides=('soci')
  17 conflicts=('soci')
  18
  19 _gitroot='git://soci.git.sourceforge.net/gitroot/soci/soci'
  20 _gitname='soci'
  21
  22 build() {
  23     cd "${srcdir}"
  24     msg "Connecting to GIT server..."
  25     if [ -d "${_gitname}" ]; then
  26         cd "${_gitname}" && git pull origin master
  27         msg "The local files are updated."
  28     else
  29         git clone "${_gitroot}" "${_gitname}"
  30     fi
  31     GIT_DIR="${srcdir}/${_gitname}/.git" git checkout master
  32     msg "GIT checkout done or server timeout"
  33
  34     msg "Starting build..."
  35     rm -rf "${srcdir}/${_gitname}-build"
  36     mkdir -p "${srcdir}/${_gitname}-build"
  37     cd "${srcdir}/${_gitname}-build"
  38     cmake \
  39         -DSOCI_TESTS=OFF \
  40         -DCMAKE_INSTALL_PREFIX="/usr" \
  41         "${srcdir}/${_gitname}/src"
  42     make
  43 }
  44
  45 package() {
  46     cd "${srcdir}/${_gitname}-build"
  47     make DESTDIR="${pkgdir}" install
  48
  49     # For some reason -DLIBDIR=lib causes libsoci_empty.so to disappear
  50     if [ -e "${pkgdir}/usr/lib64" ]; then
  51         mv "${pkgdir}/usr/lib64" "${pkgdir}/usr/lib"
  52     fi
  53     install -Dm0644 "${srcdir}/${_gitname}/src/LICENSE_1_0.txt" \
  54         "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
  55 }