tigervnc-svn/PKGBUILD

   1 # Maintainer: Uroš Vampl <mobile.leecher at gmail dot com>
   2
   3 pkgname=tigervnc-svn
   4 pkgver=4830
   5 pkgrel=1
   6 _xorgver=1.11.3
   7 pkgdesc="TigerVNC is a suite of VNC servers and clients that have a focus on performance and remote display functionality. Originally this software was based on the (never released) VNC 4 branch of TightVNC."
   8 arch=('i686' 'x86_64')
   9 url="http://www.tigervnc.org"
  10 license=('GPL')
  11 depends=('zlib' 'libjpeg-turbo' 'fontconfig' 'libsm' 'libxtst' 'libxi' 'libxfont' 'libxmu' 'libxkbfile' 'libxrender' 'libgl' 'pixman' 'xorg-xauth' 'xorg-xsetroot' 'xkeyboard-config' 'xorg-fonts-alias' 'xorg-fonts-misc')
  12 makedepends=('subversion' 'cmake' 'nasm' 'xorg-util-macros' 'xorg-font-util' 'inputproto' 'xextproto' 'xproto' 'bigreqsproto' 'compositeproto' 'damageproto' 'dri2proto' 'fixesproto' 'fontsproto' 'randrproto' 'resourceproto' 'scrnsaverproto' 'videoproto' 'xcmiscproto' 'xineramaproto' 'xf86driproto' 'xf86vidmodeproto' 'glproto' 'renderproto' 'mesa' 'libpciaccess' 'xtrans')
  13 provides=('tigervnc')
  14 conflicts=('tigervnc' 'tightvnc')
  15 source=(cmakelists.patch
  16         xorg111.patch
  17         ftp://ftp.freedesktop.org/pub/xorg/individual/xserver/xorg-server-${_xorgver}.tar.bz2)
  18 md5sums=('f892722196745c937d76a07828e70a8b'
  19          'b680b55f7f9f569cd26ac0b330012a8b'
  20          'a7194c437963627e1db0dd2d6c1a1984')
  21
  22 _svntrunk=https://tigervnc.svn.sourceforge.net/svnroot/tigervnc/trunk
  23 _svnmod=tigervnc
  24
  25 build() {
  26   cd ${srcdir}
  27
  28   msg "Connecting to SVN server..."
  29   if [ -d ${_svnmod}/.svn ]; then
  30     (cd ${_svnmod} && svn up -r ${pkgver})
  31   else
  32     svn co ${_svntrunk} --config-dir ./ -r ${pkgver} ${_svnmod}
  33   fi
  34   msg "SVN checkout done or server timeout"
  35
  36   if [ -d ${_svnmod}-build ]; then
  37     msg "Deleting old build directory..."
  38     rm -rf ${_svnmod}-build
  39   fi
  40
  41   msg "Setting up build environment..."
  42   svn export ${_svnmod} ${_svnmod}-build
  43   cd ${_svnmod}-build
  44   cp -r ${srcdir}/xorg-server-${_xorgver}/* unix/xserver
  45   for p in ${srcdir}/*.patch; do patch -p1 < $p; done
  46
  47   msg "Starting build..."
  48   cmake -G "Unix Makefiles" \
  49         -DCMAKE_INSTALL_PREFIX=/usr -DUSE_INCLUDED_FLTK=yes \
  50         -DENABLE_GNUTLS=no -DENABLE_PAM=no .
  51   make
  52
  53   cd unix/xserver
  54   patch -p1 < ../xserver110.patch
  55   autoreconf -fiv
  56   ./configure --prefix=/usr \
  57         --disable-static --disable-xinerama \
  58         --disable-xorg --disable-xnest --disable-xvfb --disable-dmx \
  59         --disable-xwin --disable-xephyr --disable-kdrive --with-pic \
  60         --disable-config-dbus --disable-config-hal --disable-config-udev \
  61         --disable-unit-tests --disable-devel-docs --disable-dri \
  62         --enable-dri2 --enable-glx --enable-glx-tls
  63   make
  64 }
  65
  66 package() {
  67   cd ${srcdir}/${_svnmod}-build
  68   make DESTDIR=${pkgdir} install
  69
  70   cd unix/xserver/hw/vnc
  71   make DESTDIR=${pkgdir} install
  72   rm ${pkgdir}/usr/lib/xorg/modules/extensions/libvnc.la
  73 }