x11-misc/xkeyboard-config/xkeyboard-config-2.7-r1.ebuild

   1 # Copyright 1999-2012 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: /var/cvsroot/gentoo-x86/x11-misc/xkeyboard-config/xkeyboard-config-2.7.ebuild,v 1.3 2012/11/18 12:26:23 ago Exp $
   4
   5 EAPI=4
   6
   7 XORG_STATIC=no
   8 inherit xorg-2
   9
  10 EGIT_REPO_URI="git://anongit.freedesktop.org/git/xkeyboard-config"
  11
  12 DESCRIPTION="X keyboard configuration database"
  13 HOMEPAGE="http://www.freedesktop.org/wiki/Software/XKeyboardConfig"
  14 [[ ${PV} == *9999* ]] || SRC_URI="${XORG_BASE_INDIVIDUAL_URI}/data/${PN}/${P}.tar.bz2"
  15
  16 KEYWORDS="~alpha amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc x86 ~amd64-fbsd ~x86-fbsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~sparc-solaris ~x86-solaris"
  17 IUSE=""
  18
  19 LICENSE="MIT"
  20 SLOT="0"
  21
  22 RDEPEND=">=x11-apps/xkbcomp-1.2.3
  23         >=x11-libs/libX11-1.4.3"
  24 DEPEND="${RDEPEND}
  25         dev-util/intltool
  26         >=x11-proto/xproto-7.0.20"
  27
  28 PATCHES=(
  29         "${FILESDIR}"/${P}-cz_prog.patch
  30 )
  31
  32 XORG_CONFIGURE_OPTIONS=(
  33         --with-xkb-base="${EPREFIX}/usr/share/X11/xkb"
  34         --enable-compat-rules
  35         # do not check for runtime deps
  36         --disable-runtime-deps
  37         --with-xkb-rules-symlink=xorg
  38 )
  39
  40 src_prepare() {
  41         xorg-2_src_prepare
  42         if [[ ${XORG_EAUTORECONF} != no ]]; then
  43                 intltoolize --copy --automake || die
  44         fi
  45 }
  46
  47 src_compile() {
  48         # cleanup to make sure .dir files are regenerated
  49         # bug #328455 c#26
  50         xorg-2_src_compile clean
  51         xorg-2_src_compile
  52 }