desura/PKGBUILD

   1 # Maintainer: Kirill "reflexing" Churin <reflexing@reflexing.ru>
   2 # Contributor: Wido <widowild [at] myopera [dot] com>
   3
   4 pkgname=desura
   5 pkgver=1
   6 pkgrel=18
   7 pkgdesc='A community-driven digital distribution service for gamers'
   8 url='http://desura.com/'
   9 license=('custom: "commercial"')
  10 arch=('i686' 'x86_64')
  11 install=${pkgname}.install
  12 options=()
  13 depends=(lsb-release orbit2 gtk2 libjpeg6 libpng12 libx11 libxpm libxcb libxau libxdmcp desktop-file-utils xdg-utils)
  14 optdepends=('java-runtime: adds java support'
  15             'mono: Free implementation of the .NET platform')
  16
  17 if [[ $CARCH == i686 ]]; then
  18   optdepends+=('nvidia-utils: If you have nvidia graphics'
  19               'catalyst-utils: If you have ATI graphics'
  20               'glew1.5: if you have install M.A.R.S - a ridiculous shooter'
  21               'adobe-air: for Adobe Air-based games')
  22
  23   md5sums=('38a3aa1b69189418e823059072da7739'
  24            '6f8d2745304da5822762ae84f23e38a2'
  25            '323fe242e871e8e07e511b0a0357159c'
  26            'd74bf6e5275c0529470593872749a09d')
  27 else
  28   optdepends+=('lib32-nvidia-utils: If you have nvidia graphics'
  29               'lib32-catalyst-utils: If you have ATI graphics'
  30               'lib32-curl: if you have install TRAUMA '
  31               'lib32-nss: if you have install TRAUMA'
  32               'glew1.5: if you have install M.A.R.S - a ridiculous shooter'
  33               'bin32-adobe-air: for Adobe Air-based games')
  34
  35   md5sums=('3cee8a2935bc1cd61523aaaf23de8e2c'
  36            '6f8d2745304da5822762ae84f23e38a2'
  37            '323fe242e871e8e07e511b0a0357159c'
  38            'd74bf6e5275c0529470593872749a09d')
  39 fi
  40
  41 source=(http://www.desura.com/desura-${CARCH}.tar.gz ${pkgname}.sh ${pkgname}.desktop ${pkgname}.png)
  42
  43 package(){
  44   cd ${srcdir}
  45
  46   # Change permissions
  47   install -dm775 -g users ${pkgdir}/opt/${pkgname}
  48
  49   # Install Desura
  50   install -Dm755 ${pkgname}/${pkgname} \
  51     ${pkgdir}/opt/${pkgname}/${pkgname}
  52
  53   # Install launcher
  54   install -Dm 755 ${pkgname}.sh \
  55     ${pkgdir}/usr/bin/${pkgname}
  56
  57   # Install bootstrapper icon
  58   install -m644 -D \
  59     ${pkgname}.png \
  60     ${pkgdir}/usr/share/icons/hicolor/256x256/apps/${pkgname}.png
  61
  62   # Install bootstrapper desktop file
  63   desktop-file-install -m 644 --dir ${pkgdir}/usr/share/applications/ ${pkgname}.desktop
  64 }