SConstruct

   1 # -*- python -*-
   2
   3 #
   4 # and there we have it, or do we?
   5 #
   6
   7 import os
   8 import os.path
   9 import sys
  10 import re
  11 import shutil
  12 import glob
  13 import errno
  14 import time
  15 import platform
  16 import string
  17 import commands
  18 from sets import Set
  19 import SCons.Node.FS
  20
  21 SConsignFile()
  22 EnsureSConsVersion(0, 96)
  23
  24 ardour_version = '2.6.1'
  25
  26 subst_dict = { }
  27
  28 #
  29 # Command-line options
  30 #
  31
  32 opts = Options('scache.conf')
  33 opts.AddOptions(
  34     ('ARCH', 'Set architecture-specific compilation flags by hand (all flags as 1 argument)',''),
  35     ('WINDOWS_KEY', 'Set X Modifier (Mod1,Mod2,Mod3,Mod4,Mod5) for "Windows" key', 'Mod4'),
  36     BoolOption('AUDIOUNITS', 'Compile with Apple\'s AudioUnit library. (experimental)', 0),
  37     BoolOption('COREAUDIO', 'Compile with Apple\'s CoreAudio library', 0),
  38     BoolOption('GTKOSX', 'Compile for use with GTK-OSX, not GTK-X11', 0),
  39     BoolOption('OLDFONTS', 'Old school font sizes', 0),
  40     BoolOption('DEBUG', 'Set to build with debugging information and no optimizations', 0),
  41     BoolOption('STL_DEBUG', 'Set to build with Standard Template Library Debugging', 0),
  42     PathOption('DESTDIR', 'Set the intermediate install "prefix"', '/'),
  43     EnumOption('DIST_TARGET', 'Build target for cross compiling packagers', 'auto', allowed_values=('auto', 'i386', 'i686', 'x86_64', 'powerpc', 'tiger', 'panther', 'leopard', 'none' ), ignorecase=2),
  44     BoolOption('DMALLOC', 'Compile and link using the dmalloc library', 0),
  45     BoolOption('EXTRA_WARN', 'Compile with -Wextra, -ansi, and -pedantic.  Might break compilation.  For pedants', 0),
  46     BoolOption('FFT_ANALYSIS', 'Include FFT analysis window', 1),
  47     BoolOption('FREESOUND', 'Include Freesound database lookup', 0),
  48     BoolOption('FPU_OPTIMIZATION', 'Build runtime checked assembler code', 1),
  49     BoolOption('LIBLO', 'Compile with support for liblo library', 1),
  50     BoolOption('NLS', 'Set to turn on i18n support', 1),
  51     PathOption('PREFIX', 'Set the install "prefix"', '/usr/local'),
  52     BoolOption('SURFACES', 'Build support for control surfaces', 1),
  53     BoolOption('WIIMOTE', 'Build the wiimote control surface', 0),
  54     BoolOption('SYSLIBS', 'USE AT YOUR OWN RISK: CANCELS ALL SUPPORT FROM ARDOUR AUTHORS: Use existing system versions of various libraries instead of internal ones', 0),
  55     BoolOption('UNIVERSAL', 'Compile as universal binary.  Requires that external libraries are already universal.', 0),
  56     BoolOption('VERSIONED', 'Add revision information to ardour/gtk executable name inside the build directory', 0),
  57     BoolOption('VST', 'Compile with support for VST', 0),
  58     BoolOption('LV2', 'Compile with support for LV2 (if slv2 is available)', 1),
  59     BoolOption('GPROFILE', 'Compile with support for gprofile (Developers only)', 0),
  60     BoolOption('FREEDESKTOP', 'Install MIME type, icons and .desktop file as per the freedesktop.org spec (requires xdg-utils and shared-mime-info). "scons uninstall" removes associations in desktop database', 0),
  61     BoolOption('TRANZPORT', 'Compile with support for Frontier Designs (if libusb is available)', 1),
  62     BoolOption('AUBIO', "Use Paul Brossier's aubio library for feature detection (if available)", 1)
  63
  64 )
  65
  66 #----------------------------------------------------------------------
  67 # a handy helper that provides a way to merge compile/link information
  68 # from multiple different "environments"
  69 #----------------------------------------------------------------------
  70 #
  71 class LibraryInfo(Environment):
  72     def __init__(self,*args,**kw):
  73         Environment.__init__ (self,*args,**kw)
  74
  75     def Merge (self,others):
  76         for other in others:
  77             self.Append (LIBS = other.get ('LIBS',[]))
  78             self.Append (LIBPATH = other.get ('LIBPATH', []))
  79             self.Append (CPPPATH = other.get('CPPPATH', []))
  80             self.Append (LINKFLAGS = other.get('LINKFLAGS', []))
  81             self.Append (CCFLAGS = other.get('CCFLAGS', []))
  82         self.Replace(LIBPATH = list(Set(self.get('LIBPATH', []))))
  83         self.Replace(CPPPATH = list(Set(self.get('CPPPATH',[]))))
  84         #doing LINKFLAGS breaks -framework
  85         #doing LIBS break link order dependency
  86
  87     def ENV_update(self, src_ENV):
  88         for k in src_ENV.keys():
  89             if k in self['ENV'].keys() and k in [ 'PATH', 'LD_LIBRARY_PATH',
  90                                                   'LIB', 'INCLUDE' ]:
  91                 self['ENV'][k]=SCons.Util.AppendPath(self['ENV'][k], src_ENV[k])
  92             else:
  93                 self['ENV'][k]=src_ENV[k]
  94
  95 env = LibraryInfo (options = opts,
  96                    CPPPATH = [ '.' ],
  97                    VERSION = ardour_version,
  98                    TARBALL='ardour-' + ardour_version + '.tar.bz2',
  99                    DISTFILES = [ ],
 100                    DISTTREE  = '#ardour-' + ardour_version,
 101                    DISTCHECKDIR = '#ardour-' + ardour_version + '/check'
 102                    )
 103
 104 env.ENV_update(os.environ)
 105
 106 #----------------------------------------------------------------------
 107 # Builders
 108 #----------------------------------------------------------------------
 109
 110 # Handy subst-in-file builder
 111 #
 112
 113 def do_subst_in_file(targetfile, sourcefile, dict):
 114     """Replace all instances of the keys of dict with their values.
 115     For example, if dict is {'%VERSION%': '1.2345', '%BASE%': 'MyProg'},
 116     then all instances of %VERSION% in the file will be replaced with 1.2345 etc.
 117     """
 118     try:
 119         f = open(sourcefile, 'rb')
 120         contents = f.read()
 121         f.close()
 122     except:
 123         raise SCons.Errors.UserError, "Can't read source file %s"%sourcefile
 124     for (k,v) in dict.items():
 125         contents = re.sub(k, v, contents)
 126     try:
 127         f = open(targetfile, 'wb')
 128         f.write(contents)
 129         f.close()
 130     except:
 131         raise SCons.Errors.UserError, "Can't write target file %s"%targetfile
 132     return 0 # success
 133
 134 def subst_in_file(target, source, env):
 135     if not env.has_key('SUBST_DICT'):
 136         raise SCons.Errors.UserError, "SubstInFile requires SUBST_DICT to be set."
 137     d = dict(env['SUBST_DICT']) # copy it
 138     for (k,v) in d.items():
 139         if callable(v):
 140             d[k] = env.subst(v())
 141         elif SCons.Util.is_String(v):
 142             d[k]=env.subst(v)
 143         else:
 144             raise SCons.Errors.UserError, "SubstInFile: key %s: %s must be a string or callable"%(k, repr(v))
 145     for (t,s) in zip(target, source):
 146         return do_subst_in_file(str(t), str(s), d)
 147
 148 def subst_in_file_string(target, source, env):
 149     """This is what gets printed on the console."""
 150     return '\n'.join(['Substituting vars from %s into %s'%(str(s), str(t))
 151                       for (t,s) in zip(target, source)])
 152
 153 def subst_emitter(target, source, env):
 154     """Add dependency from substituted SUBST_DICT to target.
 155     Returns original target, source tuple unchanged.
 156     """
 157     d = env['SUBST_DICT'].copy() # copy it
 158     for (k,v) in d.items():
 159         if callable(v):
 160             d[k] = env.subst(v())
 161         elif SCons.Util.is_String(v):
 162             d[k]=env.subst(v)
 163     Depends(target, SCons.Node.Python.Value(d))
 164     # Depends(target, source) # this doesn't help the install-sapphire-linux.sh problem
 165     return target, source
 166
 167 subst_action = Action (subst_in_file, subst_in_file_string)
 168 env['BUILDERS']['SubstInFile'] = Builder(action=subst_action, emitter=subst_emitter)
 169
 170 #
 171 # internationalization
 172 #
 173
 174 # po_builder: builder function to copy po files to the parent directory while updating them
 175 #
 176 # first source:  .po file
 177 # second source: .pot file
 178 #
 179
 180 def po_builder(target,source,env):
 181     os.spawnvp (os.P_WAIT, 'cp', ['cp', str(source[0]), str(target[0])])
 182     args = [ 'msgmerge',
 183              '--update',
 184              str(target[0]),
 185              str(source[1])
 186              ]
 187     print 'Updating ' + str(target[0])
 188     return os.spawnvp (os.P_WAIT, 'msgmerge', args)
 189
 190 po_bld = Builder (action = po_builder)
 191 env.Append(BUILDERS = {'PoBuild' : po_bld})
 192
 193 # mo_builder: builder function for (binary) message catalogs (.mo)
 194 #
 195 # first source:  .po file
 196 #
 197
 198 def mo_builder(target,source,env):
 199     args = [ 'msgfmt',
 200              '-c',
 201              '-o',
 202              target[0].get_path(),
 203              source[0].get_path()
 204              ]
 205     return os.spawnvp (os.P_WAIT, 'msgfmt', args)
 206
 207 mo_bld = Builder (action = mo_builder)
 208 env.Append(BUILDERS = {'MoBuild' : mo_bld})
 209
 210 # pot_builder: builder function for message templates (.pot)
 211 #
 212 # source: list of C/C++ etc. files to extract messages from
 213 #
 214
 215 def pot_builder(target,source,env):
 216     args = [ 'xgettext',
 217              '--keyword=_',
 218              '--keyword=N_',
 219              '--from-code=UTF-8',
 220              '-o', target[0].get_path(),
 221              "--default-domain=" + env['PACKAGE'],
 222              '--copyright-holder="Paul Davis"' ]
 223     args += [ src.get_path() for src in source ]
 224
 225     return os.spawnvp (os.P_WAIT, 'xgettext', args)
 226
 227 pot_bld = Builder (action = pot_builder)
 228 env.Append(BUILDERS = {'PotBuild' : pot_bld})
 229
 230 #
 231 # utility function, not a builder
 232 #
 233
 234 def i18n (buildenv, sources, installenv):
 235     domain = buildenv['PACKAGE']
 236     potfile = buildenv['POTFILE']
 237
 238     installenv.Alias ('potupdate', buildenv.PotBuild (potfile, sources))
 239
 240     p_oze = [ os.path.basename (po) for po in glob.glob ('po/*.po') ]
 241     languages = [ po.replace ('.po', '') for po in p_oze ]
 242
 243     for po_file in p_oze:
 244         buildenv.PoBuild(po_file, ['po/'+po_file, potfile])
 245         mo_file = po_file.replace (".po", ".mo")
 246         installenv.Alias ('install', buildenv.MoBuild (mo_file, po_file))
 247         installenv.Alias ('msgupdate', buildenv.MoBuild (mo_file, po_file))
 248
 249     for lang in languages:
 250         modir = (os.path.join (install_prefix, 'share/locale/' + lang + '/LC_MESSAGES/'))
 251         moname = domain + '.mo'
 252         installenv.Alias('install', installenv.InstallAs (os.path.join (modir, moname), lang + '.mo'))
 253
 254
 255 def fetch_svn_revision (path):
 256     cmd = "LANG= "
 257     cmd += "svn info "
 258     cmd += path
 259     cmd += " | awk '/^Revision:/ { print $2}'"
 260     return commands.getoutput (cmd)
 261
 262 def create_stored_revision (target = None, source = None, env = None):
 263     if os.path.exists('.svn'):
 264         rev = fetch_svn_revision ('.');
 265         try:
 266             text  = "#include <ardour/svn_revision.h>\n"
 267             text += "namespace ARDOUR {\n";
 268             text += "extern const char* svn_revision = \"" + rev + "\";\n";
 269             text += "}\n";
 270             print '============> writing svn revision info to libs/ardour/svn_revision.cc\n'
 271             o = file ('libs/ardour/svn_revision.cc', 'w')
 272             o.write (text)
 273             o.close ()
 274         except IOError:
 275             print "Could not open libs/ardour/svn_revision.cc for writing\n"
 276             sys.exit (-1)
 277     else:
 278         if not os.path.exists('libs/ardour/ardour/svn_revision.h'):
 279             print "This release of ardour is missing libs/ardour/ardour/svn_revision.h. Blame the packager."
 280             sys.exit (-1)
 281
 282 #
 283 # A generic builder for version.cc files
 284 #
 285 # note: requires that DOMAIN, MAJOR, MINOR, MICRO are set in the construction environment
 286 # note: assumes one source files, the header that declares the version variables
 287 #
 288
 289 def version_builder (target, source, env):
 290
 291     text  = "int " + env['DOMAIN'] + "_major_version = " + str (env['MAJOR']) + ";\n"
 292     text += "int " + env['DOMAIN'] + "_minor_version = " + str (env['MINOR']) + ";\n"
 293     text += "int " + env['DOMAIN'] + "_micro_version = " + str (env['MICRO']) + ";\n"
 294
 295     try:
 296         o = file (target[0].get_path(), 'w')
 297         o.write (text)
 298         o.close ()
 299     except IOError:
 300         print "Could not open", target[0].get_path(), " for writing\n"
 301         sys.exit (-1)
 302
 303     text  = "#ifndef __" + env['DOMAIN'] + "_version_h__\n"
 304     text += "#define __" + env['DOMAIN'] + "_version_h__\n"
 305     text += "extern const char* " + env['DOMAIN'] + "_revision;\n"
 306     text += "extern int " + env['DOMAIN'] + "_major_version;\n"
 307     text += "extern int " + env['DOMAIN'] + "_minor_version;\n"
 308     text += "extern int " + env['DOMAIN'] + "_micro_version;\n"
 309     text += "#endif /* __" + env['DOMAIN'] + "_version_h__ */\n"
 310
 311     try:
 312         o = file (target[1].get_path(), 'w')
 313         o.write (text)
 314         o.close ()
 315     except IOError:
 316         print "Could not open", target[1].get_path(), " for writing\n"
 317         sys.exit (-1)
 318
 319     return None
 320
 321 version_bld = Builder (action = version_builder)
 322 env.Append (BUILDERS = {'VersionBuild' : version_bld})
 323
 324 #
 325 # a builder that makes a hard link from the 'source' executable to a name with
 326 # a "build ID" based on the most recent CVS activity that might be reasonably
 327 # related to version activity. this relies on the idea that the SConscript
 328 # file that builds the executable is updated with new version info and committed
 329 # to the source code repository whenever things change.
 330 #
 331
 332 def versioned_builder(target,source,env):
 333     w, r = os.popen2( "LANG= svn info | awk '/^Revision:/ { print $2}'")
 334
 335     last_revision = r.readline().strip()
 336     w.close()
 337     r.close()
 338     if last_revision == "":
 339         print "No SVN info found - versioned executable cannot be built"
 340         return -1
 341
 342     print "The current build ID is " + last_revision
 343
 344     tagged_executable = source[0].get_path() + '-' + last_revision
 345
 346     if os.path.exists (tagged_executable):
 347         print "Replacing existing executable with the same build tag."
 348         os.unlink (tagged_executable)
 349
 350     return os.link (source[0].get_path(), tagged_executable)
 351
 352 verbuild = Builder (action = versioned_builder)
 353 env.Append (BUILDERS = {'VersionedExecutable' : verbuild})
 354
 355 #
 356 # source tar file builder
 357 #
 358
 359 def distcopy (target, source, env):
 360     treedir = str (target[0])
 361
 362     try:
 363         os.mkdir (treedir)
 364     except OSError, (errnum, strerror):
 365         if errnum != errno.EEXIST:
 366             print 'mkdir ', treedir, ':', strerror
 367
 368     cmd = 'tar cf - '
 369     #
 370     # we don't know what characters might be in the file names
 371     # so quote them all before passing them to the shell
 372     #
 373     all_files = ([ str(s) for s in source ])
 374     cmd += " ".join ([ "'%s'" % quoted for quoted in all_files])
 375     cmd += ' | (cd ' + treedir + ' && tar xf -)'
 376     p = os.popen (cmd)
 377     return p.close ()
 378
 379 def tarballer (target, source, env):
 380     cmd = 'tar -jcf ' + str (target[0]) +  ' ' + str(source[0]) + "  --exclude '*~'" + " --exclude .svn --exclude '.svn/*'"
 381     print 'running ', cmd, ' ... '
 382     p = os.popen (cmd)
 383     return p.close ()
 384
 385 dist_bld = Builder (action = distcopy,
 386                     target_factory = SCons.Node.FS.default_fs.Entry,
 387                     source_factory = SCons.Node.FS.default_fs.Entry,
 388                     multi = 1)
 389
 390 tarball_bld = Builder (action = tarballer,
 391                        target_factory = SCons.Node.FS.default_fs.Entry,
 392                        source_factory = SCons.Node.FS.default_fs.Entry)
 393
 394 env.Append (BUILDERS = {'Distribute' : dist_bld})
 395 env.Append (BUILDERS = {'Tarball' : tarball_bld})
 396
 397 #
 398 # Make sure they know what they are doing
 399 #
 400
 401 if env['VST']:
 402     if os.path.isfile('.personal_use_only'):
 403         print "Enabling VST support. Note that distributing a VST-enabled ardour\nis a violation of several different licences.\nBuild with VST=false if you intend to distribute ardour to others."
 404     else:
 405         sys.stdout.write ("Are you building Ardour for personal use (rather than distribution to others)? [no]: ")
 406         answer = sys.stdin.readline ()
 407         answer = answer.rstrip().strip()
 408         if answer == "yes" or answer == "y":
 409             fh = open('.personal_use_only', 'w')
 410             fh.close()
 411             print "OK, VST support will be enabled"
 412         else:
 413             print 'You cannot build Ardour with VST support for distribution to others.\nIt is a violation of several different licenses. Build with VST=false.'
 414             sys.exit (-1);
 415 else:
 416     if os.path.isfile('.personal_use_only'):
 417         os.remove('.personal_use_only')
 418
 419 ####################
 420 # push environment
 421 ####################
 422
 423 def pushEnvironment(context):
 424     if os.environ.has_key('PATH'):
 425         context.Append(PATH = os.environ['PATH'])
 426
 427     if os.environ.has_key('PKG_CONFIG_PATH'):
 428         context.Append(PKG_CONFIG_PATH = os.environ['PKG_CONFIG_PATH'])
 429
 430     if os.environ.has_key('CC'):
 431         context['CC'] = os.environ['CC']
 432
 433     if os.environ.has_key('CXX'):
 434         context['CXX'] = os.environ['CXX']
 435
 436     if os.environ.has_key('DISTCC_HOSTS'):
 437         context['ENV']['DISTCC_HOSTS'] = os.environ['DISTCC_HOSTS']
 438         context['ENV']['HOME'] = os.environ['HOME']
 439
 440 pushEnvironment (env)
 441
 442 #######################
 443 # Dependency Checking #
 444 #######################
 445
 446 deps = \
 447 {
 448         'glib-2.0'             : '2.10.1',
 449         'gthread-2.0'          : '2.10.1',
 450         'gtk+-2.0'             : '2.8.1',
 451         'libxml-2.0'           : '2.6.0',
 452         'samplerate'           : '0.1.0',
 453         'raptor'               : '1.4.2',
 454         'lrdf'                 : '0.4.0',
 455         'jack'                 : '0.109.0',
 456         'libgnomecanvas-2.0'   : '2.0',
 457 }
 458
 459 def DependenciesRequiredMessage():
 460         print 'You do not have the necessary dependencies required to build ardour'
 461         print 'Please consult http://ardour.org/building for more information'
 462
 463 def CheckPKGConfig(context, version):
 464     context.Message( 'Checking for pkg-config version >= %s... ' %version )
 465     ret = context.TryAction('pkg-config --atleast-pkgconfig-version=%s' % version)[0]
 466     context.Result( ret )
 467     return ret
 468
 469 def CheckPKGVersion(context, name, version):
 470     context.Message( 'Checking for %s... ' % name )
 471     ret = context.TryAction('pkg-config --atleast-version=%s %s' %(version,name) )[0]
 472     context.Result( ret )
 473     return ret
 474
 475 def CheckPKGExists(context, name):
 476     context.Message ('Checking for %s...' % name)
 477     ret = context.TryAction('pkg-config --exists %s' % name)[0]
 478     context.Result (ret)
 479     return ret
 480
 481 conf = Configure(env, custom_tests = { 'CheckPKGConfig' : CheckPKGConfig,
 482                                        'CheckPKGVersion' : CheckPKGVersion })
 483
 484 # I think a more recent version is needed on win32
 485 min_pkg_config_version = '0.8.0'
 486
 487 if not conf.CheckPKGConfig(min_pkg_config_version):
 488      print 'pkg-config >= %s not found.' % min_pkg_config_version
 489      Exit(1)
 490
 491 for pkg, version in deps.iteritems():
 492         if not conf.CheckPKGVersion( pkg, version ):
 493                 print '%s >= %s not found.' %(pkg, version)
 494                 DependenciesRequiredMessage()
 495                 Exit(1)
 496
 497 env = conf.Finish()
 498
 499 # ----------------------------------------------------------------------
 500 # Construction environment setup
 501 # ----------------------------------------------------------------------
 502
 503 libraries = { }
 504
 505 libraries['core'] = LibraryInfo (CCFLAGS = '-Ilibs')
 506
 507 #libraries['sndfile'] = LibraryInfo()
 508 #libraries['sndfile'].ParseConfig('pkg-config --cflags --libs sndfile')
 509
 510 libraries['lrdf'] = LibraryInfo()
 511 libraries['lrdf'].ParseConfig('pkg-config --cflags --libs lrdf')
 512
 513 libraries['raptor'] = LibraryInfo()
 514 libraries['raptor'].ParseConfig('pkg-config --cflags --libs raptor')
 515
 516 libraries['samplerate'] = LibraryInfo()
 517 libraries['samplerate'].ParseConfig('pkg-config --cflags --libs samplerate')
 518
 519 conf = env.Configure (custom_tests = { 'CheckPKGExists' : CheckPKGExists } )
 520
 521 if conf.CheckPKGExists ('fftw3f'):
 522     libraries['fftw3f'] = LibraryInfo()
 523     libraries['fftw3f'].ParseConfig('pkg-config --cflags --libs fftw3f')
 524
 525 if conf.CheckPKGExists ('fftw3'):
 526     libraries['fftw3'] = LibraryInfo()
 527     libraries['fftw3'].ParseConfig('pkg-config --cflags --libs fftw3')
 528
 529 if conf.CheckPKGExists ('aubio'):
 530     libraries['aubio'] = LibraryInfo()
 531     libraries['aubio'].ParseConfig('pkg-config --cflags --libs aubio')
 532     env['AUBIO'] = 1
 533 else:
 534     env['AUBIO'] = 0
 535
 536 env = conf.Finish ()
 537
 538 if env['FFT_ANALYSIS']:
 539         #
 540         # Check for fftw3 header as well as the library
 541         #
 542
 543         conf = Configure(libraries['fftw3'])
 544
 545         if conf.CheckHeader ('fftw3.h') == False:
 546             print ('Ardour cannot be compiled without the FFTW3 headers, which do not seem to be installed')
 547             sys.exit (1)
 548         conf.Finish()
 549
 550 if env['FREESOUND']:
 551         #
 552         # Check for curl header as well as the library
 553         #
 554
 555         libraries['curl'] = LibraryInfo()
 556
 557         conf = Configure(libraries['curl'])
 558
 559         if conf.CheckHeader ('curl/curl.h') == False:
 560                 print ('Ardour cannot be compiled without the curl headers, which do not seem to be installed')
 561                 sys.exit (1)
 562         else:
 563                 libraries['curl'].ParseConfig('pkg-config --cflags --libs libcurl')
 564         conf.Finish()
 565 else:
 566         print 'FREESOUND support is not enabled.  Build with \'scons FREESOUND=1\' to enable.'
 567
 568 if env['LV2']:
 569         conf = env.Configure(custom_tests = { 'CheckPKGVersion' : CheckPKGVersion})
 570
 571         if conf.CheckPKGVersion('slv2', '0.6.0'):
 572                 libraries['slv2'] = LibraryInfo()
 573                 libraries['slv2'].ParseConfig('pkg-config --cflags --libs slv2')
 574                 env.Append (CCFLAGS="-DHAVE_LV2")
 575         else:
 576                 print 'LV2 support is not enabled (SLV2 not found or older than 0.6.0)'
 577                 env['LV2'] = 0
 578         conf.Finish()
 579 else:
 580         print 'LV2 support is not enabled.  Build with \'scons LV2=1\' to enable.'
 581
 582 if env['WIIMOTE']:
 583         wiimote_surface = [ 'libs/surfaces/wiimote' ]
 584 else:
 585         wiimote_surface = [ ]
 586         print 'WIIMOTE not enabled. Build with \'scons WIIMOTE=1\' to enable support.'
 587
 588 libraries['jack'] = LibraryInfo()
 589 libraries['jack'].ParseConfig('pkg-config --cflags --libs jack')
 590
 591 libraries['xml'] = LibraryInfo()
 592 libraries['xml'].ParseConfig('pkg-config --cflags --libs libxml-2.0')
 593
 594 libraries['xslt'] = LibraryInfo()
 595 libraries['xslt'].ParseConfig('pkg-config --cflags --libs libxslt')
 596
 597 libraries['glib2'] = LibraryInfo()
 598 libraries['glib2'].ParseConfig ('pkg-config --cflags --libs glib-2.0')
 599 libraries['glib2'].ParseConfig ('pkg-config --cflags --libs gobject-2.0')
 600 libraries['glib2'].ParseConfig ('pkg-config --cflags --libs gmodule-2.0')
 601 libraries['glib2'].ParseConfig ('pkg-config --cflags --libs gthread-2.0')
 602
 603 libraries['freetype2'] = LibraryInfo()
 604 libraries['freetype2'].ParseConfig ('pkg-config --cflags --libs freetype2')
 605
 606 libraries['gtk2'] = LibraryInfo()
 607 libraries['gtk2'].ParseConfig ('pkg-config --cflags --libs gtk+-2.0')
 608
 609 libraries['pango'] = LibraryInfo()
 610 libraries['pango'].ParseConfig ('pkg-config --cflags --libs pango')
 611
 612 libraries['libgnomecanvas2'] = LibraryInfo()
 613 libraries['libgnomecanvas2'].ParseConfig ('pkg-config --cflags --libs libgnomecanvas-2.0')
 614
 615 #libraries['flowcanvas'] = LibraryInfo(LIBS='flowcanvas', LIBPATH='#/libs/flowcanvas', CPPPATH='#libs/flowcanvas')
 616
 617 # The Ardour Control Protocol Library
 618
 619 libraries['ardour_cp'] = LibraryInfo (LIBS='ardour_cp', LIBPATH='#libs/surfaces/control_protocol',
 620                                       CPPPATH='#libs/surfaces/control_protocol')
 621
 622 # The Ardour backend/engine
 623
 624 libraries['ardour'] = LibraryInfo (LIBS='ardour', LIBPATH='#libs/ardour', CPPPATH='#libs/ardour')
 625 libraries['midi++2'] = LibraryInfo (LIBS='midi++', LIBPATH='#libs/midi++2', CPPPATH='#libs/midi++2')
 626 libraries['pbd']    = LibraryInfo (LIBS='pbd', LIBPATH='#libs/pbd', CPPPATH='#libs/pbd')
 627 libraries['gtkmm2ext'] = LibraryInfo (LIBS='gtkmm2ext', LIBPATH='#libs/gtkmm2ext', CPPPATH='#libs/gtkmm2ext')
 628
 629
 630 # SCons should really do this for us
 631
 632 conf = env.Configure ()
 633
 634 have_cxx = conf.TryAction (Action (str(env['CXX']) + ' --version'))
 635 if have_cxx[0] != 1:
 636     print "This system has no functional C++ compiler. You cannot build Ardour from source without one."
 637     sys.exit (1)
 638 else:
 639     print "Congratulations, you have a functioning C++ compiler."
 640
 641 env = conf.Finish()
 642
 643
 644 #
 645 # Compiler flags and other system-dependent stuff
 646 #
 647
 648 opt_flags = []
 649 if env['GPROFILE'] == 1:
 650     debug_flags = [ '-g', '-pg' ]
 651 else:
 652     debug_flags = [ '-g' ]
 653
 654 # guess at the platform, used to define compiler flags
 655
 656 config_guess = os.popen("tools/config.guess").read()[:-1]
 657
 658 config_cpu = 0
 659 config_arch = 1
 660 config_kernel = 2
 661 config_os = 3
 662 config = config_guess.split ("-")
 663
 664 print "system triple: " + config_guess
 665
 666 # Autodetect
 667 if env['DIST_TARGET'] == 'auto':
 668     if config[config_arch] == 'apple':
 669         # The [.] matches to the dot after the major version, "." would match any character
 670         if re.search ("darwin[0-7][.]", config[config_kernel]) != None:
 671             env['DIST_TARGET'] = 'panther'
 672         if re.search ("darwin8[.]", config[config_kernel]) != None:
 673             env['DIST_TARGET'] = 'tiger'
 674         else:
 675             env['DIST_TARGET'] = 'leopard'
 676     else:
 677         if re.search ("x86_64", config[config_cpu]) != None:
 678             env['DIST_TARGET'] = 'x86_64'
 679         elif re.search("i[0-5]86", config[config_cpu]) != None:
 680             env['DIST_TARGET'] = 'i386'
 681         elif re.search("powerpc", config[config_cpu]) != None:
 682             env['DIST_TARGET'] = 'powerpc'
 683         else:
 684             env['DIST_TARGET'] = 'i686'
 685     print "\n*******************************"
 686     print "detected DIST_TARGET = " + env['DIST_TARGET']
 687     print "*******************************\n"
 688
 689
 690 if config[config_cpu] == 'powerpc' and env['DIST_TARGET'] != 'none':
 691     #
 692     # Apple/PowerPC optimization options
 693     #
 694     # -mcpu=7450 does not reliably work with gcc 3.*
 695     #
 696     if env['DIST_TARGET'] == 'panther' or env['DIST_TARGET'] == 'tiger':
 697         if config[config_arch] == 'apple':
 698             ## opt_flags.extend ([ "-mcpu=7450", "-faltivec"])
 699             # to support g3s but still have some optimization for above
 700             opt_flags.extend ([ "-mcpu=G3", "-mtune=7450"])
 701         else:
 702             opt_flags.extend ([ "-mcpu=7400", "-maltivec", "-mabi=altivec"])
 703     else:
 704         opt_flags.extend([ "-mcpu=750", "-mmultiple" ])
 705     opt_flags.extend (["-mhard-float", "-mpowerpc-gfxopt"])
 706     opt_flags.extend (["-Os"])
 707
 708 elif ((re.search ("i[0-9]86", config[config_cpu]) != None) or (re.search ("x86_64", config[config_cpu]) != None)) and env['DIST_TARGET'] != 'none':
 709
 710     build_host_supports_sse = 0
 711
 712     if (re.search ("i[0-9]86", config[config_cpu]) != None):
 713         debug_flags.append ("-DARCH_X86")
 714         opt_flags.append ("-DARCH_X86")
 715
 716     if config[config_kernel] == 'linux' :
 717
 718         if env['DIST_TARGET'] != 'i386':
 719
 720             flag_line = os.popen ("cat /proc/cpuinfo | grep '^flags'").read()[:-1]
 721             x86_flags = flag_line.split (": ")[1:][0].split ()
 722
 723             if "mmx" in x86_flags:
 724                 opt_flags.append ("-mmmx")
 725             if "sse" in x86_flags:
 726                 build_host_supports_sse = 1
 727             if "3dnow" in x86_flags:
 728                 opt_flags.append ("-m3dnow")
 729
 730             if config[config_cpu] == "i586":
 731                 opt_flags.append ("-march=i586")
 732             elif config[config_cpu] == "i686":
 733                 opt_flags.append ("-march=i686")
 734
 735     if ((env['DIST_TARGET'] == 'i686') or (env['DIST_TARGET'] == 'x86_64')) and build_host_supports_sse:
 736         opt_flags.extend (["-msse", "-mfpmath=sse", "-DUSE_XMMINTRIN"])
 737         debug_flags.extend (["-msse", "-mfpmath=sse", "-DUSE_XMMINTRIN"])
 738 # end of processor-specific section
 739
 740 # optimization section
 741 if env['FPU_OPTIMIZATION']:
 742     if env['DIST_TARGET'] == 'tiger' or env['DIST_TARGET'] == 'leopard':
 743         opt_flags.append ("-DBUILD_VECLIB_OPTIMIZATIONS");
 744         debug_flags.append ("-DBUILD_VECLIB_OPTIMIZATIONS");
 745         libraries['core'].Append(LINKFLAGS= '-framework Accelerate')
 746     elif env['DIST_TARGET'] == 'i686' or env['DIST_TARGET'] == 'x86_64':
 747         opt_flags.append ("-DBUILD_SSE_OPTIMIZATIONS")
 748         debug_flags.append ("-DBUILD_SSE_OPTIMIZATIONS")
 749         if env['DIST_TARGET'] == 'x86_64':
 750             opt_flags.append ("-DUSE_X86_64_ASM")
 751             debug_flags.append ("-DUSE_X86_64_ASM")
 752         if build_host_supports_sse != 1:
 753             print "\nWarning: you are building Ardour with SSE support even though your system does not support these instructions. (This may not be an error, especially if you are a package maintainer)"
 754 # end optimization section
 755
 756 # handle x86/x86_64 libdir properly
 757
 758 if env['DIST_TARGET'] == 'x86_64':
 759     env['LIBDIR']='lib64'
 760 else:
 761     env['LIBDIR']='lib'
 762
 763 #
 764 # a single way to test if we're on OS X
 765 #
 766
 767 if env['DIST_TARGET'] in ['panther', 'tiger', 'leopard' ]:
 768     env['IS_OSX'] = 1
 769     # force tiger or later, to avoid issues on PPC which defaults
 770     # back to 10.1 if we don't tell it otherwise.
 771     env.Append (CCFLAGS="-DMAC_OS_X_VERSION_MIN_REQUIRED=1040")
 772
 773     if env['DIST_TARGET'] == 'leopard':
 774         # need this to really build against the 10.4 SDK when building on leopard
 775         # ideally this would be configurable, but lets just do that later when we need it
 776         env.Append(CCFLAGS="-mmacosx-version-min=10.4 -isysroot /Developer/SDKs/MacOSX10.4u.sdk")
 777         env.Append(LINKFLAGS="-mmacosx-version-min=10.4 -isysroot /Developer/SDKs/MacOSX10.4u.sdk")
 778
 779 else:
 780     env['IS_OSX'] = 0
 781
 782 #
 783 # save off guessed arch element in an env
 784 #
 785 env.Append(CONFIG_ARCH=config[config_arch])
 786
 787
 788 #
 789 # ARCH="..." overrides all
 790 #
 791
 792 if env['ARCH'] != '':
 793     opt_flags = env['ARCH'].split()
 794
 795 #
 796 # prepend boiler plate optimization flags
 797 #
 798
 799 opt_flags[:0] = [
 800     "-O3",
 801     "-fomit-frame-pointer",
 802     "-ffast-math",
 803     "-fstrength-reduce",
 804     "-pipe"
 805     ]
 806
 807 if env['DEBUG'] == 1:
 808     env.Append(CCFLAGS=" ".join (debug_flags))
 809     env.Append(LINKFLAGS=" ".join (debug_flags))
 810 else:
 811     env.Append(CCFLAGS=" ".join (opt_flags))
 812     env.Append(LINKFLAGS=" ".join (opt_flags))
 813
 814 if env['STL_DEBUG'] == 1:
 815     env.Append(CXXFLAGS="-D_GLIBCXX_DEBUG")
 816
 817 if env['UNIVERSAL'] == 1:
 818     env.Append(CCFLAGS="-arch i386 -arch ppc")
 819     env.Append(LINKFLAGS="-arch i386 -arch ppc")
 820
 821
 822 #
 823 # warnings flags
 824 #
 825
 826 env.Append(CCFLAGS="-Wall")
 827 env.Append(CXXFLAGS="-Woverloaded-virtual")
 828
 829 if env['EXTRA_WARN']:
 830     env.Append(CCFLAGS="-Wextra -pedantic -ansi")
 831     env.Append(CXXFLAGS="-ansi")
 832 #    env.Append(CFLAGS="-iso")
 833
 834 if env['LIBLO']:
 835     env.Append(CCFLAGS="-DHAVE_LIBLO")
 836
 837
 838 #
 839 # fix scons nitpickiness on APPLE
 840 #
 841
 842
 843 def prep_libcheck(topenv, libinfo):
 844     if topenv['IS_OSX']:
 845         #
 846         # rationale: GTK-Quartz uses jhbuild and installs to /opt/gtk by default.
 847         #            All libraries needed should be built against this location
 848         # However.. now jhbuild installs to ~/gtk/inst by default.. changed to accomodate this
 849         if topenv['GTKOSX']:
 850                 GTKROOT = os.path.expanduser ('~/gtk/inst')
 851                 libinfo.Append(CPPPATH= GTKROOT + "/include", LIBPATH= GTKROOT + "/lib")
 852                 libinfo.Append(CXXFLAGS="-I" + GTKROOT + "/include", LINKFLAGS="-L" + GTKROOT + "/lib")
 853         #libinfo.Append(CPPPATH="/opt/local/include", LIBPATH="/opt/local/lib")
 854         #libinfo.Append(CXXFLAGS="-I/opt/local/include", LINKFLAGS="-L/opt/local/lib")
 855
 856 prep_libcheck(env, env)
 857
 858
 859 #
 860 # these are part of the Ardour source tree because they are C++
 861 #
 862
 863 libraries['vamp'] = LibraryInfo (LIBS='vampsdk',
 864                                  LIBPATH='#libs/vamp-sdk',
 865                                  CPPPATH='#libs/vamp-sdk')
 866 libraries['vamphost'] = LibraryInfo (LIBS='vamphostsdk',
 867                                  LIBPATH='#libs/vamp-sdk',
 868                                  CPPPATH='#libs/vamp-sdk')
 869
 870 env['RUBBERBAND'] = False
 871
 872 conf = Configure (env)
 873
 874 if conf.CheckHeader ('fftw3.h'):
 875     env['RUBBERBAND'] = True
 876     libraries['rubberband'] = LibraryInfo (LIBS='rubberband',
 877                                            LIBPATH='#libs/rubberband',
 878                                            CPPPATH='#libs/rubberband',
 879                                            CCFLAGS='-DUSE_RUBBERBAND')
 880 else:
 881     print ""
 882     print "-------------------------------------------------------------------------"
 883     print "You do not have the FFTW single-precision development package installed."
 884     print "This prevents Ardour from using the Rubberband library for timestretching"
 885     print "and pitchshifting. It will fall back on SoundTouch for timestretch, and "
 886     print "pitchshifting will not be available."
 887     print "-------------------------------------------------------------------------"
 888     print ""
 889
 890 conf.Finish()
 891
 892 #
 893 # Check for libusb
 894
 895 libraries['usb'] = LibraryInfo ()
 896 prep_libcheck(env, libraries['usb'])
 897
 898 conf = Configure (libraries['usb'])
 899 if conf.CheckLib ('usb', 'usb_interrupt_write'):
 900     have_libusb = True
 901 else:
 902     have_libusb = False
 903
 904 # check for linux/input.h while we're at it for powermate
 905 if conf.CheckHeader('linux/input.h'):
 906     have_linux_input = True
 907 else:
 908     have_linux_input = False
 909
 910 libraries['usb'] = conf.Finish ()
 911
 912 #
 913 # Check for wiimote dependencies
 914
 915 if env['WIIMOTE']:
 916     wiimoteConf = env.Configure ( )
 917     if not wiimoteConf.CheckHeader('cwiid.h'):
 918         print 'WIIMOTE configured but you are missing libcwiid!'
 919         sys.exit(1)
 920     if not wiimoteConf.CheckHeader('bluetooth/bluetooth.h'):
 921         print 'WIIMOTE configured but you are missing the libbluetooth headers which you need to compile wiimote support!'
 922         sys.exit(1)
 923     wiimoteConf.Finish()
 924
 925
 926 #
 927 # Check for FLAC
 928
 929 libraries['flac'] = LibraryInfo ()
 930 prep_libcheck(env, libraries['flac'])
 931 libraries['flac'].Append(CPPPATH="/usr/local/include", LIBPATH="/usr/local/lib")
 932
 933 #
 934 # june 1st 2007: look for a function that is in FLAC 1.1.2 and not in later versions
 935 #                since the version of libsndfile we have internally does not support
 936 #                the new API that libFLAC has adopted
 937 #
 938
 939 conf = Configure (libraries['flac'])
 940 if conf.CheckLib ('FLAC', 'FLAC__seekable_stream_decoder_init', language='CXX'):
 941     conf.env.Append(CCFLAGS='-DHAVE_FLAC')
 942     use_flac = True
 943 else:
 944     use_flac = False
 945
 946 libraries['flac'] = conf.Finish ()
 947
 948 # or if that fails...
 949 #libraries['flac']    = LibraryInfo (LIBS='FLAC')
 950
 951 # boost (we don't link against boost, just use some header files)
 952
 953 libraries['boost'] = LibraryInfo ()
 954 prep_libcheck(env, libraries['boost'])
 955 libraries['boost'].Append(CPPPATH="/usr/local/include", LIBPATH="/usr/local/lib")
 956 conf = Configure (libraries['boost'])
 957 if conf.CheckHeader ('boost/shared_ptr.hpp', language='CXX') == False:
 958         print "Boost header files do not appear to be installed. You also might be running a buggy version of scons. Try scons 0.97 if you can."
 959         sys.exit (1)
 960
 961 libraries['boost'] = conf.Finish ()
 962
 963 #
 964 # Check for liblo
 965
 966 if env['LIBLO']:
 967     libraries['lo'] = LibraryInfo ()
 968     prep_libcheck(env, libraries['lo'])
 969
 970     conf = Configure (libraries['lo'])
 971     if conf.CheckLib ('lo', 'lo_server_new') == False:
 972         print "liblo does not appear to be installed."
 973         sys.exit (1)
 974
 975     libraries['lo'] = conf.Finish ()
 976
 977 #
 978 # Check for dmalloc
 979
 980 libraries['dmalloc'] = LibraryInfo ()
 981 prep_libcheck(env, libraries['dmalloc'])
 982
 983 #
 984 # look for the threaded version
 985 #
 986
 987 conf = Configure (libraries['dmalloc'])
 988 if conf.CheckLib ('dmallocth', 'dmalloc_shutdown'):
 989     have_libdmalloc = True
 990 else:
 991     have_libdmalloc = False
 992
 993 libraries['dmalloc'] = conf.Finish ()
 994
 995 #
 996 # ensure FREEDESKTOP target is doable..
 997 #
 998
 999 conf = env.Configure ()
1000 if env['FREEDESKTOP']:
1001         have_update_mime_database = conf.TryAction (Action ('update-mime-database -v'))
1002         if have_update_mime_database[0] != 1:
1003                 print "Warning. You have no update-mime-database command in your PATH. FREEDESKTOP is now disabled."
1004                 env['FREEDESKTOP'] = 0
1005         have_gtk_update_icon_cache = conf.TryAction (Action ('gtk-update-icon-cache -?'))
1006         if have_gtk_update_icon_cache[0] != 1:
1007                 print "Warning. You have no gtk-update-icon-cache command in your PATH. FREEDESKTOP is now disabled."
1008                 env['FREEDESKTOP'] = 0
1009         have_update_desktop_database = conf.TryAction (Action ('update-desktop-database -?'))
1010         if have_update_desktop_database[0] != 1:
1011                 print "Warning. You have no update-desktop-database command in your PATH. FREEDESKTOP is now disabled."
1012                 env['FREEDESKTOP'] = 0
1013 env = conf.Finish()
1014
1015 #
1016 # Audio/MIDI library (needed for MIDI, since audio is all handled via JACK)
1017 #
1018
1019 conf = Configure(env)
1020
1021 if conf.CheckCHeader('alsa/asoundlib.h'):
1022     libraries['sysmidi'] = LibraryInfo (LIBS='asound')
1023     env['SYSMIDI'] = 'ALSA Sequencer'
1024     subst_dict['%MIDITAG%'] = "seq"
1025     subst_dict['%MIDITYPE%'] = "alsa/sequencer"
1026 elif conf.CheckCHeader('/System/Library/Frameworks/CoreMIDI.framework/Headers/CoreMIDI.h'):
1027     # this line is needed because scons can't handle -framework in ParseConfig() yet.
1028     if env['GTKOSX']:
1029         # We need Carbon as well as the rest
1030         libraries['sysmidi'] = LibraryInfo (
1031                 LINKFLAGS = ' -framework CoreMIDI -framework CoreFoundation -framework CoreAudio -framework CoreServices -framework AudioUnit -framework AudioToolbox -framework Carbon -bind_at_load' )
1032     else:
1033         libraries['sysmidi'] = LibraryInfo (
1034                 LINKFLAGS = ' -framework CoreMIDI -framework CoreFoundation -framework CoreAudio -framework CoreServices -framework AudioUnit -framework AudioToolbox -bind_at_load' )
1035     env['SYSMIDI'] = 'CoreMIDI'
1036     subst_dict['%MIDITAG%'] = "ardour"
1037     subst_dict['%MIDITYPE%'] = "coremidi"
1038 else:
1039     print "It appears you don't have the required MIDI libraries installed. For Linux this means you are missing the development package for ALSA libraries."
1040     sys.exit (1)
1041
1042 env = conf.Finish()
1043
1044 if env['SYSLIBS']:
1045
1046     syslibdeps = \
1047     {
1048         'sigc++-2.0'           : '2.0',
1049         'gtkmm-2.4'            : '2.8',
1050         'libgnomecanvasmm-2.6' : '2.12.0'
1051     }
1052
1053     conf = Configure(env, custom_tests = { 'CheckPKGConfig' : CheckPKGConfig,
1054                     'CheckPKGVersion' : CheckPKGVersion })
1055
1056     for pkg, version in syslibdeps.iteritems():
1057         if not conf.CheckPKGVersion( pkg, version ):
1058             print '%s >= %s not found.' %(pkg, version)
1059             DependenciesRequiredMessage()
1060             Exit(1)
1061
1062     env = conf.Finish()
1063
1064     libraries['sigc2'] = LibraryInfo()
1065     libraries['sigc2'].ParseConfig('pkg-config --cflags --libs sigc++-2.0')
1066     libraries['glibmm2'] = LibraryInfo()
1067     libraries['glibmm2'].ParseConfig('pkg-config --cflags --libs glibmm-2.4')
1068     libraries['cairomm'] = LibraryInfo()
1069     libraries['cairomm'].ParseConfig('pkg-config --cflags --libs cairomm-1.0')
1070     libraries['gdkmm2'] = LibraryInfo()
1071     libraries['gdkmm2'].ParseConfig ('pkg-config --cflags --libs gdkmm-2.4')
1072     libraries['gtkmm2'] = LibraryInfo()
1073     libraries['gtkmm2'].ParseConfig ('pkg-config --cflags --libs gtkmm-2.4')
1074     libraries['atkmm'] = LibraryInfo()
1075     libraries['atkmm'].ParseConfig ('pkg-config --cflags --libs atkmm-1.6')
1076     libraries['pangomm'] = LibraryInfo()
1077     libraries['pangomm'].ParseConfig ('pkg-config --cflags --libs pangomm-1.4')
1078     libraries['libgnomecanvasmm'] = LibraryInfo()
1079     libraries['libgnomecanvasmm'].ParseConfig ('pkg-config --cflags --libs libgnomecanvasmm-2.6')
1080
1081 #
1082 # cannot use system one for the time being
1083 #
1084
1085     libraries['sndfile-ardour'] = LibraryInfo(LIBS='libsndfile-ardour',
1086                                     LIBPATH='#libs/libsndfile',
1087                                     CPPPATH=['#libs/libsndfile/src'])
1088
1089 #    libraries['libglademm'] = LibraryInfo()
1090 #    libraries['libglademm'].ParseConfig ('pkg-config --cflags --libs libglademm-2.4')
1091
1092 #    libraries['flowcanvas'] = LibraryInfo(LIBS='flowcanvas', LIBPATH='#/libs/flowcanvas', CPPPATH='#libs/flowcanvas')
1093     libraries['soundtouch'] = LibraryInfo()
1094     libraries['soundtouch'].ParseConfig ('pkg-config --cflags --libs soundtouch-1.0')
1095     # Comment the previous line and uncomment this for old versions of Debian:
1096     #libraries['soundtouch'].ParseConfig ('pkg-config --cflags --libs libSoundTouch')
1097
1098     libraries['appleutility'] = LibraryInfo(LIBS='libappleutility',
1099                                             LIBPATH='#libs/appleutility',
1100                                             CPPPATH='#libs/appleutility')
1101
1102     coredirs = [
1103         'templates',
1104         'manual'
1105     ]
1106
1107     subdirs = [
1108         'libs/libsndfile',
1109         'libs/pbd',
1110         'libs/midi++2',
1111         'libs/ardour',
1112         'libs/vamp-sdk',
1113         'libs/vamp-plugins/',
1114     # these are unconditionally included but have
1115     # tests internally to avoid compilation etc
1116     # if VST is not set
1117         'libs/fst',
1118         'vst',
1119     # this is unconditionally included but has
1120     # tests internally to avoid compilation etc
1121     # if COREAUDIO is not set
1122         'libs/appleutility'
1123         ]
1124
1125     gtk_subdirs = [
1126 #        'libs/flowcanvas',
1127         'libs/gtkmm2ext',
1128         'gtk2_ardour',
1129         'libs/clearlooks'
1130         ]
1131
1132 else:
1133     libraries['sigc2'] = LibraryInfo(LIBS='sigc++2',
1134                                     LIBPATH='#libs/sigc++2',
1135                                     CPPPATH='#libs/sigc++2')
1136     libraries['glibmm2'] = LibraryInfo(LIBS='glibmm2',
1137                                     LIBPATH='#libs/glibmm2',
1138                                     CPPPATH='#libs/glibmm2')
1139     libraries['pangomm'] = LibraryInfo(LIBS='pangomm',
1140                                     LIBPATH='#libs/gtkmm2/pango',
1141                                     CPPPATH='#libs/gtkmm2/pango')
1142     libraries['cairomm'] = LibraryInfo(LIBS='cairomm',
1143                                     LIBPATH='#libs/cairomm',
1144                                     CPPPATH='#libs/cairomm')
1145     libraries['atkmm'] = LibraryInfo(LIBS='atkmm',
1146                                      LIBPATH='#libs/gtkmm2/atk',
1147                                      CPPPATH='#libs/gtkmm2/atk')
1148     libraries['gdkmm2'] = LibraryInfo(LIBS='gdkmm2',
1149                                       LIBPATH='#libs/gtkmm2/gdk',
1150                                       CPPPATH='#libs/gtkmm2/gdk')
1151     libraries['gtkmm2'] = LibraryInfo(LIBS='gtkmm2',
1152                                      LIBPATH="#libs/gtkmm2/gtk",
1153                                      CPPPATH='#libs/gtkmm2/gtk/')
1154     libraries['libgnomecanvasmm'] = LibraryInfo(LIBS='libgnomecanvasmm',
1155                                                 LIBPATH='#libs/libgnomecanvasmm',
1156                                                 CPPPATH='#libs/libgnomecanvasmm')
1157
1158     libraries['soundtouch'] = LibraryInfo(LIBS='soundtouch',
1159                                           LIBPATH='#libs/soundtouch',
1160                                           CPPPATH=['#libs', '#libs/soundtouch'])
1161     libraries['sndfile-ardour'] = LibraryInfo(LIBS='libsndfile-ardour',
1162                                     LIBPATH='#libs/libsndfile',
1163                                     CPPPATH=['#libs/libsndfile', '#libs/libsndfile/src'])
1164 #    libraries['libglademm'] = LibraryInfo(LIBS='libglademm',
1165 #                                          LIBPATH='#libs/libglademm',
1166 #                                          CPPPATH='#libs/libglademm')
1167     libraries['appleutility'] = LibraryInfo(LIBS='libappleutility',
1168                                             LIBPATH='#libs/appleutility',
1169                                             CPPPATH='#libs/appleutility')
1170
1171     coredirs = [
1172         'templates',
1173         'manual'
1174     ]
1175
1176     subdirs = [
1177         'libs/sigc++2',
1178         'libs/libsndfile',
1179         'libs/pbd',
1180         'libs/midi++2',
1181         'libs/ardour',
1182         'libs/vamp-sdk',
1183         'libs/vamp-plugins/',
1184     # these are unconditionally included but have
1185     # tests internally to avoid compilation etc
1186     # if VST is not set
1187         'libs/fst',
1188         'vst',
1189     # this is unconditionally included but has
1190     # tests internally to avoid compilation etc
1191     # if COREAUDIO is not set
1192         'libs/appleutility'
1193         ]
1194
1195     gtk_subdirs = [
1196         'libs/glibmm2',
1197         'libs/gtkmm2/pango',
1198         'libs/gtkmm2/atk',
1199         'libs/gtkmm2/gdk',
1200         'libs/gtkmm2/gtk',
1201         'libs/libgnomecanvasmm',
1202         'libs/gtkmm2ext',
1203         'gtk2_ardour',
1204         'libs/clearlooks'
1205         ]
1206
1207 #
1208 # * always build the LGPL control protocol lib, since we link against it from libardour
1209 # * ditto for generic MIDI
1210 # * tranzport checks whether it should build internally, but we need here so that
1211 #   its included in the tarball
1212 #
1213
1214 surface_subdirs = [ 'libs/surfaces/control_protocol',
1215                     'libs/surfaces/generic_midi',
1216                     'libs/surfaces/tranzport',
1217                     'libs/surfaces/mackie',
1218                     'libs/surfaces/powermate'
1219                     ]
1220 surface_subdirs += wiimote_surface
1221
1222 if env['SURFACES']:
1223     if have_libusb:
1224         env['TRANZPORT'] = 1
1225     else:
1226         env['TRANZPORT'] = 0
1227         print 'Disabled building Tranzport code because libusb could not be found'
1228
1229     if have_linux_input:
1230         env['POWERMATE'] = 1
1231     else:
1232         env['POWERMATE'] = 0
1233         print 'Disabled building Powermate code because linux/input.h could not be found'
1234
1235     if os.access ('libs/surfaces/sony9pin', os.F_OK):
1236         surface_subdirs += [ 'libs/surfaces/sony9pin' ]
1237 else:
1238     env['POWERMATE'] = 0
1239     env['TRANZPORT'] = 0
1240
1241 #
1242 # timestretch libraries
1243 #
1244
1245 timefx_subdirs = ['libs/soundtouch']
1246 if env['RUBBERBAND']:
1247     timefx_subdirs += ['libs/rubberband']
1248
1249 opts.Save('scache.conf', env)
1250 Help(opts.GenerateHelpText(env))
1251
1252 final_prefix = '$PREFIX'
1253
1254 if env['DESTDIR'] :
1255     install_prefix = '$DESTDIR/$PREFIX'
1256 else:
1257     install_prefix = env['PREFIX']
1258
1259 subst_dict['%INSTALL_PREFIX%'] = install_prefix;
1260 subst_dict['%FINAL_PREFIX%'] = final_prefix;
1261 subst_dict['%PREFIX%'] = final_prefix;
1262
1263 if env['PREFIX'] == '/usr':
1264     final_config_prefix = '/etc'
1265 else:
1266     final_config_prefix = env['PREFIX'] + '/etc'
1267
1268 config_prefix = '$DESTDIR' + final_config_prefix
1269
1270 #
1271 # everybody needs this
1272 #
1273
1274 env.Merge ([ libraries['core'] ])
1275
1276
1277 #
1278 # i18n support
1279 #
1280
1281 conf = Configure (env)
1282 if env['NLS']:
1283     nls_error = 'This system is not configured for internationalized applications.  An english-only version will be built:'
1284     print 'Checking for internationalization support ...'
1285     have_gettext = conf.TryAction(Action('xgettext --version'))
1286     if have_gettext[0] != 1:
1287         nls_error += ' No xgettext command.'
1288         env['NLS'] = 0
1289     else:
1290         print "Found xgettext"
1291
1292     have_msgmerge = conf.TryAction(Action('msgmerge --version'))
1293     if have_msgmerge[0] != 1:
1294         nls_error += ' No msgmerge command.'
1295         env['NLS'] = 0
1296     else:
1297         print "Found msgmerge"
1298
1299     if not conf.CheckCHeader('libintl.h'):
1300         nls_error += ' No libintl.h.'
1301         env['NLS'] = 0
1302
1303     if env['NLS'] == 0:
1304         print nls_error
1305     else:
1306         print "International version will be built."
1307 env = conf.Finish()
1308
1309 if env['NLS'] == 1:
1310     env.Append(CCFLAGS="-DENABLE_NLS")
1311
1312 Export('env install_prefix final_prefix config_prefix final_config_prefix libraries i18n ardour_version subst_dict use_flac')
1313
1314 #
1315 # the configuration file may be system dependent
1316 #
1317
1318 conf = env.Configure ()
1319
1320 if conf.CheckCHeader('/System/Library/Frameworks/CoreAudio.framework/Versions/A/Headers/CoreAudio.h'):
1321     subst_dict['%JACK_INPUT%'] = "coreaudio:Built-in Audio:in"
1322     subst_dict['%JACK_OUTPUT%'] = "coreaudio:Built-in Audio:out"
1323 else:
1324     subst_dict['%JACK_INPUT%'] = "alsa_pcm:playback_"
1325     subst_dict['%JACK_OUTPUT%'] = "alsa_pcm:capture_"
1326
1327 # posix_memalign available
1328 if not conf.CheckFunc('posix_memalign'):
1329     print 'Did not find posix_memalign(), using malloc'
1330     env.Append(CCFLAGS='-DNO_POSIX_MEMALIGN')
1331
1332
1333 env = conf.Finish()
1334
1335 # Which GTK tooltips API
1336
1337 gtktestenv = env.Clone ()
1338 gtktestenv.Merge ([
1339         libraries['gtk2']
1340         ])
1341
1342 conf = gtktestenv.Configure ()
1343
1344 if conf.CheckFunc('gtk_widget_set_tooltip_text'):
1345     env.Append (CXXFLAGS='-DGTK_NEW_TOOLTIP_API')
1346
1347 conf.Finish ()
1348
1349
1350 # generate the per-user and system rc files from the same source
1351
1352 sysrcbuild = env.SubstInFile ('ardour_system.rc','ardour.rc.in', SUBST_DICT = subst_dict)
1353
1354 # add to the substitution dictionary
1355
1356 subst_dict['%VERSION%'] = ardour_version[0:3]
1357 subst_dict['%EXTRA_VERSION%'] = ardour_version[3:]
1358 subst_dict['%REVISION_STRING%'] = ''
1359 if os.path.exists('.svn'):
1360     subst_dict['%REVISION_STRING%'] = '.' + fetch_svn_revision ('.') + 'svn'
1361
1362 # specbuild = env.SubstInFile ('ardour.spec','ardour.spec.in', SUBST_DICT = subst_dict)
1363
1364 the_revision = env.Command ('frobnicatory_decoy', [], create_stored_revision)
1365 remove_ardour = env.Command ('frobnicatory_decoy2', [],
1366                              [ Delete ('$PREFIX/etc/ardour2'),
1367                                Delete ('$PREFIX/lib/ardour2'),
1368                                Delete ('$PREFIX/bin/ardour2'),
1369                                Delete ('$PREFIX/share/ardour2')])
1370
1371 env.Alias('revision', the_revision)
1372 env.Alias('install', env.Install(os.path.join(config_prefix, 'ardour2'), 'ardour_system.rc'))
1373 env.Alias('uninstall', remove_ardour)
1374
1375 Default (sysrcbuild)
1376
1377 # source tarball
1378
1379 Precious (env['DISTTREE'])
1380
1381 env.Distribute (env['DISTTREE'],
1382                [ 'SConstruct',
1383                   'COPYING', 'PACKAGER_README', 'README',
1384                   'ardour.rc.in',
1385                   'tools/config.guess',
1386                   'icons/icon/ardour_icon_mac_mask.png',
1387                   'icons/icon/ardour_icon_mac.png',
1388                   'icons/icon/ardour_icon_tango_16px_blue.png',
1389                   'icons/icon/ardour_icon_tango_16px_red.png',
1390                   'icons/icon/ardour_icon_tango_22px_blue.png',
1391                   'icons/icon/ardour_icon_tango_22px_red.png',
1392                   'icons/icon/ardour_icon_tango_32px_blue.png',
1393                   'icons/icon/ardour_icon_tango_32px_red.png',
1394                   'icons/icon/ardour_icon_tango_48px_blue.png',
1395                   'icons/icon/ardour_icon_tango_48px_red.png'
1396                   ] +
1397                 glob.glob ('DOCUMENTATION/AUTHORS*') +
1398                 glob.glob ('DOCUMENTATION/CONTRIBUTORS*') +
1399                 glob.glob ('DOCUMENTATION/TRANSLATORS*') +
1400                 glob.glob ('DOCUMENTATION/BUILD*') +
1401                 glob.glob ('DOCUMENTATION/FAQ*') +
1402                 glob.glob ('DOCUMENTATION/README*')
1403                 )
1404
1405 srcdist = env.Tarball(env['TARBALL'], [ env['DISTTREE'], the_revision ])
1406 env.Alias ('srctar', srcdist)
1407
1408 #
1409 # don't leave the distree around
1410 #
1411
1412 env.AddPreAction (env['DISTTREE'], Action ('rm -rf ' + str (File (env['DISTTREE']))))
1413 env.AddPostAction (srcdist, Action ('rm -rf ' + str (File (env['DISTTREE']))))
1414
1415 #
1416 # Update revision info before going into subdirs
1417 #
1418
1419 create_stored_revision()
1420
1421 #
1422 # the subdirs
1423 #
1424
1425 for subdir in coredirs:
1426     SConscript (subdir + '/SConscript')
1427
1428 for sublistdir in [ subdirs, timefx_subdirs, gtk_subdirs, surface_subdirs ]:
1429     for subdir in sublistdir:
1430         SConscript (subdir + '/SConscript')
1431
1432 # cleanup
1433 env.Clean ('scrub', [ 'scache.conf', '.sconf_temp', '.sconsign.dblite', 'config.log'])
1434