thunderbird2/PKGBUILD

   1 # Maintainer: linuxSEAT <--put_my_name_here--@gmail.com>
   2 # Contributor: Alexander Baldeck <alexander@archlinux.org>
   3 # Contributor: Dale Blount <dale@archlinux.org>
   4 # Contributor: Anders Bostrom <anders.bostrom@home.se>
   5 pkgname=thunderbird2
   6 pkgver=2.0.0.24
   7 pkgrel=1
   8 pkgdesc="Standalone Mail/News reader (Version 2)"
   9 arch=('i686' 'x86_64')
  10 license=('MPL' 'GPL')
  11 url="http://www.mozilla.org/projects/thunderbird"
  12 provides=('mozilla-thunderbird' 'thunderbird')
  13 conflicts=('mozilla-thunderbird' 'thunderbird')
  14 replaces=('mozilla-thunderbird' 'thunderbird')
  15 depends=('gtk2>=2.16.5' 'gcc-libs>=4.4' 'libidl2>=0.8.13' 'mozilla-common' 'nss>=3.12.3' 'libxt' 'shared-mime-info')
  16 makedepends=('zip' 'pkgconfig' 'imagemagick>=6.5.3.10-1' 'libgnomeui')
  17 options=('!makeflags')
  18 source=(ftp://ftp.mozilla.org/pub/mozilla.org/thunderbird/releases/${pkgver}/source/thunderbird-${pkgver}-source.tar.bz2
  19         mozconfig
  20         thunderbird.desktop
  21         thunderbird-1.5-lang.patch
  22         firefox-2.0-link-layout.patch
  23         thunderbird-appversion.patch
  24         xulrunner-elif.patch
  25         libpng.patch)
  26 md5sums=('6e09f74b25aac46705abb13ea4c26f67'
  27          '17e3015259da53f40bc445b27078f693'
  28          'ea4e3c3dee98e3891bef16409551eb6e'
  29          'bc6f10a06407faee6494acad546aabf9'
  30          'b933c00957ea793fe940f4d46a85e10e'
  31          '63dd0436e43e2de71abcf9160a1a6f44'
  32          '38457261a6355365079dbe5c2342ec68'
  33          'a0c53b831cf162a4723a59950f70572e')
  34
  35 build() {
  36   # -Wl,--as-needed seems to fail here
  37   unset LDFLAGS
  38
  39   cd "${srcdir}/mozilla"
  40   patch -Np1 -i "${srcdir}/thunderbird-1.5-lang.patch" || return 1
  41   patch -Np1 -i "${srcdir}/firefox-2.0-link-layout.patch" || return 1
  42   patch -Np1 -i "${srcdir}/thunderbird-appversion.patch" || return 1
  43   patch -Np1 -i "${srcdir}/xulrunner-elif.patch" || return 1
  44   patch -Np1 -i "${srcdir}/libpng.patch" || return 1
  45
  46   cp "${srcdir}/mozconfig" .mozconfig
  47
  48   echo "ac_cv_visibility_pragma=no" >> .mozconfig
  49
  50   export MOZ_PROJECT=mail
  51   unset CXXFLAGS
  52   unset CFLAGS
  53
  54   make -f client.mk build || return 1
  55   make DESTDIR="${pkgdir}" install || return 1
  56
  57   rm -rf "${pkgdir}/usr/bin/defaults"
  58
  59   install -m755 -d "${pkgdir}/usr/share/applications"
  60   install -m755 -d "${pkgdir}/usr/share/pixmaps"
  61   convert "${srcdir}/mozilla/mail/app/default.xpm" \
  62       "${pkgdir}/usr/share/pixmaps/thunderbird.png" || return 1
  63   install -m644 "${srcdir}/thunderbird.desktop" \
  64       "${pkgdir}/usr/share/applications/" || return 1
  65
  66   install -m644 "${srcdir}/mozilla/mail/app/default.xpm" \
  67       "${pkgdir}/usr/lib/thunderbird-2.0/icons/" || return 1
  68
  69   rm -f ${pkgdir}/usr/lib/pkgconfig/thunderbird-ns{s,pr}.pc
  70 }