vlc-dev/PKGBUILD

   1 # Maintainer: Det <nimetonmaili at gmail a-dot com>
   2 # Contributor: bxs <bxsbxs@gmail.com>
   3 # Contributor: uwinkelvos <uwinkelvos@gmx.de> (for being such a genius)
   4 # Based on [extra]'s vlc
   5
   6 pkgname=vlc-dev
   7 pkgver=1.2.0pre4
   8 _dlver=1.2.0-pre4
   9 pkgrel=1
  10 pkgdesc="A multi-platform media player - Bleeding edge version"
  11 arch=('i686' 'x86_64')
  12 url="http://www.videolan.org/vlc/"
  13 license=('GPL')
  14 depends=('a52dec' 'desktop-file-utils' 'faad2' 'ffmpeg' 'fluidsynth' 'fribidi' 'libass' 'libcddb' 'libcdio' 'libdca' 'libdvbpsi' 'libdvdnav' 'libmad' 'libmatroska' 'libmodplug' 'libmpcdec' 'libmpeg2' 'libmtp' 'libproxy' 'libshout' 'libupnp' 'libxpm' 'libxv' 'lua' 'mesa' 'qt' 'sdl_image' 'smbclient' 'sysfsutils' 'taglib' 'ttf-freefont' 'xcb-util-keysyms' 'xdg-utils' 'zvbi')
  15 makedepends=('alsa-lib' 'avahi' 'flac' 'gnutls' 'jack' 'kdelibs' 'libavc1394' 'libcaca' 'libdc1394' 'libnotify' 'libpulse' 'libraw1394' 'libtheora' 'libva' 'lirc-utils' 'live-media' 'udev')
  16 optdepends=('avahi: for service discovery using bonjour protocol'
  17             'libavc1394: for devices using the 1394ta AV/C'
  18             'libdc1394: for IEEE 1394 plugin'
  19             'libdvdcss: for decoding encrypted DVDs'
  20             'libnotify: for notification plugin'
  21             'libpulse: PulseAudio support'
  22             'lirc-utils: for lirc plugin'
  23             'kdelibs: KDE Solid hardware integration'
  24             'ncurses: for ncurses interface support'
  25             'libva-driver-intel: back-end for intel cards'
  26             'vdpau-video: VDPAU back-end for Nvidia'
  27             'xvba-video: XvBA backend for ATI/AMD')
  28 provides=("vlc=$pkgver")
  29 conflicts=('vlc' 'vlc-plugin')
  30 replaces=('vlc-plugin')
  31 backup=('usr/share/vlc/lua/http/.hosts'
  32         'usr/share/vlc/lua/http/dialogs/.hosts')
  33 options=('!libtool')
  34 install=vlc-dev.install
  35 # source=("http://download.videolan.org/pub/videolan/vlc/$_dlver/vlc-$_dlver.tar.bz2")
  36 # md5sums=(`curl -s $source.md5 | cut -d " " -f1`)
  37 source=(http://downloads.videolan.org/pub/videolan/testing/vlc-$_dlver/vlc-$_dlver.tar.xz)   ## The 'bleeding edge' line
  38 sha512sums=(`curl -s $source.sha512 | cut -d " " -f1`)                                      ## The 'bleeding edge' line
  39
  40 build() {
  41   cd vlc-$_dlver
  42
  43   sed -i -e 's:truetype/freefont:TTF:g' modules/text_renderer/freetype.c
  44
  45   ./configure --prefix=/usr \
  46               --disable-rpath \
  47               --enable-faad \
  48               --enable-dbus-control \
  49               --enable-nls \
  50               --enable-lirc \
  51               --enable-pvr \
  52               --enable-ncurses \
  53               --enable-upnp \
  54               --enable-realrtsp
  55   make
  56 }
  57
  58 package() {
  59   cd vlc-$_dlver
  60
  61   make DESTDIR="$pkgdir" install
  62
  63   for res in 16 32 48 128; do
  64     install -D -m644 share/icons/${res}x$res/vlc.png "$pkgdir/usr/share/icons/hicolor/${res}x$res/apps/vlc.png"
  65   done
  66 }