fomus/PKGBUILD

   1 # Maintainer: SpepS <dreamspepser at yahoo dot it>
   2
   3 pkgname=fomus
   4 pkgver=0.1.18_alpha
   5 pkgrel=1
   6 pkgdesc="Automatic music notation application for musicians and composers."
   7 arch=(i686 x86_64)
   8 url="http://fomus.sourceforge.net/"
   9 license=('GPL3')
  10 depends=('boost-libs' 'libtool')
  11 makedepends=('graphviz' 'imagemagick' 'libxml2' 'swig' 'libtool' 'pd')
  12 optdepends=('lilypond: lilypond support'
  13             'emacs: emacs support'
  14             'pd: pd support'
  15             'cm: common music and grace support')
  16 options=('!libtool')
  17 source=("http://downloads.sourceforge.net/project/$pkgname/$pkgname-${pkgver//_/-}.tar.gz")
  18 md5sums=('b26a2f55d393385a5db9681bc27d3cfc')
  19
  20 build() {
  21   cd "$srcdir/$pkgname-${pkgver//_/-}"
  22
  23   ./configure --prefix=/usr \
  24               --enable-static=no \
  25               --with-puredata
  26   make
  27 }
  28
  29 package() {
  30   cd "$srcdir/$pkgname-${pkgver//_/-}"
  31
  32   make DESTDIR="$pkgdir/" install
  33
  34   # install pd extension in the right path
  35   install -d "$pkgdir/usr/lib/pd/extra"
  36   mv "$pkgdir/usr/share/$pkgname/$pkgname.pd_linux" "$pkgdir/usr/lib/pd/extra"
  37 }
  38
  39 # vim:set ts=2 sw=2 et: