cinnamon-git/PKGBUILD

   1 # Maintainer: Xiao-Long Chen <chenxiaolong@cxl.epac.to>
   2
   3 pkgname=cinnamon-git
   4 pkgver=20120109
   5 pkgrel=1
   6 pkgdesc="Linux desktop which provides advanced innovative features and a traditional user experience"
   7 arch=('i686' 'x86_64')
   8 url="https://github.com/linuxmint/Cinnamon"
   9 license=('GPL')
  10 depends=('gnome-menus' 'libpulse' 'gnome-desktop' 'python' 'gnome-bluetooth' 'gjs' 'mutter' 'libcroco' 'folks' 'telepathy-logger' 'networkmanager' 'caribou' 'nautilus' 'telepathy-mission-control' 'gnome-common' 'gnome-session')
  11 makedepends=('git' 'intltool')
  12 provides=('cinnamon')
  13 conflicts=('cinnamon')
  14 options=('!libtool')
  15 install=${pkgname}.install
  16 source=('cinnamon.session'
  17         'cinnamon.xsession')
  18 sha512sums=('e54d88c200314d6f19c3a220d19000a67b1d282de522d67d4757f4fb9443ddd0ab818a79c9dd215d7c5123ea9dc771092b0313a531479ff55310d31d9b9efba3'
  19             '44d5d2588832e93f3bc4f49d34cb83b5b558b15893ab3c6d4c4ba9cda3133ae54869de86cac59ccbd63383913bf820203a2ded35c854ea8150f6053a2394eb85')
  20
  21 _gitroot='https://github.com/linuxmint/Cinnamon.git'
  22 _gitname='Cinnamon'
  23
  24 build() {
  25   cd "${srcdir}"
  26   msg "Connecting to GIT server...."
  27
  28   if [[ -d "${_gitname}" ]]; then
  29     cd "${_gitname}" && git pull origin
  30     msg "The local files are updated."
  31   else
  32     git clone "${_gitroot}" "${_gitname}"
  33   fi
  34
  35   msg "GIT checkout done or server timeout"
  36   msg "Starting build..."
  37
  38   rm -rf "${srcdir}/${_gitname}-build"
  39   git clone "${srcdir}/${_gitname}" "${srcdir}/${_gitname}-build"
  40   cd "${srcdir}/${_gitname}-build"
  41
  42   ./autogen.sh --prefix=/usr --sysconfdir=/etc --libexecdir=/usr/lib/cinnamon --localstatedir=/var --disable-static --disable-schemas-compile --disable-schemas-install --enable-compile-warnings=yes
  43   make
  44 }
  45
  46 package() {
  47   cd "${srcdir}/${_gitname}-build"
  48   make GCONF_DISABLE_MAKEFILE_SCHEMA_INSTALL=1 DESTDIR="${pkgdir}/" install
  49
  50   # GConf2 stuff
  51   install -dm755 "${pkgdir}/usr/share/gconf/schemas/"
  52   gconf-merge-schema "${pkgdir}/usr/share/gconf/schemas/${pkgname%-*}.schemas" --domain cinnamon "${pkgdir}"/etc/gconf/schemas/*.schemas
  53   rm "${pkgdir}"/etc/gconf/schemas/*.schemas
  54
  55   # Python 2 fix
  56   sed -i 's|^\(#!.*python\)$|\12|g' "${pkgdir}/usr/bin/cinnamon-extension-tool"
  57
  58   # Install GNOME Session manager session file
  59   install -dm755 "${pkgdir}/usr/share/gnome-session/sessions/"
  60   install -m644 "${srcdir}/cinnamon.session" "${pkgdir}/usr/share/gnome-session/sessions/cinnamon.session"
  61
  62   # Install X11 session file
  63   install -dm755 "${pkgdir}/usr/share/xsessions/"
  64   install -m644 "${srcdir}/cinnamon.xsession" "${pkgdir}/usr/share/xsessions/cinnamon.desktop"
  65 }
  66
  67 # vim:set ts=2 sw=2 et: