configure.in

   1 dnl
   2 dnl Process this file with autoconf to produce a configure script
   3 dnl
   4
   5 AC_PREREQ(2.50)
   6 AC_INIT(export_vars.sh.in)
   7
   8 AC_CONFIG_HEADER(include/private/apu_config.h)
   9 AC_CONFIG_AUX_DIR(build)
  10
  11 sinclude(build/apu-conf.m4)
  12 sinclude(build/apu-iconv.m4)
  13 sinclude(build/apu-hints.m4)
  14 sinclude(build/apr_common.m4)
  15 sinclude(build/find_apr.m4)
  16 sinclude(build/dbm.m4)
  17 sinclude(build/dbd.m4)
  18 sinclude(build/ssl.m4)
  19
  20 dnl Generate ./config.nice for reproducing runs of configure
  21 dnl
  22 APR_CONFIG_NICE(config.nice)
  23
  24 dnl # Some initial steps for configuration.  We setup the default directory
  25 dnl # and which files are to be configured.
  26
  27 dnl Absolute source/build directory
  28 abs_srcdir=`(cd $srcdir && pwd)`
  29 abs_builddir=`pwd`
  30
  31 if test "$abs_builddir" != "$abs_srcdir"; then
  32   USE_VPATH=1
  33   APU_CONFIG_LOCATION=build
  34 else
  35   APU_CONFIG_LOCATION=source
  36 fi
  37
  38 AC_SUBST(APU_CONFIG_LOCATION)
  39
  40 AC_CANONICAL_SYSTEM
  41
  42 AC_PROG_INSTALL
  43
  44 dnl
  45 dnl compute the top directory of the build
  46 dnl note: this is needed for LIBTOOL and exporting the bundled Expat
  47 dnl
  48 top_builddir="$abs_builddir"
  49 AC_SUBST(top_builddir)
  50 AC_SUBST(abs_srcdir)
  51 AC_SUBST(abs_builddir)
  52
  53 dnl Initialize mkdir -p functionality.
  54 APR_MKDIR_P_CHECK($abs_srcdir/build/mkdir.sh)
  55
  56 dnl get our version information
  57 get_version="$abs_srcdir/build/get-version.sh"
  58 version_hdr="$abs_srcdir/include/apu_version.h"
  59 APRUTIL_MAJOR_VERSION="`$get_version major $version_hdr APU`"
  60 APRUTIL_DOTTED_VERSION="`$get_version all $version_hdr APU`"
  61
  62 AC_SUBST(APRUTIL_DOTTED_VERSION)
  63 AC_SUBST(APRUTIL_MAJOR_VERSION)
  64
  65 echo "APR-util Version: ${APRUTIL_DOTTED_VERSION}"
  66
  67 dnl Enable the layout handling code, then reparse the prefix-style
  68 dnl arguments due to autoconf being a PITA.
  69 APR_ENABLE_LAYOUT(apr-util)
  70 APR_PARSE_ARGUMENTS
  71
  72 dnl load os-specific hints for apr-util
  73 APU_PRELOAD
  74
  75 dnl
  76 dnl set up the compilation flags and stuff
  77 dnl
  78
  79 APRUTIL_INCLUDES=""
  80 APRUTIL_PRIV_INCLUDES="-I$top_builddir/include -I$top_builddir/include/private"
  81 if test -n "$USE_VPATH"; then
  82     APRUTIL_PRIV_INCLUDES="$APRUTIL_PRIV_INCLUDES -I$abs_srcdir/include/private -I$abs_srcdir/include"
  83 fi
  84
  85 dnl
  86 dnl Find the APR includes directory and (possibly) the source (base) dir.
  87 dnl
  88 APU_FIND_APR
  89
  90 dnl
  91 dnl even though we use apr_rules.mk for building apr-util, we need
  92 dnl to grab CC and CPP ahead of time so that apr-util config tests
  93 dnl use the same compiler as APR; we need the same compiler options
  94 dnl and feature test macros as well
  95 dnl
  96 APR_SETIFNULL(CC, `$apr_config --cc`)
  97 APR_SETIFNULL(CPP, `$apr_config --cpp`)
  98 APR_ADDTO(CFLAGS, `$apr_config --cflags`)
  99 APR_ADDTO(CPPFLAGS, `$apr_config --cppflags`)
 100
 101 dnl
 102 dnl  Find the APR-ICONV directory.
 103 dnl
 104 AC_ARG_WITH(apr-iconv,
 105             [  --with-apr-iconv=DIR    relative path to apr-iconv source],
 106   [ apu_apriconv_dir="$withval"
 107     if test "$apu_apriconv_dir" != "no"; then
 108       if test -d "$apu_apriconv_dir"; then
 109         APR_SUBDIR_CONFIG("$apu_apriconv_dir",
 110                           [$apache_apr_flags \
 111                              --prefix=$prefix \
 112                              --exec-prefix=$exec_prefix \
 113                              --libdir=$libdir \
 114                              --includedir=$includedir \
 115                              --bindir=$bindir \
 116                              --datadir=$datadir \
 117                              --with-installbuilddir=$installbuilddir],
 118                           [--enable-layout=*|\'--enable-layout=*])
 119         APRUTIL_EXPORT_LIBS="$abs_srcdir/$apu_apriconv_dir/lib/libapriconv.la \
 120                              $APRUTIL_EXPORT_LIBS"
 121         APRUTIL_INCLUDES="-I$abs_srcdir/apu_apriconv_dir/include \
 122                           $APRUTIL_INCLUDES"
 123         APR_ICONV_DIR="$apu_apriconv_dir"
 124       else
 125        APR_ICONV_DIR=""
 126       fi
 127     else
 128       APR_ICONV_DIR=""
 129     fi
 130   ])
 131 AC_SUBST(APR_ICONV_DIR)
 132
 133 dnl Find LDAP library
 134 dnl Determine what DBM backend type to use.
 135 dnl Find Expat
 136 dnl Find an iconv library
 137 APU_FIND_LDAP
 138 APU_CHECK_DBM
 139 APU_CHECK_DBD
 140 APU_CHECK_DBD_MYSQL
 141 APU_CHECK_DBD_SQLITE3
 142 APU_CHECK_DBD_SQLITE2
 143 APU_CHECK_DBD_ORACLE
 144 APU_FIND_EXPAT
 145 APU_FIND_ICONV
 146
 147 AC_SEARCH_LIBS(crypt, crypt ufc)
 148 AC_MSG_CHECKING(if system crypt() function is threadsafe)
 149 if test "x$apu_crypt_threadsafe" = "x1"; then
 150   AC_DEFINE(APU_CRYPT_THREADSAFE, 1, [Define if the system crypt() function is threadsafe])
 151   msg="yes"
 152 else
 153   msg="no"
 154 fi
 155 AC_MSG_RESULT([$msg])
 156
 157 AC_CHECK_FUNCS(crypt_r, [ crypt_r="1" ], [ crypt_r="0" ])
 158 if test "$crypt_r" = "1"; then
 159   APU_CHECK_CRYPT_R_STYLE
 160 fi
 161
 162 APU_FIND_SSL
 163
 164 so_ext=$APR_SO_EXT
 165 lib_target=$APR_LIB_TARGET
 166 AC_SUBST(so_ext)
 167 AC_SUBST(lib_target)
 168
 169 APRUTIL_LIBNAME="aprutil${libsuffix}"
 170 AC_SUBST(APRUTIL_LIBNAME)
 171
 172 dnl
 173 dnl Prep all the flags and stuff for compilation and export to other builds
 174 dnl
 175 APR_ADDTO(APRUTIL_LIBS, [$APR_LIBS])
 176
 177 AC_SUBST(APRUTIL_EXPORT_LIBS)
 178 AC_SUBST(APRUTIL_PRIV_INCLUDES)
 179 AC_SUBST(APRUTIL_INCLUDES)
 180 AC_SUBST(APRUTIL_LDFLAGS)
 181 AC_SUBST(APRUTIL_LIBS)
 182 AC_SUBST(LDFLAGS)
 183
 184 dnl copy apr's rules.mk into our build directory.
 185 if test ! -d ./build; then
 186    $mkdir_p build
 187 fi
 188 cp $APR_BUILD_DIR/apr_rules.mk $abs_builddir/build/rules.mk
 189
 190 dnl
 191 dnl BSD/OS (BSDi) needs to use a different include syntax in the Makefiles
 192 dnl
 193 case "$host_alias" in
 194 *bsdi* | BSD/OS)
 195     # Check whether they've installed GNU make
 196     if make --version > /dev/null 2>&1; then
 197         INCLUDE_RULES="include $abs_builddir/build/rules.mk"
 198         INCLUDE_OUTPUTS="include $abs_srcdir/build-outputs.mk"
 199     else
 200         INCLUDE_RULES=".include \"$abs_builddir/build/rules.mk\""
 201         INCLUDE_OUTPUTS=".include \"$abs_srcdir/build-outputs.mk\""
 202     fi
 203     ;;
 204 *)
 205     INCLUDE_RULES="include $abs_builddir/build/rules.mk"
 206     INCLUDE_OUTPUTS="include $abs_srcdir/build-outputs.mk"
 207     ;;
 208 esac
 209 AC_SUBST(INCLUDE_RULES)
 210 AC_SUBST(INCLUDE_OUTPUTS)
 211
 212 for d in include include/private; do
 213     test -d $top_builddir/$d || mkdir $top_builddir/$d
 214 done
 215
 216 AC_CONFIG_FILES([Makefile export_vars.sh
 217                  build/pkg/pkginfo apr-util.pc
 218                  apu-$APRUTIL_MAJOR_VERSION-config:apu-config.in
 219                  include/private/apu_select_dbm.h
 220                  include/apr_ldap.h
 221                  include/apu.h include/apu_want.h])
 222
 223 AC_CONFIG_COMMANDS([default], [
 224 chmod +x apu-$APRUTIL_MAJOR_VERSION-config
 225 ],[
 226 APRUTIL_MAJOR_VERSION=$APRUTIL_MAJOR_VERSION
 227 ])
 228
 229 if test -d $srcdir/test; then
 230     AC_CONFIG_FILES([test/Makefile])
 231 fi
 232
 233 AC_OUTPUT