dofus-beta/PKGBUILD

   1 # Contributor: p2k <Patrick.Schneider@uni-ulm.de>
   2 # Contributor: Schtroumpfette <fpeterschmitt@voila.fr>
   3 pkgname=dofus-beta
   4 pkgver=2.4.0
   5 pkgrel=1
   6 pkgdesc="A manga inspired, Massively Multiplayer Online Role-playing Game (MMORPG) for Adobe AIR (beta version)."
   7 url="http://www.dofus.com/"
   8 license=("custom:Dofus License")
   9 arch=('i686' 'x86_64')
  10 source=(DofusInstall.run::http://dl.ak.ankama.com/games/dofus2-beta/setup/setup-base-beta.run
  11         air-generic-launcher.sh
  12         UpLauncher.arch.sh)
  13 if [ "$CARCH" == "x86_64" ];then
  14   depends=('bin32-adobe-air' 'lib32-gtk2' 'lib32-libxt'
  15            'lib32-libjpeg6' 'lib32-libpng12' 'lib32-openssl-compatibility'
  16            'lib32-libldap' 'lib32-gvfs' 'lib32-nss' 'lib32-libxslt'
  17            'lib32-dbus-glib' 'lib32-alsa-lib')
  18 else
  19   depends=('adobe-air-sdk' 'gtk2' 'libxt'
  20            'libjpeg6' 'libpng12' 'openssl-compatibility'
  21            'gvfs' 'nss' 'libxslt' 'alsa-lib')
  22 fi
  23 install=(dofus.install)
  24 md5sums=('246f4bb1b9d69858171618d1b62ec9c0'
  25          'f179eaa5e6e6674b1853cf826fc33c3a'
  26          'ae460da240d653d796e5c8f703d572c0')
  27
  28 build() {
  29   cd "$srcdir"
  30
  31   msg2 "Extracting installer..."
  32   sh ./DofusInstall.run --noexec --keep --target dofus_install
  33 }
  34
  35 package() {
  36   cd "$srcdir/dofus_install"
  37   install_dir="$pkgdir/opt/dofus-beta"
  38   mkdir -p "$install_dir"
  39
  40   msg2 "Installing main applications..."
  41   cp -R Dofus/* "$install_dir"
  42   chmod 0775 "$install_dir/share"
  43   install "$srcdir/air-generic-launcher.sh" "$install_dir/bin/Dofus"
  44   cp -R Reg "$install_dir/share/reg"
  45   chmod 0775 "$install_dir/share/reg" "$install_dir/share/reg/share"
  46   install "$srcdir/air-generic-launcher.sh" "$install_dir/share/reg/bin/Reg"
  47
  48   msg2 "Installing additional content..."
  49   mv "$install_dir/share/reg/share/Reg.swf" "$install_dir/share/reg/Reg.swf"
  50   ln -s ../Reg.swf "$install_dir/share/reg/share/Reg.swf"
  51   ln -s ../content "$install_dir/share/reg/share/content"
  52   ln -s ../config.xml "$install_dir/share/reg/share/config.xml"
  53   install UpLauncher "$install_dir/share/UpLauncher"
  54   install -m 644 uplauncherComponents.xml "$install_dir/share/uplauncherComponents.xml"
  55
  56   msg2 "Installing launcher script..."
  57   install "$srcdir/UpLauncher.arch.sh" "$install_dir/share/UpLauncher.arch.sh"
  58   mkdir -p "$pkgdir/usr/bin"
  59   ln -s /opt/dofus-beta/share/UpLauncher.arch.sh "$pkgdir/usr/bin/dofus-beta"
  60
  61   msg2 "Installing menu icon..."
  62   mkdir -p "$pkgdir/usr/share/applications"
  63   cat > "$pkgdir/usr/share/applications/Dofus-beta.desktop" <<EOF
  64 [Desktop Entry]
  65 Encoding=UTF-8
  66 Type=Application
  67 Name=Dofus
  68 GenericName=Dofus
  69 Comment=Dofus
  70 Icon=/opt/dofus-beta/share/icon/dofus-icon-48.png
  71 Exec=/opt/dofus-beta/share/UpLauncher.arch.sh
  72 Path=/opt/dofus-beta/share/
  73 Categories=Game;RolePlaying;Ankama-Games
  74 EOF
  75
  76   msg2 "Installing licenses..."
  77   mkdir -p "$pkgdir/usr/share/licenses/dofus-beta"
  78   cp -R licenses/*.txt "$pkgdir/usr/share/licenses/dofus-beta"
  79   chmod 0644 "$pkgdir/usr/share/licenses/dofus-beta"/*
  80 }
  81 # vim:set ts=2 sw=2 et: