geogebra-svn/PKGBUILD

   1 # Current i686 Maintainer: ifaigios <ifaigios_at_gmail_dot_com>
   2 # Contributor: moostik <mooostik_at_gmail_dot_com>
   3
   4 pkgname=geogebra-svn
   5 _realname=geogebra
   6 pkgver=12988
   7 _realver=4.9.4.0
   8 pkgrel=1
   9 pkgdesc="Dynamic mathematics software with interactive graphics, algebra and spreadsheet - SVN version"
  10 arch=('i686' 'x86_64')
  11 url='http://www.geogebra.org/'
  12 license=('custom')
  13         # Application and source code under GPLv3
  14         # Language files and documentation under CC-BY-SA 3.0
  15 depends=('java-runtime' 'shared-mime-info' 'xdg-utils' 'desktop-file-utils' 'hicolor-icon-theme' 'gtk-update-icon-cache')
  16 makedepends=('subversion' 'jdk' 'apache-ant')
  17 optdepends=('geogebra-thumbnail-kde: KDE thumbnailer for GeoGebra')
  18 install="$_realname.install"
  19 provides=('geogebra' 'geogebra-beta' 'geogebra42-beta' 'geogebra5-beta')
  20 conflicts=('geogebra' 'geogebra-beta' 'geogebra42-beta' 'geogebra5-beta')
  21 source=("$_realname.sh")
  22 md5sums=('a0b7c8314b54ff7e945b0c4e1ae83d48')
  23
  24 _svntrunk="http://www.geogebra.org/svn/trunk/$_realname/"
  25 _svnmod="$_realname"
  26
  27 build() {
  28     # SVN checkout
  29   cd $srcdir
  30   if [ -d $_svnmod/.svn ]; then
  31     (cd $_svnmod && svn up -r $pkgver)
  32   else
  33     svn co $_svntrunk --config-dir ./ -r $pkgver $_svnmod
  34   fi
  35
  36   msg "SVN checkout done or server timeout"
  37
  38     # Creating working directory
  39   rm -rf $srcdir/$_svnmod-build
  40   cp -r $srcdir/$_svnmod $srcdir/$_svnmod-build
  41   cd $srcdir/$_svnmod-build
  42
  43   msg "Starting make..."
  44
  45     # Downloading external libraries
  46   ant -f kickstart.xml lib ecj
  47
  48     # Actual build
  49   cd $srcdir/$_svnmod-build/scripts/autobuild
  50   touch autobuild.conf
  51   sh make-vanilla-jars -j /opt/java
  52 }
  53
  54 package() {
  55     # Installing application
  56   cd $srcdir/$_svnmod-build/build
  57   install -dm755 $pkgdir/usr/share/java/$_realname
  58   install -Dm644 *.jar $pkgdir/usr/share/java/$_realname
  59
  60     # Installing launcher
  61   install -Dm755 $srcdir/$_realname.sh $pkgdir/usr/bin/$_realname
  62
  63     # Installing icons
  64   cd $srcdir/$_svnmod-build/icons/hicolor
  65   for i in *; do
  66       install -dm755 $pkgdir/usr/share/icons/hicolor/$i/{apps,mimetypes}
  67       install -Dm644 $i/apps/* $pkgdir/usr/share/icons/hicolor/$i/apps
  68       install -Dm644 $i/mimetypes/* $pkgdir/usr/share/icons/hicolor/$i/mimetypes
  69   done
  70
  71     # Installing menu item
  72   install -Dm644 $srcdir/$_svnmod-build/scripts/autobuild/linux/generic/$_realname.desktop $pkgdir/usr/share/applications/$_realname.desktop
  73
  74     # Installing pixmap
  75   install -dm755 $pkgdir/usr/share/pixmaps
  76   ln -s /usr/share/icons/hicolor/64x64/apps/$_realname.png $pkgdir/usr/share/pixmaps/$_realname.png
  77
  78     # Installing mimetype
  79   install -Dm644 $srcdir/$_svnmod-build/scripts/autobuild/linux/generic/$_realname.xml $pkgdir/usr/share/mime/packages/$_realname.xml
  80
  81     # Installing license
  82   install -Dm644 $srcdir/$_svnmod-build/_LICENSE.txt $pkgdir/usr/share/licenses/$pkgname/LICENSE
  83 }