nautilus-dropbox/PKGBUILD

   1 # Maintainer: josephgbr <rafael.f.f1@gmail.com>
   2 # Contributor: cmorlok <christianmorlok@web.de>
   3 # Contributor: fazibear <fazibear@gmail.com>
   4 # Contributor: neuromante <lorenzo.nizzi.grifi@gmail.com>
   5 # Contributor: Gordin <9ordin @t gmail.com>
   6
   7 pkgname=nautilus-dropbox
   8 pkgver=0.7.1
   9 pkgrel=1
  10 pkgdesc="Dropbox for Linux - Nautilus extension"
  11 arch=('i686' 'x86_64')
  12 url="http://forums.dropbox.com/topic.php?id=21111"
  13 license=('custom:CC-BY-ND-3' 'GPL')
  14 depends=('libnotify' 'nautilus' 'dropbox' 'hicolor-icon-theme')
  15 makedepends=('docutils' 'python2' 'pygtk')
  16 install=$pkgname.install
  17 options=('!libtool' '!emptydirs')
  18 source=("https://www.dropbox.com/download?dl=packages/$pkgname-$pkgver.tar.bz2")
  19 md5sums=('f08f6ffaecea55c2f1e615876dbf9479')
  20
  21 build() {
  22   cd "$srcdir/$pkgname-$pkgver/"
  23
  24   sed "s/python/python2/" \
  25         -i configure \
  26         -i Makefile.am \
  27         -i Makefile.in \
  28         -i dropbox.in \
  29         -i rst2man.py
  30
  31   ./configure --prefix=/usr --sysconfdir=/etc
  32   make
  33 }
  34
  35 package() {
  36   cd "$srcdir/$pkgname-$pkgver/"
  37   make DESTDIR="$pkgdir" install
  38   rm "$pkgdir/usr/bin/dropbox"
  39   rm "$pkgdir/usr/share/applications/dropbox.desktop"
  40   rmdir "$pkgdir/usr/share/applications"
  41   install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
  42 }