util-linux-aes/PKGBUILD

   1 # Maintainer: xerc <aur[at]xerc.de>
   2 # Contributor: milomouse <vincent[at]fea.st>
   3 # Contributor: judd <jvinet[at]zeroflux.org>
   4 # Contributor: falconindy <d[at]falconindy.com>
   5
   6 _basename=util-linux
   7 pkgname=${_basename}-aes
   8 _basever=2.20
   9 pkgver=${_basever}.1
  10 pkgrel=1
  11 _loopaesdiff=${_basename}-${_basever}-20110905.diff
  12
  13 pkgdesc="Miscellaneous system utilities for Linux, with loop-AES support"
  14 url="http://xerc.de/"
  15 license=('GPL2')
  16 arch=('i686' 'x86_64')
  17 groups=('base')
  18 depends=('bash' 'ncurses>=5.7' 'zlib' 'filesystem')
  19 makedepends=('autoconf' 'automake')
  20 optdepends=('perl: for chkdupexe support')
  21 provides=('linux32' "util-linux=${pkgver}" "util-linux-ng=${pkgver}")
  22 conflicts=('linux32' 'util-linux' 'util-linux-ng' 'e2fsprogs<1.41.8-2')
  23 replaces=('linux32' 'util-linux' 'util-linux-ng')
  24 options=('!libtool')
  25
  26 install=${pkgname}.install
  27 source=(http://ftp.kernel.org/pub/linux/utils/${_basename}/v${_basever}/${_basename}-${pkgver}.tar.bz2
  28         http://loop-aes.sourceforge.net/updates/${_loopaesdiff}.bz2
  29         ${pkgname}.install)
  30
  31 build() {
  32   cd "${srcdir}/${_basename}-${pkgver}"
  33   # hardware clock
  34   sed -e 's%etc/adjtime%var/lib/hwclock/adjtime%' -i hwclock/hwclock.c
  35   # provide loop-AES support
  36   msg "Patching with: ${_loopaesdiff}"
  37   patch -Np1 -i "${srcdir}/${_loopaesdiff}"
  38   msg "Starting autoreconf.."
  39   autoreconf
  40   msg "Starting automake.."
  41   automake
  42   msg "Starting configure.."
  43   ./configure --enable-arch --enable-write --enable-raw --disable-wall --enable-partx
  44   msg "Starting make.."
  45   make
  46 }
  47
  48 package() {
  49   cd "${srcdir}/${_basename}-${pkgver}"
  50   install -dm0755 "${pkgdir}/var/lib/hwclock"
  51   make DESTDIR="${pkgdir}" install
  52 }
  53
  54 md5sums=('079b37517fd4e002a2e6e992e8b4e361'
  55          '3b1b5cbe6dd8c4220aafa59b109a19e9'
  56          '7bfa755b056a0c48a504153a3809cf1c')