configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_PREREQ(2.65)
   4
   5 m4_define(anjuta_major_version,  3)
   6 m4_define(anjuta_minor_version, 5)
   7 m4_define(anjuta_micro_version, 5)
   8 m4_define(anjuta_version, anjuta_major_version.anjuta_minor_version.anjuta_micro_version)
   9 m4_define(bugzilla_version, anjuta_major_version.anjuta_minor_version.anjuta_micro_version)
  10
  11 AC_INIT([Anjuta],[anjuta_version],[http://bugzilla.gnome.org/enter_bug.cgi?product=anjuta],[anjuta],[http://www.anjuta.org/])
  12
  13 AC_CONFIG_HEADERS([config.h])
  14 AC_CONFIG_SRCDIR([src/main.c])
  15 AC_CONFIG_MACRO_DIR([m4])
  16
  17
  18 AC_DEFINE(ANJUTA_MAJOR_VERSION, anjuta_major_version, [Anjuta major version])
  19 AC_SUBST(ANJUTA_MAJOR_VERSION, anjuta_major_version)
  20 AC_DEFINE(ANJUTA_MINOR_VERSION, anjuta_minor_version, [Anjuta minor version])
  21 AC_SUBST(ANJUTA_MINOR_VERSION, anjuta_minor_version)
  22 AC_DEFINE(ANJUTA_MICRO_VERSION, anjuta_micro_version, [Anjuta micro version])
  23 AC_SUBST(ANJUTA_MICRO_VERSION, anjuta_micro_version)
  24 AC_DEFINE(ANJUTA_VERSION, anjuta_version, [Anjuta version])
  25 AC_SUBST(ANJUTA_VERSION)
  26
  27 ANJUTA_VERSION=anjuta_version
  28 AC_SUBST(ANJUTA_VERSION)
  29
  30 BUGZILLA_VERSION=bugzilla_version
  31 AC_SUBST(BUGZILLA_VERSION)
  32
  33 dnl Anjuta core
  34 GLIB_REQUIRED=2.32.0
  35 GTK_REQUIRED=3.4.0
  36 GTHREAD_REQUIRED=2.22.0
  37 GDK_PIXBUF_REQUIRED=2.0.0
  38 GDA4_REQUIRED=4.2.0
  39 GDA5_REQUIRED=5.0.0
  40 VTE_REQUIRED=0.27.6
  41 LIBXML_REQUIRED=2.4.23
  42 GDL_REQUIRED=3.5.4
  43 LIBWNCK_REQUIRED=2.12
  44
  45 dnl GtkSourceView
  46 GTKSOURCEVIEW_REQUIRED=3.0.0
  47
  48 dnl Devhelp
  49 LIBDEVHELP_REQUIRED=3.4.2
  50
  51 dnl Glade
  52 GLADEUI_REQUIRED=3.12.0
  53
  54 dnl Introspection
  55 GI_REQUIRED=0.9.5
  56
  57 dnl Various
  58 LIBGRAPHVIZ_REQUIRED=1.0
  59
  60 dnl Subversion plugin
  61 NEON_REQUIRED=0.28.2
  62 SVN_MAJOR=1
  63 SVN_MINOR=5
  64 SVN_PATCH=0
  65 SUBVERSION_REQUIRED=$SVN_MAJOR.$SVN_MINOR.$SVN_PATCH
  66
  67 AM_INIT_AUTOMAKE([1.10 dist-xz no-dist-gzip])
  68 AM_MAINTAINER_MODE([enable])
  69
  70 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  71
  72 dnl Check for C Compiler
  73 AC_PROG_CC
  74 AC_PROG_CPP
  75 AC_PROG_LEX
  76 if test "$LEX" != "flex"; then
  77         AC_MSG_ERROR(flex is required)
  78 fi
  79 AC_PROG_YACC
  80 if test "$YACC" != "bison -y"; then
  81         AC_MSG_ERROR(bison is required)
  82 fi
  83 AC_LANG([C])
  84 AC_LANG([C++])
  85 AC_PROG_CXX
  86 if test "x$ac_ct_CXX" = "x"
  87 then
  88   AC_MSG_ERROR([C++ Compiler required to compile Anjuta])
  89 fi
  90 AM_PROG_CC_C_O
  91
  92 GNOME_COMPILE_WARNINGS([maximum])
  93 AM_CFLAGS="$AM_CFLAGS $WARN_CFLAGS"
  94 AM_CXXFLAGS="$AM_CXXFLAGS $WARN_CXXFLAGS"
  95
  96 dnl Enable debugging mode
  97 AC_ARG_ENABLE(debug,
  98   AS_HELP_STRING([--enable-debug],[Enable debug messages]),
  99   [if test "x$enableval" = "xyes"; then
 100       AM_CFLAGS="$AM_CFLAGS -DDEBUG"
 101   fi]
 102   AM_CXXFLAGS="$AM_CXXFLAGS -DDEBUG")
 103 AC_SUBST(AM_CFLAGS)
 104 AC_SUBST(AM_CXXFLAGS)
 105
 106 ANJUTA_LDFLAGS="-no-undefined"
 107 ANJUTA_PLUGIN_LDFLAGS="-module -avoid-version -no-undefined"
 108 AC_SUBST(ANJUTA_LDFLAGS)
 109 AC_SUBST(ANJUTA_PLUGIN_LDFLAGS)
 110
 111 dnl GSettings
 112 GLIB_GSETTINGS
 113
 114 dnl Disable deprecated APIs
 115 dnl if test x$MAINT = x; then
 116 dnl     DEPRECATED_FLAGS="-DGDK_DISABLE_DEPRECATED -DGTK_DISABLE_DEPRECATED"
 117 dnl     AC_SUBST(DEPRECATED_FLAGS)
 118 dnl fi
 119
 120 dnl Check for pkg-config
 121 PKG_PROG_PKG_CONFIG([0.22])
 122
 123 dnl Enable versioned user preferences directory
 124 AC_ARG_WITH(pref-suffix,
 125   AS_HELP_STRING([--with-pref-suffix=VALUE],[Suffix to add to user preferences dir.]),
 126   PREF_SUFFIX="$withval")
 127
 128 AC_SUBST(PREF_SUFFIX)
 129 AC_DEFINE_UNQUOTED(PREF_SUFFIX,
 130       "${PREF_SUFFIX}",
 131           [Suffix to add to preferences directory])
 132
 133 # Initialize libtool
 134 LT_PREREQ([2.2])
 135 LT_INIT([disable-static])
 136
 137 dnl ***************************************************************************
 138 dnl Check for GObject-Introspection
 139 dnl ***************************************************************************
 140 m4_ifdef([GOBJECT_INTROSPECTION_CHECK], [GOBJECT_INTROSPECTION_CHECK([0.6.7])],
 141 [AM_CONDITIONAL(HAVE_INTROSPECTION, false)])
 142
 143 dnl ***************************************************************************
 144 dnl Set gjsdir
 145 dnl ***************************************************************************
 146 gjsdir=`pkg-config --variable=jsdir gjs-1.0`
 147 AC_SUBST(gjsdir)
 148
 149 dnl Check base modules
 150
 151 PKG_CHECK_MODULES([ANJUTA],
 152    [gthread-2.0 >= $GTHREAD_REQUIRED
 153         glib-2.0 >= $GLIB_REQUIRED
 154         gio-2.0 >= $GLIB_REQUIRED
 155         gmodule-2.0 >= $GLIB_REQUIRED
 156         gtk+-3.0 >= $GTK_REQUIRED
 157         gdk-pixbuf-2.0 >= $GDK_PIXBUF_REQUIRED])
 158
 159 PKG_CHECK_MODULES([XML],
 160    [libxml-2.0 >= $LIBXML_REQUIRED])
 161
 162 PKG_CHECK_MODULES([GDL],
 163    [gdl-3.0 >= $GDL_REQUIRED])
 164
 165 PKG_CHECK_MODULES([GDA],
 166    [libgda-5.0 >= $GDA5_REQUIRED],,
 167    [PKG_CHECK_MODULES([GDA],
 168       [libgda-4.0 >= $GDA4_REQUIRED])])
 169
 170 PKG_CHECK_MODULES([VTE],
 171    [vte-2.90 >= $VTE_REQUIRED])
 172
 173 dnl Check for autogen
 174 dnl -----------------
 175 AC_PATH_PROG(AUTOGEN_PATH, autogen,no)
 176 if test x$AUTOGEN_PATH = xno; then
 177    AC_MSG_WARN([Couldn't find autogen. You will be able to build anjuta without autogen \
 178                 but several things won't work. You can get it from http://autogen.sourceforge.net/])
 179 fi
 180
 181 dnl Check for Devhelp
 182 dnl -----------------
 183
 184 AC_ARG_ENABLE(plugin-devhelp,
 185   AS_HELP_STRING([--disable-plugin-devhelp],[Disable devhelp plugin support in Anjuta.]),
 186   [ if test "$enableval" = "no"; then
 187        user_disabled_devhelp=1
 188     fi ],
 189   [ user_disabled_devhelp=0 ] )
 190
 191 AC_MSG_CHECKING(if devhelp plugin is disabled)
 192 if test "$user_disabled_devhelp" = 1; then
 193         AC_MSG_RESULT(yes)
 194         devhelp_enabled="no"
 195 else
 196         AC_MSG_RESULT(no)
 197         PKG_CHECK_MODULES(PLUGIN_DEVHELP,
 198                                 [libdevhelp-3.0 >= $LIBDEVHELP_REQUIRED],
 199                                 [
 200                                     devhelp_enabled=yes
 201                                 ], [
 202                                     devhelp_enabled=no
 203                                 ])
 204 fi
 205
 206 AM_CONDITIONAL(HAVE_PLUGIN_DEVHELP, [test x$devhelp_enabled = xyes])
 207
 208 dnl Check for Glade3
 209 dnl ---------------------
 210
 211 AC_ARG_ENABLE(plugin-glade,
 212   AS_HELP_STRING([--disable-plugin-glade],[Disable glade plugin support in Anjuta.]),
 213   [ if test "$enableval" = "no"; then
 214        user_disabled_glade=1
 215     fi ],
 216   [ user_disabled_glade=0 ] )
 217
 218 AC_MSG_CHECKING(if glade plugin is disabled)
 219 if test "$user_disabled_glade" = 1; then
 220         AC_MSG_RESULT(yes)
 221         gladeui_found="no"
 222 else
 223         AC_MSG_RESULT(no)
 224         gladeui_version=0
 225         PKG_CHECK_MODULES(PLUGIN_GLADE, gladeui-2.0 >= $GLADEUI_REQUIRED,
 226             [
 227                 gladeui_found=yes
 228             ], [
 229                 gladeui_found=no
 230             ])
 231 fi
 232
 233 AM_CONDITIONAL(HAVE_PLUGIN_GLADE, [test x$gladeui_found = xyes])
 234
 235 dnl Check for gtksourceview
 236 dnl -------------------------------------------------------------
 237 PKG_CHECK_MODULES(SOURCEVIEW,
 238                 [gtksourceview-3.0 >= $GTKSOURCEVIEW_REQUIRED])
 239
 240 dnl Check for vala
 241 dnl -------------------------------------------------------------
 242
 243 AC_ARG_ENABLE(vala,
 244         AS_HELP_STRING([--disable-vala],[Disable vala support]),
 245         [ if test "$enableval" = "no"; then
 246                 user_disabled_vala=1
 247           fi ],
 248         [ user_disabled_vala=0 ])
 249
 250 AC_MSG_CHECKING(if vala support is disabled)
 251 if test "$user_disabled_vala" = 1; then
 252         AC_MSG_RESULT(yes)
 253         enable_vala="no"
 254 else
 255         AC_MSG_RESULT(no)
 256         AC_MSG_CHECKING(if libvala is available)
 257         PKG_CHECK_EXISTS([ libvala-0.18 ],
 258                          [ valaver="-0.18" ],
 259                          [ PKG_CHECK_EXISTS([ libvala-0.16 ],
 260                                             [ valaver="-0.16" ],
 261                                             [ valaver="" ])
 262                          ])
 263         if test "x$valaver" != "x"; then
 264                 AC_MSG_RESULT(yes)
 265                 enable_vala="yes"
 266                 LIBVALA="libvala${valaver}"
 267                 PKG_CHECK_MODULES([VALA], ${LIBVALA})
 268         else
 269                 AC_MSG_RESULT(no)
 270                 enable_vala="no"
 271                 VALA_REQUIRED=0.16.0
 272         fi
 273         AC_SUBST(LIBVALA)
 274 fi
 275
 276 if test x$enable_vala = xyes; then
 277         AC_PATH_PROGS(VALAC, [valac${valaver} valac], valac)
 278         AC_SUBST(VALAC)
 279 fi
 280
 281 AM_CONDITIONAL(ENABLE_VALA, [test x$enable_vala = xyes])
 282
 283 dnl Check for Python
 284 dnl -------------------------------------------------------------
 285
 286 AM_PATH_PYTHON([],
 287         [have_python="yes"],
 288         [have_python="no"])
 289
 290 if test x$have_python = xyes; then
 291         if test -x $PYTHON-config; then
 292                 PYTHON_CFLAGS=`$PYTHON-config --cflags`
 293                 PYTHON_LIBS=`$PYTHON-config --libs`
 294                 AC_SUBST(PYTHON_CFLAGS)
 295                 AC_SUBST(PYTHON_LIBS)
 296         elif test -x $PYTHON$PYTHON_VERSION-config; then
 297                 PYTHON_CFLAGS=`$PYTHON$PYTHON_VERSION-config --cflags`
 298                 PYTHON_LIBS=`$PYTHON$PYTHON_VERSION-config --libs`
 299                 AC_SUBST(PYTHON_CFLAGS)
 300                 AC_SUBST(PYTHON_LIBS)
 301         else
 302                 have_python="no"
 303                 echo "$PYTHON-config or $PYTHON$PYTHON_VERSION-config not found - disabling python"
 304         fi
 305 fi
 306
 307 AM_CONDITIONAL(HAVE_PYTHON, [test x$have_python = xyes])
 308
 309 dnl Disable packagekit support
 310 dnl -----------------------------------
 311 AC_ARG_ENABLE(packagekit,
 312   [AC_HELP_STRING([--disable-packagekit],[build without PackageKit support])],,
 313   [enable_packagekit=yes])
 314 if test "x$enable_packagekit" != "xno"; then
 315   AC_DEFINE(ENABLE_PACKAGEKIT, 1, [define to enable PackageKit installer])
 316 fi
 317
 318 dnl Setup Anjuta Library flags
 319 dnl --------------------------
 320 LIBANJUTA_CFLAGS='$(ANJUTA_CFLAGS) $(GDL_CFLAGS) $(DEPRECATED_FLAGS) -I$(top_srcdir) -I$(top_builddir)/libanjuta -DPACKAGE_PIXMAPS_DIR=\""$(datadir)/pixmaps/$(PACKAGE)"\" -DPACKAGE_LIB_DIR=\""$(pkglibdir)"\" -DPACKAGE_DATA_DIR=\""$(datadir)/$(PACKAGE)"\"'
 321 LIBANJUTA_LIBS='$(top_builddir)/libanjuta/libanjuta-3.la'
 322 AC_SUBST(LIBANJUTA_CFLAGS)
 323 AC_SUBST(LIBANJUTA_LIBS)
 324
 325 dnl Setup FooCanvas Library flags
 326 dnl --------------------------
 327 LIBFOOCANVAS_CFLAGS='-I$(top_srcdir)'
 328 LIBFOOCANVAS_LIBS='$(top_builddir)/libfoocanvas/libanjuta-foocanvas.la'
 329 AC_SUBST(LIBFOOCANVAS_CFLAGS)
 330 AC_SUBST(LIBFOOCANVAS_LIBS)
 331
 332 dnl Checks for Xft/XRender for foocanvas
 333 dnl
 334 AC_CHECK_LIB(Xrender, XRenderFindFormat,
 335         [AC_SUBST(RENDER_LIBS, "-lXrender -lXext")
 336          AC_DEFINE(HAVE_RENDER, 1, [Define if libXrender is available.])],
 337         [AC_SUBST(RENDER_LIBS, "")],
 338         [-lXext])
 339
 340 dnl Setup Plugin directories
 341 dnl ------------------------
 342 anjuta_plugin_dir='$(libdir)/anjuta'
 343 anjuta_data_dir='$(datadir)/anjuta'
 344 anjuta_ui_dir='$(datadir)/anjuta/ui'
 345 anjuta_glade_dir='$(datadir)/anjuta/glade'
 346 anjuta_image_dir='$(datadir)/pixmaps/anjuta'
 347 AC_SUBST(anjuta_plugin_dir)
 348 AC_SUBST(anjuta_data_dir)
 349 AC_SUBST(anjuta_ui_dir)
 350 AC_SUBST(anjuta_glade_dir)
 351 AC_SUBST(anjuta_image_dir)
 352
 353 dnl ***************************************************************************
 354 dnl Check for marshal and enum generators
 355 dnl ***************************************************************************
 356 GLIB_GENMARSHAL="`$PKG_CONFIG --variable=glib_genmarshal glib-2.0`"
 357 AC_SUBST(GLIB_GENMARSHAL)
 358 GLIB_MKENUMS="`$PKG_CONFIG --variable=glib_mkenums glib-2.0`"
 359 AC_SUBST(GLIB_MKENUMS)
 360
 361 dnl Set up Glade 3 catlog information
 362 dnl ---------------------
 363 GLADE_PLUGINS_PATH="`$PKG_CONFIG --variable=moduledir gladeui-1.0`"
 364 AC_SUBST(GLADE_PLUGINS_PATH)
 365 GLADE_CATALOG_PATH="`$PKG_CONFIG --variable=catalogdir gladeui-1.0`"
 366 AC_SUBST(GLADE_CATALOG_PATH)
 367
 368 dnl ***************************************************************************
 369 dnl Internatinalization
 370 dnl ***************************************************************************
 371 IT_PROG_INTLTOOL([0.40.1])
 372
 373 AM_GNU_GETTEXT([external])
 374 AM_GNU_GETTEXT_VERSION([0.17])
 375
 376 GETTEXT_PACKAGE=anjuta
 377 AC_SUBST(GETTEXT_PACKAGE)
 378 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE", [GETTEXT package name])
 379
 380 BISON_I18N
 381
 382 dnl ***************************************************************************
 383 dnl Check for gtk-doc.
 384 dnl ***************************************************************************
 385 GTK_DOC_CHECK([1.4])
 386
 387 dnl ***************************************************************************
 388 dnl User manual
 389 dnl ***************************************************************************
 390 GNOME_DOC_INIT([0.18])
 391
 392 dnl Define convenience macros
 393 dnl -------------------------
 394 dnl CHECK_HEADER_DEFINE(LABEL, HEADER [,ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND ] ])
 395 AC_DEFUN([CHECK_HEADER_DEFINE],
 396 [
 397         AC_MSG_CHECKING("if $1 is defined in $2")
 398         AC_EGREP_CPP(yes,
 399 [#include <$2>
 400 #ifdef $1
 401   yes
 402 #endif
 403 ], [
 404         AC_MSG_RESULT(yes)
 405         $3
 406 ], [
 407         AC_MSG_RESULT(no)
 408         $4
 409 ]) ])
 410
 411 dnl Checks for header files.
 412 AC_CHECK_HEADERS(dirent.h fcntl.h fnmatch.h stat.h stdlib.h string.h stdint.h)
 413 AC_CHECK_HEADERS(time.h types.h unistd.h)
 414 AC_CHECK_HEADERS(sys/dir.h sys/stat.h sys/times.h sys/types.h)
 415
 416 dnl Checks for typedefs, structures, and compiler characteristics.
 417
 418 AC_CANONICAL_HOST
 419 CYGWIN=no
 420 MINGW32=no
 421 case $host_os in
 422   *cygwin* ) CYGWIN=yes;;
 423   *mingw32* ) MINGW32=yes;;
 424 esac
 425
 426
 427 dnl Check for bind in libsocket (needed on Solaris)
 428 AC_CHECK_LIB(socket, bind)
 429
 430 dnl Check for function forkpty and related headers
 431 AC_SEARCH_LIBS(forkpty, util, , AC_DEFINE(EMULATE_FORKPTY, [], [Need  to implement our own forkpty()]))
 432 AC_CHECK_HEADERS(libutil.h util.h pty.h)
 433
 434 dnl Checks for library functions.
 435 AC_CHECK_FUNCS(fnmatch)
 436 AC_CHECK_FUNCS(strstr)
 437 AC_CHECK_FUNCS(stricmp)
 438 AC_CHECK_FUNCS(strnicmp)
 439 AC_CHECK_FUNCS(getline)
 440
 441 dnl for libegg/egg-recent-model.c
 442 AC_CHECK_DECLS([lockf])
 443 AC_CHECK_FUNCS([lockf])
 444
 445 AC_CHECK_FUNCS(fgetpos, have_fgetpos=yes)
 446
 447 dnl SEEK_SET should be in stdio.h, but may be in unistd.h on SunOS 4.1.x
 448 if test "$have_fgetpos" != yes ; then
 449     CHECK_HEADER_DEFINE(SEEK_SET, stdio.h,,
 450         CHECK_HEADER_DEFINE(SEEK_SET, unistd.h,,
 451             AC_DEFINE(SEEK_SET, 0, [Seek set 0])))
 452 fi
 453
 454 AC_CHECK_FUNCS(mkstemp, have_mkstemp=yes)
 455 if test "$have_mkstemp" != yes ; then
 456     AC_CHECK_FUNCS(chmod)
 457     if test "$tmpdir_specified" = yes ; then
 458         AC_MSG_RESULT(use of tmpnam overrides temporary directory selection)
 459     fi
 460 else
 461     AC_MSG_CHECKING(directory to use for temporary files)
 462     if test -z "$enable_tmpdir" -o "$enable_tmpdir" = no -o "$enable_tmpdir" = yes ;
 463         then tmpdir=/tmp
 464         else tmpdir="$enable_tmpdir"
 465     fi
 466     if test -d $tmpdir ; then
 467         AC_MSG_RESULT($tmpdir)
 468         AC_DEFINE_UNQUOTED(TMPDIR, "$tmpdir", [Directory for temporary files])
 469     else
 470         AC_MSG_WARN($tmpdir does not exist)
 471     fi
 472 fi
 473
 474 dnl -----------------------------
 475 dnl Checks for FreeBSD Build
 476 dnl -----------------------------
 477 AC_MSG_CHECKING(if building on FreeBSD)
 478
 479 if test `uname -s` = "FreeBSD" ; then
 480         AC_MSG_RESULT(yes)
 481         FREEBSD_BUILD=-DFREEBSD
 482         AC_SUBST(FREEBSD_BUILD)
 483         AC_PATH_PROG(GMAKE, gmake, no)
 484         if test "x$GMAKE" = "xno"; then
 485                 AC_MSG_ERROR(You need gmake installed to build Anjuta!)
 486         fi
 487 else
 488         AC_MSG_RESULT(no)
 489         GMAKE="make"
 490 fi
 491
 492 AC_SUBST(GMAKE)
 493
 494 dnl Checks for missing prototypes
 495 dnl -----------------------------
 496 AC_MSG_NOTICE([checking for missing prototypes...])
 497
 498 AC_DEFUN([CHECK_PROTO], [AC_EGREP_HEADER([[^A-Za-z0-9_]$1([   ]+[A-Za-z0-9_]*)?\(], $2,, AC_DEFINE(patsubst([NEED_PROTO_NAME], [NAME], translit($1, [a-z], [A-Z])),,[Do not know]) AC_MSG_RESULT(adding prototype for $1))])
 499
 500 if test "$have_remove" = yes ; then
 501     CHECK_PROTO(remove, stdio.h)
 502 else
 503     CHECK_PROTO(unlink, unistd.h)
 504 fi
 505 CHECK_PROTO(malloc, stdlib.h)
 506 CHECK_PROTO(getenv, stdlib.h)
 507 CHECK_PROTO(stat,   sys/stat.h)
 508 CHECK_PROTO(lstat,  sys/stat.h)
 509 if test "$have_fgetpos" = yes ; then
 510     CHECK_PROTO(fgetpos, stdio.h)
 511 fi
 512 if test "$have_truncate" = yes ; then
 513     CHECK_PROTO(truncate, unistd.h)
 514 fi
 515 if test "$have_ftruncate" = yes ; then
 516     CHECK_PROTO(ftruncate, unistd.h)
 517 fi
 518
 519 dnl  **********************************************************
 520 dnl  check if we have svn libraries to build subversion plugin
 521 dnl  (stolen from kdevelop ;-)
 522 dnl  **********************************************************
 523
 524 AC_MSG_CHECKING(for Subversion svn-config)
 525 AC_ARG_WITH(subversion-dir,
 526                 AS_HELP_STRING([--with-subversion-dir=DIR],[Where Subversion is installed ]),
 527                 [
 528                                 SVNCONFIG="$withval/bin/svn-config"
 529                 ])
 530
 531 if test -z "$SVNCONFIG"; then
 532                 _SVNCONFIG="`svn-config --prefix 2> /dev/null`"
 533                 if test -n "$_SVNCONFIG"; then
 534                                 SVNCONFIG="$_SVNCONFIG/bin/svn-config"
 535                 fi
 536 fi
 537
 538 AC_SUBST(SVNCONFIG)
 539 if test -x "$SVNCONFIG"; then
 540                 SVNLD="`$SVNCONFIG --ldflags 2> /dev/null`"
 541                 SVN_LIB="`$SVNCONFIG --libs --cflags 2> /dev/null` -lsvn_client-1 -lsvn_subr-1"
 542                 dnl ugly hack for subversion svn-config problems in 0.14.x, to be removed when svn-config is fixed
 543                 SVN_INCLUDE="`$SVNCONFIG --includes 2> /dev/null` -I$_SVNCONFIG/include/subversion-1/"
 544                 AC_MSG_RESULT(yes)
 545 else
 546                 AC_MSG_RESULT(not found)
 547
 548                 dnl just a fallback to debian's config so that it works for me :)
 549                 AC_ARG_WITH(svn-include,
 550                                                                 [[  --with-svn-include=DIR   Use the given path to the subversion headers.]],
 551                                                                 [
 552                                                                 if test "$withval" != "yes" -a "$withval" != ""; then
 553                                                                                 SVN_INCLUDES=$withval
 554                                                                 fi
 555                                                                 ])
 556                 if test -z "$SVN_INCLUDES"; then
 557                         SVN_INCLUDES="/usr/local/include /usr/include"
 558                 fi
 559                 AC_MSG_CHECKING([for Subversion headers])
 560                 SVN_INCLUDE=""
 561                 for VALUE in $SVN_INCLUDES ; do
 562                                 if test -f $VALUE/subversion-1/svn_types.h ; then
 563                                                 SVN_INCLUDE=$VALUE/subversion-1
 564                                                 break
 565                                 fi
 566                                 if test -f $VALUE/svn_types.h ; then
 567                                                 SVN_INCLUDE=$VALUE
 568                                                 break
 569                                 fi
 570                 done
 571                 if test $SVN_INCLUDE ; then
 572                                 AC_MSG_RESULT([found])
 573                 else
 574                                 AC_MSG_RESULT([not found])
 575                 fi
 576                 SVN_LIBS="/usr/local/lib64 /usr/local/lib /usr/lib64 /usr/lib"
 577                 AC_ARG_WITH(svn-lib,
 578                                                 [[  --with-svn-lib=DIR  Use the given path to the subversion libraries.]],
 579                                                 [
 580                                                         if test "$withval" != "yes" -a "$withval" != ""; then
 581                                                                 SVN_LIBS=$withval
 582                                                         fi
 583                                                 ])
 584                 AC_MSG_CHECKING([for Subversion libraries])
 585                 SVN_LIB=""
 586                 for VALUE in $SVN_LIBS ; do
 587                                 if ls $VALUE/libsvn_client-1.* 1>/dev/null 2>&1; then
 588                                                 SVN_LIB=$VALUE
 589                                                 break
 590                                 fi
 591                 done
 592                 if test $SVN_LIB ; then
 593                                 AC_MSG_RESULT([found])
 594                 else
 595                                 AC_MSG_RESULT([not found])
 596                 fi
 597 fi
 598
 599 dnl ******************************************************************
 600 dnl Check for extra libs required by subversion.
 601 dnl FIXME: This should actually be done by subversion and not by us.
 602 dnl ******************************************************************
 603
 604 AC_ARG_ENABLE(plugin-subversion,
 605   AS_HELP_STRING([--disable-plugin-subversion],[Disable subversion support in Anjuta.]),
 606   [ if test "$enableval" = "no"; then
 607         user_disabled_subversion=1
 608     fi ],
 609   [ user_disabled_subversion=0 ] )
 610
 611 AC_MSG_CHECKING(if subversion support is disabled)
 612 if test "$user_disabled_subversion" = 1; then
 613         AC_MSG_RESULT(yes)
 614         SVN_INCLUDE=""
 615         SVN_LIB=""
 616 else
 617         AC_MSG_RESULT(no)
 618 fi
 619
 620 if test -n "$SVN_INCLUDE" ; then
 621         dnl ------------------------------------
 622         dnl APR. Required by subversion (devel)
 623         dnl ------------------------------------
 624         have_atr=no
 625         PKG_CHECK_MODULES(APR,                            \
 626                 apr-1, have_apr=yes, have_apr=no)
 627         if test x"$have_apr" = "xno"; then
 628                 SVN_INCLUDE=""
 629         fi
 630
 631         dnl -----------------------------------------
 632         dnl APR util. Required by subversion (devel)
 633         dnl------------------------------------------
 634         have_atr_util=no
 635         PKG_CHECK_MODULES(APR_UTILS,                            \
 636                 apr-util-1, have_apr_util=yes, have_apr_util=no)
 637         if test x"$have_apr_util" = "xno"; then
 638                 SVN_INCLUDE=""
 639         fi
 640
 641         dnl -----------------------------------------
 642         dnl NEON. Required by subversion (devel)
 643         dnl------------------------------------------
 644         have_neon=no
 645         PKG_CHECK_MODULES(NEON,                            \
 646                 neon, have_neon=yes, have_neon=no)
 647         if test x"$have_neon" = "xno"; then
 648                 SVN_INCLUDE=""
 649         fi
 650
 651         dnl Make sure our SVN version is high enough
 652         dnl Eww, eww, eww, this is dirty
 653         AC_MSG_CHECKING([for subversion >= $SUBVERSION_REQUIRED])
 654         AC_LANG([C])
 655         dnl Temporarily set CFLAGS so that include dirs are found
 656         CFLAGS_TMP=$CFLAGS
 657         CFLAGS="-I$SVN_INCLUDE $APR_CFLAGS"
 658         AC_COMPILE_IFELSE(
 659                 [AC_LANG_PROGRAM([[#include <svn_version.h>]],
 660                         [[
 661                                 #if (SVN_VER_MAJOR < $SVN_MAJOR) || (SVN_VER_MINOR < $SVN_MINOR) || (SVN_VER_PATCH < $SVN_PATCH)
 662                                 #       error "Version too low"
 663                                 #endif
 664                         ]])], AC_MSG_RESULT(yes), have_svn_version=no)
 665         if test x"$have_svn_version" = "xno"; then
 666                 AC_MSG_RESULT(no)
 667                 SVN_INCLUDE=""
 668         fi
 669         CFLAGS=$CFLAGS_TMP
 670 fi
 671
 672 dnl ------------------------------------------
 673 dnl Finally prepare subversion build flags
 674 dnl ------------------------------------------
 675
 676 if test -n "$SVN_INCLUDE" ; then
 677         SVN_INCLUDE="-I$SVN_INCLUDE"
 678         if test x != "x$SVN_LIB" ; then
 679             SVN_LIB="-L$SVN_LIB $APR_LIBS $APR_UTILS_LIBS $NEON_LIBS -lsvn_client-1 -lsvn_subr-1"
 680         else
 681             SVN_LIB="$APR_LIBS $APR_UTILS_LIBS $NEON_LIBS -lsvn_client-1 -lsvn_subr-1"
 682         fi
 683         SVN_CFLAGS="$APR_CFLAGS $APR_UTILS_CFLAGS $NEON_CFLAGS"
 684 fi
 685
 686 AM_CONDITIONAL(BUILD_SVN, [test -n "$SVN_INCLUDE"])
 687 AC_SUBST(SVN_INCLUDE)
 688 AC_SUBST(SVN_LIB)
 689 AC_SUBST(SVN_CFLAGS)
 690
 691 dnl ------------------------------------------
 692 dnl Symbol-db shared memory checks
 693 dnl ------------------------------------------
 694
 695 SYMBOL_DB_SHM="/dev/shm"
 696 user_specified_shm=0
 697 AC_MSG_CHECKING(for symbol-db shared memory)
 698 AC_ARG_WITH(symbol-db-shm,
 699                 AS_HELP_STRING([--with-symbol-db-shm=DIR],[Where shared memory is placed ]),
 700                 [
 701                                 user_specified_shm=1
 702                                 SYMBOL_DB_SHM="$withval"
 703                 ])
 704 if test "$user_specified_shm" = 1; then
 705         AC_MSG_RESULT(yes)
 706 else
 707         AC_MSG_RESULT(no)
 708 fi
 709
 710 AC_SUBST(SYMBOL_DB_SHM)
 711
 712
 713 dnl Check for graphviz (class inheritance and profiler plugins)
 714 AC_ARG_ENABLE(graphviz,
 715         AS_HELP_STRING([--disable-graphviz],[Disable GraphViz support in Anjuta]),
 716         [ if test "$enableval" = "no"; then
 717                 user_disabled_graphviz=1
 718           fi ],
 719         [ user_disabled_graphviz=0 ])
 720
 721 AC_MSG_CHECKING(if GraphViz support is disabled)
 722 if test "$user_disabled_graphviz" = 1; then
 723         AC_MSG_RESULT(yes)
 724         libgraphviz_found="no"
 725 else
 726         AC_MSG_RESULT(no)
 727         PKG_CHECK_MODULES(GRAPHVIZ,
 728                 [libgvc >= $LIBGRAPHVIZ_REQUIRED libgraph >= $LIBGRAPHVIZ_REQUIRED],
 729                 [libgraphviz_found="yes"],
 730                 [libgraphviz_found="no"])
 731 fi
 732
 733 AM_CONDITIONAL(HAVE_GRAPHVIZ, [test x$libgraphviz_found = xyes])
 734
 735 dnl Test using autotest
 736 dnl -----------------------------
 737 AC_CONFIG_TESTDIR(plugins/am-project/tests)
 738 AM_MISSING_PROG([AUTOM4TE], [autom4te])
 739
 740 AC_CONFIG_FILES([
 741 Makefile
 742 po/Makefile.in
 743 libanjuta/Makefile
 744 libanjuta/tests/Makefile
 745 libanjuta/interfaces/Makefile
 746 libanjuta/libanjuta-3.0.pc
 747 libanjuta/anjuta-version.h
 748 src/Makefile
 749 pixmaps/Makefile
 750 pixmaps/16x16/Makefile
 751 pixmaps/22x22/Makefile
 752 pixmaps/24x24/Makefile
 753 pixmaps/32x32/Makefile
 754 pixmaps/48x48/Makefile
 755 pixmaps/scalable/Makefile
 756 data/Makefile
 757 data/welcome.txt
 758 data/templates/Makefile
 759 doc/anjuta.1
 760 doc/anjuta-launcher.1
 761 doc/Makefile
 762 scripts/Makefile
 763 launcher/Makefile
 764 plugins/Makefile
 765 plugins/class-gen/Makefile
 766 plugins/class-gen/templates/Makefile
 767 plugins/code-analyzer/Makefile
 768 plugins/patch/Makefile
 769 plugins/document-manager/Makefile
 770 plugins/document-manager/images/Makefile
 771 plugins/message-view/Makefile
 772 plugins/gdb/Makefile
 773 plugins/gdb/images/Makefile
 774 plugins/debug-manager/Makefile
 775 plugins/debug-manager/images/Makefile
 776 plugins/devhelp/Makefile
 777 plugins/devhelp/images/Makefile
 778 plugins/glade/Makefile
 779 plugins/glade/images/Makefile
 780 plugins/js-debugger/Makefile
 781 plugins/file-manager/Makefile
 782 plugins/file-loader/Makefile
 783 plugins/file-wizard/Makefile
 784 plugins/build-basic-autotools/Makefile
 785 plugins/project-manager/Makefile
 786 plugins/symbol-db/benchmark/Makefile
 787 plugins/symbol-db/benchmark/symbol-db/Makefile
 788 plugins/symbol-db/benchmark/libgda/Makefile
 789 plugins/symbol-db/benchmark/sqlite/Makefile
 790 plugins/symbol-db/images/Makefile
 791 plugins/symbol-db/Makefile
 792 plugins/symbol-db/anjuta-tags/Makefile
 793 plugins/project-wizard/Makefile
 794 plugins/snippets-manager/Makefile
 795 plugins/cvs-plugin/Makefile
 796 plugins/subversion/Makefile
 797 plugins/git/Makefile
 798 plugins/git/images/Makefile
 799 plugins/sourceview/Makefile
 800 plugins/terminal/Makefile
 801 plugins/tools/Makefile
 802 plugins/tools/scripts/Makefile
 803 plugins/language-manager/Makefile
 804 plugins/project-import/Makefile
 805 plugins/project-wizard/templates/Makefile
 806 plugins/project-wizard/templates/mkfile/Makefile
 807 plugins/project-wizard/templates/mkfile/src/Makefile
 808 plugins/project-wizard/templates/mkfile/po/Makefile
 809 plugins/project-wizard/templates/minimal/Makefile
 810 plugins/project-wizard/templates/js_minimal/Makefile
 811 plugins/project-wizard/templates/js_minimal/src/Makefile
 812 plugins/project-wizard/templates/terminal/Makefile
 813 plugins/project-wizard/templates/terminal/src/Makefile
 814 plugins/project-wizard/templates/terminal/po/Makefile
 815 plugins/project-wizard/templates/cpp/Makefile
 816 plugins/project-wizard/templates/cpp/src/Makefile
 817 plugins/project-wizard/templates/cpp/po/Makefile
 818 plugins/project-wizard/templates/gtk/Makefile
 819 plugins/project-wizard/templates/gtk/src/Makefile
 820 plugins/project-wizard/templates/gtk/po/Makefile
 821 plugins/project-wizard/templates/gtkapplication/Makefile
 822 plugins/project-wizard/templates/gtkapplication/src/Makefile
 823 plugins/project-wizard/templates/gtkapplication/po/Makefile
 824 plugins/project-wizard/templates/anjuta-plugin/Makefile
 825 plugins/project-wizard/templates/anjuta-plugin/src/Makefile
 826 plugins/project-wizard/templates/anjuta-plugin/po/Makefile
 827 plugins/project-wizard/templates/gtkmm/Makefile
 828 plugins/project-wizard/templates/gtkmm/src/Makefile
 829 plugins/project-wizard/templates/gtkmm/po/Makefile
 830 plugins/project-wizard/templates/gcj/Makefile
 831 plugins/project-wizard/templates/gcj/src/Makefile
 832 plugins/project-wizard/templates/java/Makefile
 833 plugins/project-wizard/templates/java/src/Makefile
 834 plugins/project-wizard/templates/java/po/Makefile
 835 plugins/project-wizard/templates/python/Makefile
 836 plugins/project-wizard/templates/python/src/Makefile
 837 plugins/project-wizard/templates/python/po/Makefile
 838 plugins/project-wizard/templates/pygtk/Makefile
 839 plugins/project-wizard/templates/pygtk/src/Makefile
 840 plugins/project-wizard/templates/pygtk/po/Makefile
 841 plugins/project-wizard/templates/vala-gtk/Makefile
 842 plugins/project-wizard/templates/vala-gtk/src/Makefile
 843 plugins/project-wizard/templates/wxwin/Makefile
 844 plugins/project-wizard/templates/wxwin/src/Makefile
 845 plugins/project-wizard/templates/wxwin/po/Makefile
 846 plugins/project-wizard/templates/xlib/Makefile
 847 plugins/project-wizard/templates/xlib/src/Makefile
 848 plugins/project-wizard/templates/xlib/po/Makefile
 849 plugins/project-wizard/templates/xlib-dock/Makefile
 850 plugins/project-wizard/templates/xlib-dock/src/Makefile
 851 plugins/project-wizard/templates/xlib-dock/po/Makefile
 852 plugins/project-wizard/templates/sdl/Makefile
 853 plugins/project-wizard/templates/sdl/src/Makefile
 854 plugins/project-wizard/templates/sdl/po/Makefile
 855 plugins/project-wizard/templates/licenses/Makefile
 856 plugins/project-wizard/templates/library/Makefile
 857 plugins/project-wizard/templates/library/src/Makefile
 858 plugins/project-wizard/templates/library/po/Makefile
 859 plugins/project-wizard/templates/directory/Makefile
 860 plugins/project-wizard/templates/m4/Makefile
 861 plugins/project-wizard/templates/gnome-shell-extension/Makefile
 862 plugins/project-wizard/templates/gnome-shell-extension/src/Makefile
 863 plugins/am-project/Makefile
 864 plugins/am-project/tests/atlocal
 865 plugins/am-project/tests/Makefile
 866 plugins/mk-project/Makefile
 867 plugins/dir-project/Makefile
 868 plugins/language-support-cpp-java/Makefile
 869 plugins/language-support-cpp-java/cxxparser/Makefile
 870 plugins/run-program/Makefile
 871 plugins/starter/Makefile
 872 plugins/indentation-c-style/Makefile
 873 plugins/indentation-python-style/Makefile
 874 plugins/language-support-js/Makefile
 875 plugins/language-support-vala/Makefile
 876 plugins/language-support-python/Makefile
 877 plugins/python-loader/Makefile
 878 anjuta.desktop.in
 879 manuals/Makefile
 880 manuals/reference/Makefile
 881 manuals/reference/libanjuta/Makefile
 882 manuals/reference/libanjuta/version.xml
 883 manuals/anjuta-manual/Makefile
 884 manuals/anjuta-faqs/Makefile
 885 manuals/anjuta-build-tutorial/Makefile
 886 mime/Makefile
 887 ])
 888 AC_OUTPUT
 889 echo " "
 890 echo "-------------------------------------------------------------------"
 891 echo "Conditionally built plugins:"
 892 echo "-------------------------------------------------------------------"
 893 if [ test -n "$SVN_INCLUDE" ]; then
 894         echo "Building subversion plugin: ............................YES"
 895 else
 896         echo "Building subversion plugin: ............................NO"
 897                 echo "        Requires apr (>= 0.9.4); http://subversion.org"
 898                 echo "        Requires apr-util (>= 0.9.4); http://subversion.org"
 899                 echo "        Requires neon (>= 0.28.2); http://subversion.org"
 900                 echo "        Requires subversion (>= 1.5); http://subversion.org"
 901 fi
 902
 903 if [ test x$gladeui_found = xyes ]; then
 904        echo "Building glade plugin: .................................YES"
 905 else
 906        echo "Building glade plugin: .................................NO"
 907        echo "        Requires glade-3 (>= $GLADEUI_REQUIRED)"
 908 fi
 909
 910 if [ test x$devhelp_enabled = xyes ]; then
 911        echo "Building devhelp plugin: ...............................YES"
 912 else
 913        echo "Building devhelp plugin: ...............................NO"
 914        echo "        Requires libdevhelp-3.0 (>= $LIBDEVHELP_REQUIRED)"
 915 fi
 916 if [ test x$enable_vala = xyes ]; then
 917         echo "Building Vala support: .................................YES"
 918 else
 919         echo "Building Vala support: .................................NO"
 920         echo "        Requires libvala (>= $VALA_REQUIRED)"
 921 fi
 922 if [ test x$libgraphviz_found = xyes ]; then
 923         echo "Building class inheritance plugin: .....................YES"
 924 else
 925         echo "Building class inheritance plugin: .....................NO"
 926         echo "        Requires graphviz (>= 2.6.0); http://graphviz.org"
 927 fi
 928 if [ test x$have_python = xyes]; then
 929         echo "Building python plugin loaeder: ........................YES"
 930 else
 931         echo "Building python plugin loaeder: ........................NO"
 932         echo "        Requires python"
 933 fi
 934 echo "-------------------------------------------------------------------"
 935 echo "AM_CFLAGS = $AM_CFLAGS"
 936 echo "AM_CXXFLAGS = $AM_CXXFLAGS"