mingw32-bullet/PKGBUILD

   1 # Maintainer: Sven-Hendrik Haase <sh@lutzhaase.com>
   2 # Contributor: Paul Bienkowski <opatutlol@aol.com>
   3 # Contributor: Christoph Zeiler <archNOSPAM_at_moonblade.dot.org>
   4 pkgname=('mingw32-bullet')
   5 _pkgbasename=bullet
   6 pkgver=2.79
   7 pkgrel=1
   8 pkgdesc="A 3D Collision Detection and Rigid Body Dynamics Library for games and  animation (mingw32)"
   9 arch=('any')
  10 url="http://www.bulletphysics.com/Bullet/"
  11 license=('custom:zlib')
  12 depends=('mingw32-binutils' 'mingw32-runtime')
  13 options=(!strip !buildflags)
  14 makedepends=('cmake' 'freeglut' 'mingw32-gcc')
  15 source=(http://bullet.googlecode.com/files/${_pkgbasename}-${pkgver}-rev2440.tgz \
  16         ${_pkgbasename}.pc \
  17         cmake-toolchain.cmake)
  18 md5sums=('29d6f43964d8494f0366cd69e4883dd1'
  19          '0e13789dc20d32112a6dfd2ac2bdebfb'
  20          'dd2b2db48187dff84050fe191d309d81')
  21
  22 build() {
  23   cd ${_pkgbasename}-${pkgver}
  24
  25   # get a clean build dir
  26   [[ -d build ]] && rm -rf build
  27   mkdir build && cd build
  28
  29   unset LDFLAGS
  30   # generate CMake Makefile
  31   cmake .. \
  32          -DCMAKE_INSTALL_PREFIX=/usr/i486-mingw32 \
  33          -DCMAKE_TOOLCHAIN_FILE=${srcdir}/cmake-toolchain.cmake  \
  34        -DBUILD_SHARED_LIBS=1 \
  35        -DBUILD_DEMOS=0 \
  36        -DBUILD_EXTRAS=1 \
  37        -DINSTALL_LIBS=1 \
  38        -DUSE_GLUT=0 \
  39        -DINSTALL_EXTRA_LIBS=1 \
  40        -DCMAKE_BUILD_TYPE=Release # set =Debug for debugging version
  41
  42   # compile
  43   make
  44 }
  45
  46 package() {
  47   optdepends=('bullet-docs: documentation')
  48
  49   cd ${_pkgbasename}-${pkgver}/build
  50
  51   # install it
  52   make DESTDIR=${pkgdir} install
  53
  54   # manually handle pkgconfig file
  55   mkdir -p "${pkgdir}"/usr/i486-mingw32/lib/pkgconfig
  56   sed "s|VERSION|${pkgver}|g" ${srcdir}/bullet.pc > ${pkgdir}/usr/i486-mingw32/lib/pkgconfig/bullet.pc
  57
  58   # install license
  59   install -Dm644 ../BulletLicense.txt ${pkgdir}/usr/share/licenses/${pkgname}/LICENSE
  60
  61   mkdir -p $pkgdir/usr/i486-mingw32/bin
  62   mv $pkgdir/usr/i486-mingw32/lib/*.dll $pkgdir/usr/i486-mingw32/bin/
  63 }
  64
  65 # vim: sw=2 ts=2 et: