alephone-svn/PKGBUILD

   1 # Maintainer: Marcin Skory <armitage at gfreedom dot org>
   2 pkgname=alephone-svn
   3 pkgver=4662
   4 pkgrel=2
   5 pkgdesc='A free, enhanced port of the classic FPS "Marathon 2" by Bungie Software (SVN version)'
   6 arch=('i686' 'x86_64')
   7 url="http://marathon.sourceforge.net/"
   8 license=('GPL')
   9 depends=('sdl_ttf' 'libmad' 'libsndfile' 'libvorbis' 'mesa' 'sdl_image' 'sdl_net' 'smpeg' 'speex' 'zziplib')
  10 makedepends=('subversion' 'boost' 'lua>=5.1')
  11 optdepends=('alephone-emr: community-made scenario' \
  12             'alephone-eternalx: community-made scenario' \
  13             'alephone-evil: community-made scenario' \
  14             'alephone-marathon: M1A1 data converted for AlephOne' \
  15             'alephone-marathon2: original data for Marathon 2: Durandal' \
  16             'alephone-infinity: original data for Marathon Infinity' \
  17             'alephone-red: community-made scenario' \
  18             'alephone-rubiconx: community-made scenario' \
  19             'alephone-tempus_irae: community-made scenario')
  20 provides=('alephone')
  21 conflicts=('alephone')
  22
  23 _svntrunk=https://marathon.svn.sourceforge.net/svnroot/marathon/trunk
  24 _svnmod=marathon
  25
  26 build() {
  27   cd "$srcdir"
  28   # forcing to ignore externals during checkout due to someone's bright idea to
  29   # bundle all the scenarios plus hi-res textures with the source tree; we have
  30   # separate packages for that and right now ignoring it doesn't seem to break
  31   # anything (at least not yet)
  32   if [ -d $_svnmod/.svn ]; then
  33     (cd $_svnmod && svn up --ignore-externals -r $pkgver)
  34   else
  35     svn co $_svntrunk --config-dir ./ --ignore-externals -r $pkgver $_svnmod
  36   fi
  37
  38   msg "SVN checkout done or server timeout"
  39   msg "Starting make..."
  40
  41   rm -rf "$srcdir/$_svnmod-build"
  42   cp -r "$srcdir/$_svnmod" "$srcdir/$_svnmod-build"
  43   cd "$srcdir/$_svnmod-build"
  44
  45   # Build procedure
  46   ./autogen.sh
  47   sed "s/PACKAGE='AlephOne'/PACKAGE='alephone'/g" -i configure
  48   ./configure --prefix=/usr
  49   make
  50 }
  51
  52 package() {
  53   cd "$srcdir/$_svnmod-build"
  54   make DESTDIR="$pkgdir/" install
  55 }