upse-hg/PKGBUILD

   1 # Maintainer: Christopher Rosell <chrippa@tanuki.se>
   2
   3 # aur split package hacks
   4 pkgname='upse-hg'
   5 true && pkgname=(libupse-hg upse123-hg)
   6
   7 pkgbase='upse-hg'
   8 pkgver=227
   9 pkgrel=1
  10 pkgdesc='UPSE is an advanced playstation sound emulator which concentrates on sound correctness'
  11 arch=('i686' 'x86_64')
  12 url='http://nenolod.net/projects/upse/'
  13 license=('GPL')
  14 makedepends=(mercurial libao)
  15 source=('makefile-fix.patch')
  16 md5sums=('c839a257ec0c7d8a3ff1e74abe18b7cf')
  17
  18 _hgroot='http://hg.atheme.org/unofficial'
  19 _hgrepo='upse'
  20
  21 build() {
  22   cd "$srcdir"
  23   msg "Connecting to Mercurial server...."
  24
  25   if [[ -d "$_hgrepo" ]]; then
  26     cd "$_hgrepo"
  27     hg pull -u
  28     msg "The local files are updated."
  29   else
  30     hg clone "$_hgroot" "$_hgrepo"
  31   fi
  32
  33   msg "Mercurial checkout done or server timeout"
  34   msg "Starting build..."
  35
  36   rm -rf "$srcdir/$_hgrepo-build"
  37   cp -r "$srcdir/$_hgrepo" "$srcdir/$_hgrepo-build"
  38   cd "$srcdir/$_hgrepo-build"
  39
  40   patch -p1 < $startdir/makefile-fix.patch
  41   ./autogen.sh
  42   ./configure --prefix=/usr --disable-audplugin --enable-ao
  43   make
  44 }
  45
  46 package_libupse-hg() {
  47   provides=(libupse)
  48   conflicts=(libupse)
  49   depends=(zlib)
  50
  51   cd "$srcdir/$_hgrepo-build/src/libupse"
  52   make DESTDIR="$pkgdir/" install
  53 }
  54
  55 package_upse123-hg() {
  56   depends=(libupse-hg libao)
  57   provides=(upse123)
  58   conflicts=(upse123)
  59
  60   cd "$srcdir/$_hgrepo-build/src/upse123"
  61   make DESTDIR="$pkgdir/" install
  62 }
  63
  64
  65 # vim:set ts=2 sw=2 et: