kdenlive-svn/PKGBUILD

   1 # Maintainer: Alessio Sergi <asergi [at] archlinux [dot] us>
   2
   3 pkgname=kdenlive-svn
   4 _realname=kdenlive
   5 pkgver=5425
   6 pkgrel=1
   7 pkgdesc="A non-linear video editor for Linux"
   8 arch=('i686' 'x86_64')
   9 url="http://kdenlive.sourceforge.net/"
  10 license=('GPL')
  11 depends=('hicolor-icon-theme' 'kdelibs' 'mlt-git' \
  12          'qimageblitz' 'qjson' 'shared-mime-info')
  13 makedepends=('automoc4' 'cmake' 'subversion')
  14 optdepends=('cdrkit: for creation of DVD ISO images'
  15             'dvdauthor: for creation of DVD'
  16             'dvgrab: for firewire capture'
  17             'ffmpeg: for webcam capture'
  18             'recordmydesktop: for screen capture'
  19             'xine-lib: for preview DVD')
  20 provides=(${_realname})
  21 conflicts=(${_realname})
  22 install=${pkgname}.install
  23
  24 _svntrunk=https://${_realname}.svn.sourceforge.net/svnroot/${_realname}/trunk/${_realname}
  25 _svnmod=${_realname}
  26
  27 build() {
  28   cd "${srcdir}"
  29
  30   if [ -d ${_svnmod}/.svn ]; then
  31     (cd ${_svnmod} && svn up -r ${pkgver})
  32   else
  33     svn co ${_svntrunk} ${_svnmod} -r ${pkgver}
  34   fi
  35
  36   msg "SVN checkout done or server timeout"
  37   msg "Starting make..."
  38
  39   rm -rf build
  40   cp -r ${_svnmod} build
  41   cd build
  42
  43   export LDFLAGS="${LDFLAGS} -lX11"
  44   cmake -DCMAKE_BUILD_TYPE=Release \
  45         -DCMAKE_INSTALL_PREFIX=/usr \
  46         -DLIB_INSTALL_DIR=/usr/lib \
  47         -DLINK_LIBRARIES=-lX11
  48   make
  49 }
  50
  51 package() {
  52   cd "${srcdir}/build"
  53
  54   make DESTDIR="${pkgdir}" install
  55 }