soci/PKGBUILD

   1 # Maintainer: Mika Fischer <mika.fischer@zoopnet.de>
   2 pkgname=soci
   3 pkgver=3.1.0
   4 pkgrel=5
   5 pkgdesc="Database access library for C++"
   6 arch=('i686' 'x86_64')
   7 url="http://soci.sf.net"
   8 license=('custom:boost')
   9 depends=('gcc-libs')
  10 makedepends=('cmake' 'libmysqlclient' 'postgresql-libs' 'sqlite3' 'unixodbc')
  11 optdepends=('instantclient-basic: support for oracle databases'
  12             'libmysqlclient: support for mysql databases'
  13             'postgresql-libs: support for postgresql databases'
  14             'sqlite3: support for sqlite databases'
  15             'unixodbc: support for ODBC databases')
  16 source=("http://downloads.sourceforge.net/project/soci/soci/${pkgname}-${pkgver}/${pkgname}-${pkgver}.zip")
  17 md5sums=('6ffac090b996bc34aedf4a29adf4595c')
  18
  19 build() {
  20     rm -rf "${srcdir}/${pkgname}-${pkgver}-build"
  21     mkdir -p "${srcdir}/${pkgname}-${pkgver}-build"
  22     cd "${srcdir}/${pkgname}-${pkgver}-build"
  23     cmake \
  24         -DSOCI_TESTS=OFF \
  25         -DCMAKE_INSTALL_PREFIX="/usr" \
  26         "${srcdir}/${pkgname}-${pkgver}"
  27     make
  28 }
  29
  30 package() {
  31     cd "${srcdir}/${pkgname}-${pkgver}-build"
  32     make DESTDIR="${pkgdir}" install
  33
  34     # For some reason -DLIBDIR=lib causes libsoci_empty.so to disappear
  35     if [ -e "${pkgdir}/usr/lib64" ]; then
  36         mv "${pkgdir}/usr/lib64" "${pkgdir}/usr/lib"
  37     fi
  38     install -Dm0644 "${srcdir}/${pkgname}-${pkgver}/LICENSE_1_0.txt" \
  39         "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
  40 }