cf/krb-readline.m4

   1 dnl $Id$
   2 dnl
   3 dnl Tests for readline functions
   4 dnl
   5
   6 dnl el_init
   7
   8 AC_DEFUN([KRB_READLINE],[
   9 AC_FIND_FUNC_NO_LIBS(el_init, edit, [], [], [$LIB_tgetent])
  10 if test "$ac_cv_func_el_init" = yes ; then
  11         AC_CACHE_CHECK(for four argument el_init, ac_cv_func_el_init_four,[
  12                 AC_TRY_COMPILE([#include <stdio.h>
  13                         #include <histedit.h>],
  14                         [el_init("", NULL, NULL, NULL);],
  15                         ac_cv_func_el_init_four=yes,
  16                         ac_cv_func_el_init_four=no)])
  17         if test "$ac_cv_func_el_init_four" = yes; then
  18                 AC_DEFINE(HAVE_FOUR_VALUED_EL_INIT, 1, [Define if el_init takes four arguments.])
  19         fi
  20 fi
  21
  22 dnl readline
  23
  24 ac_foo=no
  25 if test "$with_readline" = yes; then
  26         :
  27 elif test "$ac_cv_func_readline" = yes; then
  28         :
  29 elif test "$ac_cv_func_el_init" = yes; then
  30         ac_foo=yes
  31         LIB_readline="\$(top_builddir)/lib/editline/libel_compat.la \$(LIB_el_init) \$(LIB_tgetent)"
  32 else
  33         LIB_readline="\$(top_builddir)/lib/editline/libeditline.la \$(LIB_tgetent)"
  34 fi
  35 AM_CONDITIONAL(el_compat, test "$ac_foo" = yes)
  36 AC_DEFINE(HAVE_READLINE, 1,
  37         [Define if you have a readline compatible library.])dnl
  38
  39 ])