app-cdr/k3b/k3b-1.0.5-r6.ebuild

   1 # Copyright 1999-2009 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: /var/cvsroot/gentoo-x86/app-cdr/k3b/k3b-1.0.5-r6.ebuild,v 1.5 2009/10/13 17:39:55 ssuominen Exp $
   4
   5 EAPI=2
   6 inherit kde eutils multilib
   7
   8 DESCRIPTION="K3b, KDE CD Writing Software"
   9 HOMEPAGE="http://www.k3b.org/"
  10 SRC_URI="mirror://sourceforge/k3b/${P/_}.tar.bz2"
  11
  12 LICENSE="GPL-2"
  13 SLOT="3.5"
  14 KEYWORDS="amd64 ppc ppc64 x86 ~x86-fbsd"
  15 IUSE="alsa css dvd dvdr encode emovix ffmpeg flac hal mp3 musicbrainz
  16         sndfile vcd vorbis"
  17
  18 COMMON_DEPEND="!<app-cdr/k3b-1.0.5-r5
  19         media-libs/libsamplerate
  20         media-libs/taglib
  21         media-sound/cdparanoia
  22         alsa? ( media-libs/alsa-lib )
  23         dvd? ( media-libs/libdvdread )
  24         encode? ( media-sound/lame )
  25         ffmpeg? ( >=media-video/ffmpeg-0.5 )
  26         flac? ( media-libs/flac[cxx] )
  27         hal? ( sys-apps/hal )
  28         mp3? ( media-libs/libmad )
  29         musicbrainz? ( media-libs/musicbrainz:1 )
  30         sndfile? ( media-libs/libsndfile )
  31         vorbis? ( media-libs/libvorbis )"
  32 RDEPEND="${COMMON_DEPEND}
  33         app-cdr/cdrdao
  34         media-sound/normalize
  35         virtual/cdrtools
  36         dvdr? ( >=app-cdr/dvd+rw-tools-7 )
  37         css? ( media-libs/libdvdcss )
  38         encode? ( media-sound/sox
  39                 media-video/transcode[dvd] )
  40         emovix? ( media-video/emovix )
  41         vcd? ( media-video/vcdimager )"
  42 DEPEND="${COMMON_DEPEND}
  43         dev-util/pkgconfig"
  44
  45 S=${WORKDIR}/${P/_}
  46
  47 need-kde 3.5
  48
  49 PATCHES=(
  50         "${FILESDIR}/${P}-desktop-entry.diff"
  51         "${FILESDIR}/${P}-ffmpeg-0.4.9_p20080326-API.patch"
  52         "${FILESDIR}/${P}-ffmpeg-0.4.9_p20081014-API.patch"
  53         "${FILESDIR}/${P}-transcode-1.1.patch"
  54         "${FILESDIR}/${P}-libmpcdecsv7.patch"
  55 )
  56
  57 I18N="${PN}-i18n-${PV}"
  58
  59 # Supported languages and translated documentation
  60 LANGS="af ar bg br bs ca cs cy da de el en_GB es et eu fa fi fr ga gl he hi hu is it
  61         ja ka lt mk ms nb nds nl nn pa pl pt pt_BR ru rw se sk sr sr@Latn sv ta tr uk
  62         uz zh_CN zh_TW"
  63 for X in ${LANGS}; do
  64         SRC_URI="${SRC_URI} linguas_${X}? ( mirror://sourceforge/k3b/${I18N}.tar.bz2 )"
  65         IUSE="${IUSE} linguas_${X}"
  66 done
  67
  68 src_unpack() {
  69         kde_src_unpack
  70
  71         if [ -d "${WORKDIR}/${I18N}" ]; then
  72                 cd "${WORKDIR}/${I18N}"
  73                 for X in ${LANGS}; do
  74                         use linguas_${X} || rm -rf "${X}"
  75                 done
  76                 rm -f configure
  77         fi
  78         rm -f "${S}"/configure
  79 }
  80
  81 src_configure() {
  82         local myconf="--with-external-libsamplerate
  83                 --without-resmgr
  84                 --without-cdrecord-suid-root
  85                 --without-k3bsetup
  86                 --with-qt-dir=${QTDIR}
  87                 --enable-mt
  88                 --with-qt-libraries=${QTDIR}/$(get_libdir)
  89                 --disable-dependency-tracking
  90                 --without-arts
  91                 $(use_enable debug)
  92                 $(use_with hal)
  93                 $(use_with encode lame)
  94                 $(use_with ffmpeg)
  95                 $(use_with flac)
  96                 $(use_with vorbis oggvorbis)
  97                 $(use_with sndfile)
  98                 $(use_with mp3 libmad)
  99                 --without-musepack
 100                 $(use_with musicbrainz)
 101                 $(use_with dvd libdvdread)
 102                 $(use_with alsa)"
 103
 104         # Build process of K3b
 105         kde_src_configure
 106
 107         # Build process of K3b-i18n
 108         if [[ -d "${WORKDIR}/${I18N}" ]]; then
 109                 myconf="--with-qt-dir=${QTDIR}
 110                         --with-qt-libraries=${QTDIR}/$(get_libdir)
 111                         --disable-dependency-tracking
 112                         --without-arts
 113                         $(use_enable debug)"
 114
 115                 KDE_S="${WORKDIR}/${I18N}"
 116                 kde_src_configure
 117         fi
 118 }
 119
 120 src_compile() {
 121         KDE_S="${S}"
 122         kde_src_compile
 123
 124         if [[ -d "${WORKDIR}/${I18N}" ]]; then
 125                 KDE_S="${WORKDIR}/${I18N}"
 126                 kde_src_compile
 127         fi
 128 }
 129
 130 src_install() {
 131         KDE_S="${S}"
 132         kde_src_install
 133         dodoc FAQ KNOWNBUGS PERMISSIONS || die "dodoc failed"
 134
 135         if [[ -d "${WORKDIR}/${I18N}" ]]; then
 136                 KDE_S="${WORKDIR}/${I18N}"
 137                 kde_src_install
 138         fi
 139 }
 140
 141 pkg_postinst() {
 142         echo
 143         elog "We don't install k3bsetup anymore because Gentoo doesn't need it."
 144         elog "If you get warnings on start-up, uncheck the \"Check system"
 145         elog "configuration\" option in the \"Misc\" settings window."
 146         echo
 147
 148         local group=cdrom
 149         use kernel_linux || group=operator
 150         elog "Make sure you have proper read/write permissions on the cdrom device(s)."
 151         elog "Usually, it is sufficient to be in the ${group} group."
 152         echo
 153 }