nautilus-ideviceinfo-git/PKGBUILD

   1 # Contributor: Joeny Ang <ang(dot)joeny(at)gmail(dot)com>
   2
   3 pkgname=nautilus-ideviceinfo-git
   4 pkgver=20110518
   5 pkgrel=1
   6 pkgdesc="Get extra information about your iDevice"
   7 arch=('i686' 'x86_64')
   8 url="http://www.libimobiledevice.org/"
   9 license=('GPL')
  10 depends=('libimobiledevice' 'nautilus')
  11 optdepends=('mobile-broadband-provider-info: to show mobile carrier'
  12             'libgpod>=0.7.90: to enable detailed audio/video information')
  13 makedepends=('git' 'intltool')
  14 options=(!libtool)
  15 source=(rb-segmented-bar-gtk3-fix.patch)
  16 md5sums=('8b8eb9570d4006aaa9bfc641ab60136c')
  17
  18 _gitroot="git://git.gnome.org/nautilus-ideviceinfo"
  19 _gitname="nautilus-ideviceinfo"
  20
  21 build() {
  22   cd ${srcdir}
  23   msg "Connecting to GIT server...."
  24   if [ -d ${_gitname} ] ; then
  25     cd ${_gitname} && git pull origin
  26     msg "The local files are updated."
  27   else
  28     git clone ${_gitroot} ${_gitname}
  29   fi
  30   msg "GIT checkout done or server timeout"
  31   msg "Starting make..."
  32
  33   rm -rf ${srcdir}/${_gitname}-build
  34   git clone ${srcdir}/${_gitname} ${srcdir}/${_gitname}-build
  35   cd ${srcdir}/${_gitname}-build
  36
  37   export providerinfo_CFLAGS="-DMOBILE_BROADBAND_PROVIDER_INFO=\\\"`pkg-config --variable=database mobile-broadband-provider-info`\\\""
  38   ./autogen.sh --prefix=/usr
  39   unset providerinfo_CFLAGS
  40   patch -Np0 -i ../rb-segmented-bar-gtk3-fix.patch
  41   make
  42 }
  43
  44 package() {
  45   cd ${srcdir}/${_gitname}-build
  46   make DESTDIR=${pkgdir}/ install
  47 }