dleyna-renderer/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2
   3 pkgname=dleyna-renderer
   4 pkgver=0.7.2
   5 pkgrel=1
   6 pkgdesc="Library to discover and manipulate Digital Media Renderers"
   7 url="https://github.com/phako/dleyna-renderer"
   8 arch=(x86_64)
   9 license=(LGPL2.1)
  10 depends=(dleyna-connector-dbus gupnp-av gupnp-dlna libsoup)
  11 makedepends=(git meson docbook-xsl)
  12 _commit=a6fb8c077aba1465d978174f91d17b3dcfc87cd4  # tags/v0.7.2^0
  13 source=("git+https://github.com/phako/dleyna-renderer#commit=$_commit")
  14 sha256sums=('SKIP')
  15
  16 pkgver() {
  17   cd $pkgname
  18   git describe --tags | sed 's/^v//;s/-/+/g'
  19 }
  20
  21 prepare() {
  22   cd $pkgname
  23 }
  24
  25 build() {
  26   arch-meson $pkgname build
  27   meson compile -C build
  28 }
  29
  30 check() {
  31   meson test -C build --print-errorlogs
  32 }
  33
  34 package() {
  35   meson install -C build --destdir "$pkgdir"
  36 }