skencil/PKGBUILD

   1 # Maintainer: SpepS <dreamspepser at yahoo dot it>
   2 # Contributor: Michael Krauss <mickraus@googlemail.com>
   3
   4 pkgname=skencil
   5 pkgver=1.0alpha_rev784
   6 pkgrel=1
   7 pkgdesc="An interactive vector drawing program for X (similar to XFigor tgif), written almost completely in Python"
   8 arch=(i686 x86_64)
   9 url="http://sk1project.org/viewpage.php?page_id=21"
  10 license=('GPL')
  11 depends=('python-imaging' 'pygtk' 'python-reportlab' 'tk')
  12 install=("$pkgname.install")
  13 source=("http://sk1project.org/dc2.php?target=$pkgname-$pkgver.tar.gz"
  14         "http://sk1project.org/images/news/pict007.png")
  15 md5sums=('b4c259243c0a5a400b59a5e315f3ae55'
  16          'e930b652260747068ac2b4776ea05da1')
  17
  18 build() {
  19   cd "$srcdir/$pkgname-${pkgver/_*}"
  20
  21   # Python2 fixes
  22   export PYTHON="python2"
  23   sed -e "s|\(env python\).*|\12|;s|\(bin/python\).*|\12|" \
  24     -i `grep -Erl "(env python|bin/python)" .`
  25
  26   # Fix "python -c" invocation
  27   sed -i "s|python |python2 |" src/Sketch/Base/gtkutils.py
  28
  29   python2 setup.py build
  30 }
  31
  32 package() {
  33   cd "$srcdir/$pkgname-${pkgver/_*}"
  34
  35   python2 setup.py install --prefix=/usr --root="$pkgdir"
  36
  37   # Replace pixmap with a better image
  38   install -Dm644 ../pict007.png "$pkgdir/usr/share/pixmaps/$pkgname.png"
  39 }
  40
  41 # vim:set ts=2 sw=2 et: