dcaenc-git/PKGBUILD

   1 # Maintainer: Xiao-Long Chen <chenxiaolong@cxl.epac.to>
   2 pkgname=dcaenc-git
   3 pkgver=20111204
   4 pkgrel=1
   5 pkgdesc="A Free Software (LGPL-licensed) encoder for the DTS Coherent Acoustics audio format."
   6 arch=('x86_64' 'i686')
   7 url="http://aepatrakov.narod.ru/dcaenc/"
   8 license=('LGPL')
   9 depends=('alsa-lib')
  10 makedepends=('git' 'autoconf')
  11 provides=('dcaenc')
  12 conflicts=('dcaenc')
  13 options=('!libtool')
  14
  15 _gitroot="git://gitorious.org/dtsenc/dtsenc.git"
  16 _gitname="dtsenc"
  17
  18 build() {
  19   cd "${srcdir}"
  20
  21   if [[ -d "${_gitname}" ]]; then
  22     cd "${_gitname}" && git pull origin
  23     msg "The local files are updated."
  24   else
  25     git clone "${_gitroot}" "${_gitname}"
  26   fi
  27
  28   msg "GIT checkout done or server timeout"
  29   msg "Starting build..."
  30
  31   rm -rf "${srcdir}/${_gitname}-build"
  32   git clone "${srcdir}/${_gitname}" "${srcdir}/${_gitname}-build"
  33   cd "${srcdir}/${_gitname}-build"
  34
  35   autoreconf -vfi
  36   ./configure --prefix=/usr
  37   make
  38 }
  39
  40 check() {
  41   cd "${srcdir}/${_gitname}-build"
  42   make -k check
  43 }
  44
  45 package() {
  46   cd "${srcdir}/${_gitname}-build"
  47   make DESTDIR="${pkgdir}/" install
  48 }
  49
  50 # vim:set ts=2 sw=2 et: