i3-wm-16bit/PKGBUILD

   1 # $Id: PKGBUILD 58366 2011-11-12 13:28:03Z ttopper $
   2 # Contributor: Thorsten Töpper <atsutane-tu@freethoughts.de>
   3 # Maintainer: Vladimir Chizhov <master@mirlord.com>
   4
   5 pkgname=i3-wm-16bit
   6 _pkgsourcename=i3
   7 pkgver=4.1
   8 pkgrel=1
   9 pkgdesc="An improved dynamic tiling window manager with 16-bit color support"
  10 arch=('i686' 'x86_64' 'armv7h')
  11 url="http://i3wm.org/"
  12 license=('BSD')
  13 replaces=("i3" "i3bar")
  14 groups=("i3")
  15 depends=('libxcursor' 'libev' 'yajl' 'startup-notification' 'pcre')
  16 makedepends=('bison' 'flex')
  17 optdepends=('rxvt-unicode: The terminal emulator used in the default config.'
  18             'dmenu: As menu.'
  19             'i3lock: For locking your screen.'
  20             'i3status: To display systeminformation with a bar.'
  21             'perl: To migrate your configuration to v4 format.')
  22 options=('docs' '!strip')
  23 source=(http://i3wm.org/downloads/${_pkgsourcename}-${pkgver}.tar.bz2
  24         0001-Color-depth-awareness.patch
  25         0002-16-bit-color-depth-awareness-part-2-for-i3bar.patch)
  26 md5sums=('1a05d605624506c2b4b9f1272fd84a5a'
  27          'da6938310ed77de8f7f2707427d477e5'
  28          '20f17b4de6f5a4d7f735c5b7bb6f9d8a')
  29
  30 build() {
  31   cd "$srcdir/$_pkgsourcename-$pkgver"
  32
  33   patch -Np1 < $srcdir/0001-Color-depth-awareness.patch
  34   patch -Np1 < $srcdir/0002-16-bit-color-depth-awareness-part-2-for-i3bar.patch
  35
  36   # To avoid problems with bison use only a single process
  37   MAKEFLAGS="-j1"
  38   make
  39 }
  40
  41 package() {
  42   cd "$srcdir/$_pkgsourcename-$pkgver"
  43
  44   make DESTDIR="$pkgdir/" install
  45
  46   install -Dm644 man/i3.1 \
  47     ${pkgdir}/usr/share/man/man1/i3.1
  48   install -Dm644 i3bar/doc/i3bar.1 \
  49     ${pkgdir}/usr/share/man/man1/i3bar.1
  50   install -Dm644 man/i3-config-wizard.1 \
  51     ${pkgdir}/usr/share/man/man1/i3-config-wizard.1
  52   install -Dm644 man/i3-input.1 \
  53     ${pkgdir}/usr/share/man/man1/i3-input.1
  54   install -Dm644 man/i3-msg.1 \
  55     ${pkgdir}/usr/share/man/man1/i3-msg.1
  56   install -Dm644 man/i3-migrate-config-to-v4.1 \
  57     ${pkgdir}/usr/share/man/man1/i3-migrate-config-to-v4.1
  58   install -Dm644 man/i3-nagbar.1 \
  59     ${pkgdir}/usr/share/man/man1/i3-nagbar.1
  60   install -Dm644 LICENSE \
  61     ${pkgdir}/usr/share/licenses/${pkgname}/LICENSE
  62
  63   make clean
  64 }
  65
  66 # vim:set ts=2 sw=2 et: