sonic-visualiser/PKGBUILD

   1 # Maintainer : SpepS <dreamspepser at yahoo dot it>
   2 # Contributor: Orivej Desh <masecretaire@gmx.fr>
   3
   4 pkgname=sonic-visualiser
   5 pkgver=1.9
   6 pkgrel=2
   7 pkgdesc="A viewer and analyser of music audio files."
   8 arch=('i686' 'x86_64')
   9 url="http://www.sonicvisualiser.org/"
  10 license=('GPL2')
  11 depends=('qt' 'liblrdf' 'bzip2' 'rubberband' 'liblo' 'libid3tag' 'redland'
  12          'libmad' 'libfishsound' 'libpulse' 'liboggz' 'portaudio' 'jack')
  13 install="$pkgname.install"
  14 #source=("http://downloads.sourceforge.net/sv1/$pkgname-$pkgver.tar.gz")
  15 source=("http://code.soundsoftware.ac.uk/attachments/download/194/$pkgname-$pkgver.tar.gz")
  16 md5sums=('a50037994d180c7b9b113fbde3131a8c')
  17
  18 build() {
  19   cd "$srcdir/$pkgname-$pkgver"
  20
  21   # build against Qt4
  22   export QTDIR=/usr
  23
  24   ./configure
  25
  26   # Remove flac cflags (-I/usr/include/FLAC) to
  27   # prevent g++ fetching assert.h from flac headers
  28   sed -i "s|/FLAC||g" `grep -rl /FLAC . 2> /dev/null`
  29
  30   # DSO link fix (missing libX11)
  31   sed -i "/^LIBS/s/$/-lX11/" $pkgname/Makefile
  32
  33   make
  34 }
  35
  36 package() {
  37   cd "$srcdir/$pkgname-$pkgver/$pkgname"
  38
  39   # bin
  40   install -Dm755 $pkgname "$pkgdir/usr/bin/$pkgname"
  41
  42   # desktop file and pixmaps
  43   install -d "$pkgdir/usr/share/applications"
  44   install -Dm644 *.desktop "$pkgdir/usr/share/applications"
  45
  46   for _s in 16 22 24 32 48 64 128; do
  47     install -Dm644 icons/sv-${_s}x${_s}.png \
  48             "$pkgdir/usr/share/icons/hicolor/${_s}x${_s}/apps/sv-icon.png"
  49   done
  50
  51   install -Dm644 icons/sv-icon.svg \
  52           "$pkgdir/usr/share/icons/hicolor/scalable/apps/sv-icon.svg"
  53
  54   # samples
  55   install -d "$pkgdir/usr/share/$pkgname/samples"
  56   install -Dm644 samples/* "$pkgdir/usr/share/$pkgname/samples"
  57 }