linwarrior/PKGBUILD

   1 # Maintainer: Anton Bazhenov <anton.bazhenov at gmail>
   2 # Contributor: cantabile <cantabile dot desu at gmail dot com>
   3 # Contributor: Christoph Zeiler <rabyte*gmail>
   4
   5 pkgname=linwarrior
   6 pkgver=20101231
   7 pkgrel=1
   8 pkgdesc="A somewhat classical open source Mech Simulation game"
   9 arch=('i686' 'x86_64')
  10 url="http://www.hackcraft.de/games/linwarrior_3d/"
  11 license=('custom')
  12 depends=('glew' 'freealut' 'sdl')
  13 makedepends=('sed' 'findutils')
  14 source=("http://www.hackcraft.de/games/linwarrior_3d/downloads/${pkgname}_${pkgver}.tar.gz")
  15 md5sums=('ba7b8a8dd4007f9aa9b2d481f47dc794')
  16
  17 build() {
  18   cd "${srcdir}/${pkgname}"
  19   sed -i "s_data/_/usr/share/$pkgname/data/_g" source/{cBackground,cBuilding,cPlanetmap,cMech,cWeapon,main}.cpp
  20   sed -i "s_-lGLU_-lGL -lGLU_g" Makefile
  21   make || return 1
  22 }
  23
  24 package() {
  25   cd "${srcdir}/${pkgname}"
  26
  27   # install binary
  28   install -Dm755 "dist/${pkgname}" "${pkgdir}/usr/bin/${pkgname}"
  29
  30   # just to be sure
  31   find data/ -type d -exec chmod 755 '{}' \;
  32   # there's no reason for data files to be executable
  33   find data/ -type f -exec chmod 644 '{}' \;
  34   # install the data
  35   install -dm755 "${pkgdir}/usr/share/${pkgname}"
  36   cp -r data "${pkgdir}/usr/share/${pkgname}/"
  37
  38   # install license and readme
  39   install -Dm644 doc/COPYING "${pkgdir}/usr/share/licenses/${pkgname}/COPYING"
  40   install -Dm644 doc/README "${pkgdir}/usr/share/doc/${pkgname}/README"
  41 }
  42
  43 # vim:set ts=2 sw=2 et: