iscan/PKGBUILD

   1 # Maintainer: Alessio Sergi <asergi at archlinux dot us>
   2
   3 pkgname=iscan
   4 pkgver=2.28.1
   5 pkgrel=1
   6 pkgdesc="A front-end for EPSON scanner/all-in-ones"
   7 arch=('i686' 'x86_64')
   8 url="http://avasys.jp/eng/linux_driver/"
   9 license=('GPL2' 'custom:AVASYSPL')
  10 depends=('gtk2' 'iscan-data' 'sane')
  11 makedepends=('gettext')
  12 conflicts=(${pkgname}-legacy)
  13 install=${pkgname}.install
  14 options=('!libtool')
  15 source=(http://linux.avasys.jp/drivers/${pkgname}/${pkgver}/${pkgname}_${pkgver}-3.tar.gz)
  16 md5sums=('df777c77425cde132ed94c13a47eb8d7')
  17
  18 build() {
  19   cd "${srcdir}/${pkgname}-${pkgver}"
  20
  21   export LDFLAGS="${LDFLAGS} -ldl -lpng14"
  22
  23   ./configure --prefix=/usr \
  24               --enable-dependency-reduction \
  25               --enable-frontend \
  26               --enable-jpeg \
  27               --enable-tiff \
  28               --enable-png #--enable-gimp
  29   make
  30 }
  31
  32 package() {
  33   cd "${srcdir}/${pkgname}-${pkgver}"
  34
  35   make DESTDIR="${pkgdir}" install
  36
  37   # install sane file config
  38   install -d -m755 "${pkgdir}/etc/sane.d"
  39   install -m644 backend/epkowa.conf "${pkgdir}/etc/sane.d/epkowa.conf"
  40
  41   # install desktop file
  42   install -d -m755 "${pkgdir}/usr/share/applications"
  43   install -m644 "${pkgname}.desktop" \
  44     "${pkgdir}/usr/share/applications/${pkgname}.desktop"
  45
  46   # install license
  47   install -d -m755 "${pkgdir}/usr/share/licenses/${pkgname}"
  48   install -m644 "${srcdir}/${pkgname}-${pkgver}/non-free/AVASYSPL.en.txt" \
  49     "${pkgdir}/usr/share/licenses/${pkgname}/AVASYSPL"
  50 }
  51
  52 # vim:set ts=2 sw=2 et: