avr-libc-svn/PKGBUILD

   1 # $Id$
   2 # Contributor: Corrado Primier <bardo@aur.archlinux.org>
   3 # Contributor: danst0 <danst0@west.de>
   4 # Contributor: Tim Besard <tim.besard@gmail.com>
   5
   6 pkgname=avr-libc-svn
   7 pkgver=2248
   8 pkgrel=1
   9 pkgdesc="The C runtime library for the AVR family of microcontrollers"
  10 arch=('any')
  11 url="http://savannah.nongnu.org/projects/avr-libc/"
  12 license=('custom')
  13 depends=('gcc-avr')
  14 provides=('avr-libc')
  15 conflicts=('avr-libc')
  16 source=()
  17 md5sums=()
  18
  19 _svntrunk=svn://svn.savannah.nongnu.org/avr-libc/trunk/avr-libc
  20 _svnmod=avr-libc
  21
  22 build() {
  23   cd "$srcdir"
  24
  25   if [ -d $_svnmod/.svn ]; then
  26     (cd $_svnmod && svn up -r $pkgver)
  27   else
  28     svn co $_svntrunk --config-dir ./ -r $pkgver $_svnmod
  29   fi
  30
  31   msg "SVN checkout done or server timeout"
  32   msg "Starting make..."
  33
  34
  35   rm -rf "$srcdir/$_svnmod-build"
  36   cp -r "$srcdir/$_svnmod" "$srcdir/$_svnmod-build"
  37   cd "$srcdir/$_svnmod-build"
  38
  39   ./bootstrap
  40   ./configure --build=$(./config.guess) --host=avr --prefix=/usr
  41   make
  42 }
  43
  44 package() {
  45   cd "$srcdir/$_svnmod-build"
  46   make DESTDIR=${pkgdir} install
  47
  48   install -Dm644 LICENSE ${pkgdir}/usr/share/licenses/${pkgname}/COPYING
  49 }
  50
  51 # vim:set ts=2 sw=2 et: