dofus/PKGBUILD

   1 # Maintainer: p2k <Patrick.Schneider@uni-ulm.de>
   2 # Original Maintainer: Schtroumpfette <fpeterschmitt@voila.fr>
   3 pkgname=dofus
   4 pkgver=2.3.6
   5 pkgrel=1
   6 pkgdesc="A manga inspired, Massively Multiplayer Online Role-playing Game (MMORPG) for Adobe AIR."
   7 url="http://www.dofus.com/"
   8 license=("custom:Dofus License")
   9 arch=('i686' 'x86_64')
  10 source=(http://dl.ak.ankama.com/games/dofus2/setup/DofusInstall.run air-generic-launcher.sh UpLauncher.arch.sh)
  11 if [ "$CARCH" == "x86_64" ];then
  12   depends=('bin32-adobe-air' 'lib32-gtk2' 'lib32-libxt'
  13            'lib32-libjpeg6' 'lib32-libpng12' 'lib32-openssl-compatibility'
  14            'lib32-libldap' 'lib32-gvfs' 'lib32-nss' 'lib32-libxslt'
  15            'lib32-dbus-glib' 'lib32-alsa-lib')
  16 else
  17   depends=('adobe-air-sdk' 'gtk2' 'libxt'
  18            'libjpeg6' 'libpng12' 'openssl-compatibility'
  19            'gvfs' 'nss' 'libxslt' 'alsa-lib')
  20 fi
  21 install=(dofus.install)
  22 md5sums=('7343984948e0279e4cc83574bd1d1792'
  23          'f179eaa5e6e6674b1853cf826fc33c3a'
  24          'ae460da240d653d796e5c8f703d572c0')
  25
  26 build() {
  27   cd "$srcdir"
  28
  29   msg2 "Extracting installer..."
  30   sh ./DofusInstall.run --noexec --keep --target dofus_install
  31 }
  32
  33 package() {
  34   cd "$srcdir/dofus_install"
  35   install_dir="$pkgdir/opt/dofus"
  36   mkdir -p "$install_dir"
  37
  38   msg2 "Installing main applications..."
  39   cp -R Dofus/* "$install_dir"
  40   chmod 0775 "$install_dir/share"
  41   install "$srcdir/air-generic-launcher.sh" "$install_dir/bin/Dofus"
  42   cp -R Reg "$install_dir/share/reg"
  43   chmod 0775 "$install_dir/share/reg" "$install_dir/share/reg/share"
  44   install "$srcdir/air-generic-launcher.sh" "$install_dir/share/reg/bin/Reg"
  45
  46   msg2 "Installing additional content..."
  47   mv "$install_dir/share/reg/share/Reg.swf" "$install_dir/share/reg/Reg.swf"
  48   ln -s ../Reg.swf "$install_dir/share/reg/share/Reg.swf"
  49   ln -s ../content "$install_dir/share/reg/share/content"
  50   ln -s ../config.xml "$install_dir/share/reg/share/config.xml"
  51   install UpLauncher "$install_dir/share/UpLauncher"
  52   install -m 644 uplauncherComponents.xml "$install_dir/share/uplauncherComponents.xml"
  53
  54   msg2 "Installing launcher script..."
  55   install "$srcdir/UpLauncher.arch.sh" "$install_dir/share/UpLauncher.arch.sh"
  56   mkdir -p "$pkgdir/usr/bin"
  57   ln -s /opt/dofus/share/UpLauncher.arch.sh "$pkgdir/usr/bin/dofus"
  58
  59   msg2 "Installing menu icon..."
  60   mkdir -p "$pkgdir/usr/share/applications"
  61   cat > "$pkgdir/usr/share/applications/Dofus.desktop" <<EOF
  62 [Desktop Entry]
  63 Encoding=UTF-8
  64 Type=Application
  65 Name=Dofus
  66 GenericName=Dofus
  67 Comment=Dofus
  68 Icon=/opt/dofus/share/icon/dofus-icon-48.png
  69 Exec=/opt/dofus/share/UpLauncher.arch.sh
  70 Path=/opt/dofus/share/
  71 Categories=Game;RolePlaying;Ankama-Games
  72 EOF
  73
  74   msg2 "Installing licenses..."
  75   mkdir -p "$pkgdir/usr/share/licenses/dofus"
  76   cp -R licenses/*.txt "$pkgdir/usr/share/licenses/dofus"
  77   chmod 0644 "$pkgdir/usr/share/licenses/dofus"/*
  78 }
  79 # vim:set ts=2 sw=2 et: