gvfs-lite/PKGBUILD

   1 # Contributor: Nathan Hulse <nat.hulse@gmail.com>
   2
   3 _getthis=gvfs
   4 pkgname=gvfs-lite
   5 pkgver=1.10.1
   6 pkgrel=1
   7 arch=('i686' 'x86_64')
   8 pkgdesc="Userspace virtual filesystem implemented as a pluggable module for gio"
   9 provides=('gvfs')
  10 conflicts=('gvfs')
  11 optdepends=('gvfs-smb-lite: SMB/CIFS (Windows client) support'
  12             'gvfs-obexftp-lite: ObexFTP (bluetooth) support')
  13 install=gvfs.install
  14 license=('LGPL')
  15 makedepends=('fuse>=2.8.4' 'bluez>=4.77' 'smbclient>=3.5.5' 'pkgconfig' 'intltool')
  16 url="http://www.gnome.org"
  17 options=(!libtool)
  18 source=(http://ftp.gnome.org/pub/gnome/sources/${_getthis}/1.10/${_getthis}-${pkgver}.tar.bz2)
  19 md5sums=('7ca2acfa4dffd94b95f4b8713a346607')
  20 sha256sums=('417a15e53fc20c2e1a1de5ea5903430b0ac2e98178d2fcbcfc8fba3082e801ea')
  21
  22 build() {
  23   cd "${srcdir}/${_getthis}-${pkgver}"
  24   ./configure --prefix=/usr --sysconfdir=/etc \
  25       --localstatedir=/var --disable-static \
  26       --libexecdir=/usr/lib/gvfs \
  27       --with-bash-completion-dir=/etc/bash_completion.d
  28   make
  29 }
  30
  31 package() {
  32   cd "${srcdir}/${_getthis}-${pkgver}"
  33   sed -e 's/^am__append_3/#am__append_3/' \
  34       -e 's/^am__append_4/#am__append_4/' \
  35       -i monitor/Makefile
  36   make DESTDIR="${pkgdir}" install
  37   cd "${pkgdir}"
  38   rm -f usr/lib/gvfs/gvfsd-{smb,smb-browse,afc,gphoto2,obexftp}
  39   rm -f usr/share/gvfs/mounts/{smb,smb-browse,afc,gphoto2,obexftp}.mount
  40 }
  41
  42
  43
  44
  45
  46
  47