mingw32-lcms/PKGBUILD

   1 # Maintainer: Schala <schalaalexiazeal@gmail.com>
   2
   3 pkgname=mingw32-lcms
   4 pkgver=2.3
   5 pkgrel=1
   6 pkgdesc="Lightweight color management development library/engine (mingw32)"
   7 arch=('any')
   8 depends=('mingw32-runtime' 'mingw32-libtiff')
   9 makedepends=('mingw32-gcc')
  10 options=('!libtool' '!strip')
  11 conflicts=('mingw32-lcms1')
  12 license=('custom')
  13 url="http://www.littlecms.com"
  14 source=(http://downloads.sourceforge.net/sourceforge/lcms/lcms2-${pkgver}.tar.gz)
  15 md5sums=('327348d67c979c88c2dec59a23a17d85')
  16
  17 build() {
  18   cd "${srcdir}/lcms2-${pkgver}"
  19
  20   export CFLAGS="-O2 -mms-bitfields"
  21   export PKG_CONFIG_PATH="/usr/i486-mingw32/lib/pkgconfig/"
  22   unset LDFLAGS # mingw-ld chokes on --hash-style=gnu
  23
  24   ./configure \
  25       --prefix=/usr/i486-mingw32 \
  26       --host=i486-mingw32 \
  27       --build=$CHOST
  28
  29     make
  30 }
  31
  32 package() {
  33   cd "${srcdir}/lcms2-${pkgver}"
  34   make DESTDIR="${pkgdir}" install
  35   install -Dm 644 COPYING \
  36     ${pkgdir}/usr/share/licenses/${pkgname}/LICENSE
  37 }
  38
  39 # vim:set ts=2 sw=2 et: