avsynthesis/PKGBUILD

   1 # Maintainer: Alexander Rødseth <rodseth@gmail.com>
   2 pkgname=avsynthesis
   3 pkgver=34_05_13
   4 pkgrel=3
   5 pkgdesc="Audio video synthesis"
   6 arch=('any')
   7 url="http://avsynthesis.blogspot.com/"
   8 license=('custom')
   9 depends=('csound' 'java-runtime' 'jogl')
  10 makedepends=('zip')
  11 # Unable to download directly from https://docs.google.com/View?id=dfq5sj5w_80f9z8tb
  12 source=("$pkgname.zip"::'http://anonfiles.com/cdn/1319728460464.zip'
  13         "$pkgname.sh"
  14         'MANIFEST.MF'
  15         'config.xml')
  16 md5sums=('405fbe2640a2bad8168c15bbd0940d45'
  17          '722d6c2cff50b7375bb35c10d0519950'
  18          'a3a4f4ddcbd6c3c56914c90a4f190efa'
  19          '7c60330a92e20278dae6417e1ee9fb66')
  20
  21 build() {
  22   cd "$srcdir/AVSynthesis_$pkgver"
  23
  24   msg2 "Fixing jar manifest..."
  25   mkdir META-INF
  26   cp "$srcdir/MANIFEST.MF" META-INF
  27   zip -q -u AVSynthesis.jar META-INF/MANIFEST.MF
  28
  29   echo "Public domain?" > LICENSE
  30 }
  31
  32 package() {
  33   cd "$srcdir/AVSynthesis_$pkgver"
  34
  35   msg2 "Packaging data and libraries..."
  36   mkdir -p "$pkgdir/usr/share/$pkgname"
  37   cp -r data "$pkgdir/usr/share/$pkgname/data"
  38   cp -r lib "$pkgdir/usr/share/$pkgname/lib"
  39
  40   msg2 "Installing config.xml to /etc..."
  41   mkdir -p "$pkgdir/etc/$pkgname"
  42   install -Dm644 "$srcdir/config.xml" \
  43     "$pkgdir/etc/$pkgname/config.xml"
  44   ln -sf "/etc/$pkgname/config.xml" \
  45     "$pkgdir/usr/share/$pkgname/data/config.xml"
  46
  47   msg2 "Save files will be placed in /tmp instead of /usr/share..."
  48   mv "$pkgdir/usr/share/$pkgname/data/save" \
  49     "$pkgdir/usr/share/$pkgname/data/original_save"
  50   ln -s "/tmp" "$pkgdir/usr/share/$pkgname/data/save"
  51
  52   msg2 "Packaging executables..."
  53   install -Dm644 AVSynthesis.jar \
  54     "$pkgdir/usr/share/$pkgname/AVSynthesis.jar"
  55   install -Dm755 ../avsynthesis.sh \
  56     "$pkgdir/usr/bin/$pkgname"
  57
  58   install -Dm 644 LICENSE \
  59     "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
  60 }
  61
  62 # vim:set ts=2 sw=2 et: