configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_PREREQ(2.65)
   4
   5 m4_define(anjuta_major_version, 3)
   6 m4_define(anjuta_minor_version, 7)
   7 m4_define(anjuta_micro_version, 4)
   8 m4_define(anjuta_version, anjuta_major_version.anjuta_minor_version.anjuta_micro_version)
   9 m4_define(bugzilla_version, anjuta_major_version.anjuta_minor_version.anjuta_micro_version)
  10
  11 AC_INIT([Anjuta],[anjuta_version],[http://bugzilla.gnome.org/enter_bug.cgi?product=anjuta],[anjuta],[http://www.anjuta.org/])
  12
  13 AC_CONFIG_HEADERS([config.h])
  14 AC_CONFIG_SRCDIR([src/main.c])
  15 AC_CONFIG_MACRO_DIR([m4])
  16
  17
  18 AC_DEFINE(ANJUTA_MAJOR_VERSION, anjuta_major_version, [Anjuta major version])
  19 AC_SUBST(ANJUTA_MAJOR_VERSION, anjuta_major_version)
  20 AC_DEFINE(ANJUTA_MINOR_VERSION, anjuta_minor_version, [Anjuta minor version])
  21 AC_SUBST(ANJUTA_MINOR_VERSION, anjuta_minor_version)
  22 AC_DEFINE(ANJUTA_MICRO_VERSION, anjuta_micro_version, [Anjuta micro version])
  23 AC_SUBST(ANJUTA_MICRO_VERSION, anjuta_micro_version)
  24 AC_DEFINE(ANJUTA_VERSION, anjuta_version, [Anjuta version])
  25 AC_SUBST(ANJUTA_VERSION)
  26
  27 ANJUTA_VERSION=anjuta_version
  28 AC_SUBST(ANJUTA_VERSION)
  29
  30 BUGZILLA_VERSION=bugzilla_version
  31 AC_SUBST(BUGZILLA_VERSION)
  32
  33 dnl Anjuta core
  34 GLIB_REQUIRED=2.32.0
  35 GTK_REQUIRED=3.4.0
  36 GTHREAD_REQUIRED=2.22.0
  37 GDK_PIXBUF_REQUIRED=2.0.0
  38 GDA4_REQUIRED=4.2.0
  39 GDA5_REQUIRED=5.0.0
  40 VTE_REQUIRED=0.27.6
  41 LIBXML_REQUIRED=2.4.23
  42 GDL_REQUIRED=3.5.5
  43 LIBWNCK_REQUIRED=2.12
  44
  45 dnl GtkSourceView
  46 GTKSOURCEVIEW_REQUIRED=3.0.0
  47
  48 dnl Devhelp
  49 LIBDEVHELP_REQUIRED=3.7.4
  50
  51 dnl Glade
  52 GLADEUI_REQUIRED=3.12.0
  53
  54 dnl Introspection
  55 GI_REQUIRED=0.9.5
  56
  57 dnl Subversion plugin
  58 NEON_REQUIRED=0.28.2
  59 SVN_MAJOR=1
  60 SVN_MINOR=5
  61 SVN_PATCH=0
  62 SUBVERSION_REQUIRED=$SVN_MAJOR.$SVN_MINOR.$SVN_PATCH
  63
  64 AM_INIT_AUTOMAKE([1.10 dist-xz no-dist-gzip])
  65 AM_MAINTAINER_MODE([enable])
  66
  67 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  68
  69 dnl Check for C Compiler
  70 AC_PROG_CC
  71 AC_PROG_CPP
  72 AC_PROG_LEX
  73 if test "$LEX" != "flex"; then
  74         AC_MSG_ERROR(flex is required)
  75 fi
  76 AC_PROG_YACC
  77 if test "$YACC" != "bison -y"; then
  78         AC_MSG_ERROR(bison is required)
  79 fi
  80 AC_LANG([C])
  81 AC_LANG([C++])
  82 AC_PROG_CXX
  83 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],,
  84    AC_MSG_ERROR([C++ Compiler required to compile Anjuta]))
  85 AM_PROG_CC_C_O
  86
  87 GNOME_COMPILE_WARNINGS([maximum])
  88 AM_CFLAGS="$AM_CFLAGS $WARN_CFLAGS"
  89 AM_CXXFLAGS="$AM_CXXFLAGS $WARN_CXXFLAGS"
  90
  91 dnl Enable debugging mode
  92 AC_ARG_ENABLE(debug,
  93   AS_HELP_STRING([--enable-debug],[Enable debug messages]),
  94   [if test "x$enableval" = "xyes"; then
  95       AM_CFLAGS="$AM_CFLAGS -DDEBUG"
  96   fi]
  97   AM_CXXFLAGS="$AM_CXXFLAGS -DDEBUG")
  98 AC_SUBST(AM_CFLAGS)
  99 AC_SUBST(AM_CXXFLAGS)
 100
 101 ANJUTA_LDFLAGS="-no-undefined"
 102 ANJUTA_PLUGIN_LDFLAGS="-module -avoid-version -no-undefined"
 103 AC_SUBST(ANJUTA_LDFLAGS)
 104 AC_SUBST(ANJUTA_PLUGIN_LDFLAGS)
 105
 106 dnl GSettings
 107 GLIB_GSETTINGS
 108
 109 dnl Disable deprecated APIs
 110 dnl if test x$MAINT = x; then
 111 dnl     DEPRECATED_FLAGS="-DGDK_DISABLE_DEPRECATED -DGTK_DISABLE_DEPRECATED"
 112 dnl     AC_SUBST(DEPRECATED_FLAGS)
 113 dnl fi
 114
 115 dnl Check for pkg-config
 116 PKG_PROG_PKG_CONFIG([0.22])
 117
 118 dnl Enable versioned user preferences directory
 119 AC_ARG_WITH(pref-suffix,
 120   AS_HELP_STRING([--with-pref-suffix=VALUE],[Suffix to add to user preferences dir.]),
 121   PREF_SUFFIX="$withval")
 122
 123 AC_SUBST(PREF_SUFFIX)
 124 AC_DEFINE_UNQUOTED(PREF_SUFFIX,
 125       "${PREF_SUFFIX}",
 126           [Suffix to add to preferences directory])
 127
 128 # Initialize libtool
 129 LT_PREREQ([2.2])
 130 LT_INIT([disable-static])
 131
 132 dnl ***************************************************************************
 133 dnl Check for GObject-Introspection
 134 dnl ***************************************************************************
 135 m4_ifdef([GOBJECT_INTROSPECTION_CHECK], [GOBJECT_INTROSPECTION_CHECK([0.6.7])],
 136 [AM_CONDITIONAL(HAVE_INTROSPECTION, false)])
 137
 138 dnl ***************************************************************************
 139 dnl Set gjsdir
 140 dnl ***************************************************************************
 141 gjsdir=`pkg-config --variable=jsdir gjs-1.0`
 142 AC_SUBST(gjsdir)
 143
 144 dnl Check base modules
 145
 146 PKG_CHECK_MODULES([ANJUTA],
 147    [gthread-2.0 >= $GTHREAD_REQUIRED
 148         glib-2.0 >= $GLIB_REQUIRED
 149         gio-2.0 >= $GLIB_REQUIRED
 150         gmodule-2.0 >= $GLIB_REQUIRED
 151         gtk+-3.0 >= $GTK_REQUIRED
 152         gdk-pixbuf-2.0 >= $GDK_PIXBUF_REQUIRED])
 153
 154 PKG_CHECK_MODULES([XML],
 155    [libxml-2.0 >= $LIBXML_REQUIRED])
 156
 157 PKG_CHECK_MODULES([GDL],
 158    [gdl-3.0 >= $GDL_REQUIRED])
 159
 160 PKG_CHECK_MODULES([GDA],
 161    [libgda-5.0 >= $GDA5_REQUIRED],,
 162    [PKG_CHECK_MODULES([GDA],
 163       [libgda-4.0 >= $GDA4_REQUIRED])])
 164
 165 PKG_CHECK_MODULES([VTE],
 166    [vte-2.90 >= $VTE_REQUIRED])
 167
 168 dnl Check for autogen
 169 dnl -----------------
 170 AC_PATH_PROG(AUTOGEN_PATH, autogen,no)
 171 if test x$AUTOGEN_PATH = xno; then
 172    AC_MSG_WARN([Couldn't find autogen. You will be able to build anjuta without autogen \
 173                 but several things won't work. You can get it from http://autogen.sourceforge.net/])
 174 fi
 175
 176 dnl Check for Devhelp
 177 dnl -----------------
 178
 179 AC_ARG_ENABLE(plugin-devhelp,
 180   AS_HELP_STRING([--disable-plugin-devhelp],[Disable devhelp plugin support in Anjuta.]),
 181   [ if test "$enableval" = "no"; then
 182        user_disabled_devhelp=1
 183     fi ],
 184   [ user_disabled_devhelp=0 ] )
 185
 186 AC_MSG_CHECKING(if devhelp plugin is disabled)
 187 if test "$user_disabled_devhelp" = 1; then
 188         AC_MSG_RESULT(yes)
 189         devhelp_enabled="no"
 190 else
 191         AC_MSG_RESULT(no)
 192         PKG_CHECK_MODULES(PLUGIN_DEVHELP,
 193                                 [libdevhelp-3.0 >= $LIBDEVHELP_REQUIRED],
 194                                 [
 195                                     devhelp_enabled=yes
 196                                 ], [
 197                                     devhelp_enabled=no
 198                                 ])
 199 fi
 200
 201 if test "x$devhelp_enabled" = "xyes"; then
 202         case "$PLUGIN_DEVHELP_LIBS" in
 203                 *webkit2gtk-3.0*)
 204                         AC_DEFINE([HAVE_WEBKIT2], [1], [Defined if devhelp is built against webkitgtk2])
 205                         ;;
 206                 esac
 207 fi
 208 AM_CONDITIONAL(HAVE_PLUGIN_DEVHELP, [test x$devhelp_enabled = xyes])
 209
 210 dnl Check for Glade3
 211 dnl ---------------------
 212
 213 AC_ARG_ENABLE(plugin-glade,
 214   AS_HELP_STRING([--disable-plugin-glade],[Disable glade plugin support in Anjuta.]),
 215   [ if test "$enableval" = "no"; then
 216        user_disabled_glade=1
 217     fi ],
 218   [ user_disabled_glade=0 ] )
 219
 220 AC_MSG_CHECKING(if glade plugin is disabled)
 221 if test "$user_disabled_glade" = 1; then
 222         AC_MSG_RESULT(yes)
 223         gladeui_found="no"
 224 else
 225         AC_MSG_RESULT(no)
 226         gladeui_version=0
 227         PKG_CHECK_MODULES(PLUGIN_GLADE, gladeui-2.0 >= $GLADEUI_REQUIRED,
 228             [
 229                 gladeui_found=yes
 230             ], [
 231                 gladeui_found=no
 232             ])
 233 fi
 234
 235 AM_CONDITIONAL(HAVE_PLUGIN_GLADE, [test x$gladeui_found = xyes])
 236
 237 dnl Check for gtksourceview
 238 dnl -------------------------------------------------------------
 239 PKG_CHECK_MODULES(SOURCEVIEW,
 240                 [gtksourceview-3.0 >= $GTKSOURCEVIEW_REQUIRED])
 241
 242 dnl Check for vala
 243 dnl -------------------------------------------------------------
 244
 245 AC_ARG_ENABLE(vala,
 246         AS_HELP_STRING([--disable-vala],[Disable vala support]),
 247         [ if test "$enableval" = "no"; then
 248                 user_disabled_vala=1
 249           fi ],
 250         [ user_disabled_vala=0 ])
 251
 252 AC_MSG_CHECKING(if vala support is disabled)
 253 if test "$user_disabled_vala" = 1; then
 254         AC_MSG_RESULT(yes)
 255         enable_vala="no"
 256 else
 257         AC_MSG_RESULT(no)
 258         AC_MSG_CHECKING(if libvala is available)
 259         PKG_CHECK_EXISTS([ libvala-0.18 ],
 260                          [ valaver="-0.18" ],
 261                          [ PKG_CHECK_EXISTS([ libvala-0.16 ],
 262                                             [ valaver="-0.16" ],
 263                                             [ valaver="" ])
 264                          ])
 265         if test "x$valaver" != "x"; then
 266                 AC_MSG_RESULT(yes)
 267                 enable_vala="yes"
 268                 LIBVALA="libvala${valaver}"
 269                 PKG_CHECK_MODULES([VALA], ${LIBVALA})
 270         else
 271                 AC_MSG_RESULT(no)
 272                 enable_vala="no"
 273                 VALA_REQUIRED=0.16.0
 274         fi
 275         AC_SUBST(LIBVALA)
 276 fi
 277
 278 if test x$enable_vala = xyes; then
 279         AC_PATH_PROGS(VALAC, [valac${valaver} valac], valac)
 280         AC_SUBST(VALAC)
 281 fi
 282
 283 AM_CONDITIONAL(ENABLE_VALA, [test x$enable_vala = xyes])
 284
 285 dnl Check for Python
 286 dnl -------------------------------------------------------------
 287
 288 AM_PATH_PYTHON([],
 289         [have_python="yes"],
 290         [have_python="no"])
 291
 292 if test x$have_python = xyes; then
 293         if test -x $PYTHON-config; then
 294                 PYTHON_CFLAGS=`$PYTHON-config --cflags`
 295                 PYTHON_LIBS=`$PYTHON-config --libs`
 296                 AC_SUBST(PYTHON_CFLAGS)
 297                 AC_SUBST(PYTHON_LIBS)
 298         elif test -x $PYTHON$PYTHON_VERSION-config; then
 299                 PYTHON_CFLAGS=`$PYTHON$PYTHON_VERSION-config --cflags`
 300                 PYTHON_LIBS=`$PYTHON$PYTHON_VERSION-config --libs`
 301                 AC_SUBST(PYTHON_CFLAGS)
 302                 AC_SUBST(PYTHON_LIBS)
 303         else
 304                 have_python="no"
 305                 echo "$PYTHON-config or $PYTHON$PYTHON_VERSION-config not found - disabling python"
 306         fi
 307 fi
 308
 309 AM_CONDITIONAL(HAVE_PYTHON, [test x$have_python = xyes])
 310
 311 dnl Disable packagekit support
 312 dnl -----------------------------------
 313 AC_ARG_ENABLE(packagekit,
 314   [AC_HELP_STRING([--disable-packagekit],[build without PackageKit support])],,
 315   [enable_packagekit=yes])
 316 if test "x$enable_packagekit" != "xno"; then
 317   AC_DEFINE(ENABLE_PACKAGEKIT, 1, [define to enable PackageKit installer])
 318 fi
 319
 320 dnl Setup Anjuta Library flags
 321 dnl --------------------------
 322 LIBANJUTA_CFLAGS='$(ANJUTA_CFLAGS) $(GDL_CFLAGS) $(DEPRECATED_FLAGS) -I$(top_srcdir) -I$(top_builddir)/libanjuta -DPACKAGE_PIXMAPS_DIR=\""$(datadir)/pixmaps/$(PACKAGE)"\" -DPACKAGE_LIB_DIR=\""$(pkglibdir)"\" -DPACKAGE_DATA_DIR=\""$(datadir)/$(PACKAGE)"\"'
 323 LIBANJUTA_LIBS='$(top_builddir)/libanjuta/libanjuta-3.la'
 324 AC_SUBST(LIBANJUTA_CFLAGS)
 325 AC_SUBST(LIBANJUTA_LIBS)
 326
 327 dnl Setup FooCanvas Library flags
 328 dnl --------------------------
 329 LIBFOOCANVAS_CFLAGS='-I$(top_srcdir)'
 330 LIBFOOCANVAS_LIBS='$(top_builddir)/libfoocanvas/libanjuta-foocanvas.la'
 331 AC_SUBST(LIBFOOCANVAS_CFLAGS)
 332 AC_SUBST(LIBFOOCANVAS_LIBS)
 333
 334 dnl Checks for Xft/XRender for foocanvas
 335 dnl
 336 AC_CHECK_LIB(Xrender, XRenderFindFormat,
 337         [AC_SUBST(RENDER_LIBS, "-lXrender -lXext")
 338          AC_DEFINE(HAVE_RENDER, 1, [Define if libXrender is available.])],
 339         [AC_SUBST(RENDER_LIBS, "")],
 340         [-lXext])
 341
 342 dnl Setup Plugin directories
 343 dnl ------------------------
 344 anjuta_plugin_dir='$(libdir)/anjuta'
 345 anjuta_data_dir='$(datadir)/anjuta'
 346 anjuta_ui_dir='$(datadir)/anjuta/ui'
 347 anjuta_glade_dir='$(datadir)/anjuta/glade'
 348 anjuta_image_dir='$(datadir)/pixmaps/anjuta'
 349 AC_SUBST(anjuta_plugin_dir)
 350 AC_SUBST(anjuta_data_dir)
 351 AC_SUBST(anjuta_ui_dir)
 352 AC_SUBST(anjuta_glade_dir)
 353 AC_SUBST(anjuta_image_dir)
 354
 355 dnl ***************************************************************************
 356 dnl Check for marshal and enum generators
 357 dnl ***************************************************************************
 358 GLIB_GENMARSHAL="`$PKG_CONFIG --variable=glib_genmarshal glib-2.0`"
 359 AC_SUBST(GLIB_GENMARSHAL)
 360 GLIB_MKENUMS="`$PKG_CONFIG --variable=glib_mkenums glib-2.0`"
 361 AC_SUBST(GLIB_MKENUMS)
 362
 363 dnl Set up Glade 3 catlog information
 364 dnl ---------------------
 365 GLADE_PLUGINS_PATH="`$PKG_CONFIG --variable=moduledir gladeui-1.0`"
 366 AC_SUBST(GLADE_PLUGINS_PATH)
 367 GLADE_CATALOG_PATH="`$PKG_CONFIG --variable=catalogdir gladeui-1.0`"
 368 AC_SUBST(GLADE_CATALOG_PATH)
 369
 370 dnl ***************************************************************************
 371 dnl Internatinalization
 372 dnl ***************************************************************************
 373 IT_PROG_INTLTOOL([0.40.1])
 374
 375 AM_GNU_GETTEXT([external])
 376 AM_GNU_GETTEXT_VERSION([0.17])
 377
 378 GETTEXT_PACKAGE=anjuta
 379 AC_SUBST(GETTEXT_PACKAGE)
 380 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE", [GETTEXT package name])
 381
 382 BISON_I18N
 383
 384 dnl ***************************************************************************
 385 dnl Check for gtk-doc.
 386 dnl ***************************************************************************
 387 GTK_DOC_CHECK([1.4])
 388
 389 dnl ***************************************************************************
 390 dnl User manual
 391 dnl ***************************************************************************
 392 YELP_HELP_INIT
 393
 394 dnl Define convenience macros
 395 dnl -------------------------
 396 dnl CHECK_HEADER_DEFINE(LABEL, HEADER [,ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND ] ])
 397 AC_DEFUN([CHECK_HEADER_DEFINE],
 398 [
 399         AC_MSG_CHECKING("if $1 is defined in $2")
 400         AC_EGREP_CPP(yes,
 401 [#include <$2>
 402 #ifdef $1
 403   yes
 404 #endif
 405 ], [
 406         AC_MSG_RESULT(yes)
 407         $3
 408 ], [
 409         AC_MSG_RESULT(no)
 410         $4
 411 ]) ])
 412
 413 dnl Checks for header files.
 414 AC_CHECK_HEADERS(dirent.h fcntl.h fnmatch.h stat.h stdlib.h string.h stdint.h)
 415 AC_CHECK_HEADERS(time.h types.h unistd.h)
 416 AC_CHECK_HEADERS(sys/dir.h sys/stat.h sys/times.h sys/types.h)
 417
 418 dnl Checks for typedefs, structures, and compiler characteristics.
 419
 420 AC_CANONICAL_HOST
 421 CYGWIN=no
 422 MINGW32=no
 423 case $host_os in
 424   *cygwin* ) CYGWIN=yes;;
 425   *mingw32* ) MINGW32=yes;;
 426 esac
 427
 428
 429 dnl Check for bind in libsocket (needed on Solaris)
 430 AC_CHECK_LIB(socket, bind)
 431
 432 dnl Check for function forkpty and related headers
 433 AC_SEARCH_LIBS(forkpty, util, , AC_DEFINE(EMULATE_FORKPTY, [], [Need  to implement our own forkpty()]))
 434 AC_CHECK_HEADERS(libutil.h util.h pty.h)
 435
 436 dnl Checks for library functions.
 437 AC_CHECK_FUNCS(fnmatch)
 438 AC_CHECK_FUNCS(strstr)
 439 AC_CHECK_FUNCS(stricmp)
 440 AC_CHECK_FUNCS(strnicmp)
 441 AC_CHECK_FUNCS(getline)
 442
 443 dnl for libegg/egg-recent-model.c
 444 AC_CHECK_DECLS([lockf])
 445 AC_CHECK_FUNCS([lockf])
 446
 447 AC_CHECK_FUNCS(fgetpos, have_fgetpos=yes)
 448
 449 dnl SEEK_SET should be in stdio.h, but may be in unistd.h on SunOS 4.1.x
 450 if test "$have_fgetpos" != yes ; then
 451     CHECK_HEADER_DEFINE(SEEK_SET, stdio.h,,
 452         CHECK_HEADER_DEFINE(SEEK_SET, unistd.h,,
 453             AC_DEFINE(SEEK_SET, 0, [Seek set 0])))
 454 fi
 455
 456 AC_CHECK_FUNCS(mkstemp, have_mkstemp=yes)
 457 if test "$have_mkstemp" != yes ; then
 458     AC_CHECK_FUNCS(chmod)
 459     if test "$tmpdir_specified" = yes ; then
 460         AC_MSG_RESULT(use of tmpnam overrides temporary directory selection)
 461     fi
 462 else
 463     AC_MSG_CHECKING(directory to use for temporary files)
 464     if test -z "$enable_tmpdir" -o "$enable_tmpdir" = no -o "$enable_tmpdir" = yes ;
 465         then tmpdir=/tmp
 466         else tmpdir="$enable_tmpdir"
 467     fi
 468     if test -d $tmpdir ; then
 469         AC_MSG_RESULT($tmpdir)
 470         AC_DEFINE_UNQUOTED(TMPDIR, "$tmpdir", [Directory for temporary files])
 471     else
 472         AC_MSG_WARN($tmpdir does not exist)
 473     fi
 474 fi
 475
 476 dnl -----------------------------
 477 dnl Checks for FreeBSD Build
 478 dnl -----------------------------
 479 AC_MSG_CHECKING(if building on FreeBSD)
 480
 481 if test `uname -s` = "FreeBSD" ; then
 482         AC_MSG_RESULT(yes)
 483         FREEBSD_BUILD=-DFREEBSD
 484         AC_SUBST(FREEBSD_BUILD)
 485         AC_PATH_PROG(GMAKE, gmake, no)
 486         if test "x$GMAKE" = "xno"; then
 487                 AC_MSG_ERROR(You need gmake installed to build Anjuta!)
 488         fi
 489 else
 490         AC_MSG_RESULT(no)
 491         GMAKE="make"
 492 fi
 493
 494 AC_SUBST(GMAKE)
 495
 496 dnl Checks for missing prototypes
 497 dnl -----------------------------
 498 AC_MSG_NOTICE([checking for missing prototypes...])
 499
 500 AC_DEFUN([CHECK_PROTO], [AC_EGREP_HEADER([[^A-Za-z0-9_]$1([   ]+[A-Za-z0-9_]*)?\(], $2,, AC_DEFINE(patsubst([NEED_PROTO_NAME], [NAME], translit($1, [a-z], [A-Z])),,[Do not know]) AC_MSG_RESULT(adding prototype for $1))])
 501
 502 if test "$have_remove" = yes ; then
 503     CHECK_PROTO(remove, stdio.h)
 504 else
 505     CHECK_PROTO(unlink, unistd.h)
 506 fi
 507 CHECK_PROTO(malloc, stdlib.h)
 508 CHECK_PROTO(getenv, stdlib.h)
 509 CHECK_PROTO(stat,   sys/stat.h)
 510 CHECK_PROTO(lstat,  sys/stat.h)
 511 if test "$have_fgetpos" = yes ; then
 512     CHECK_PROTO(fgetpos, stdio.h)
 513 fi
 514 if test "$have_truncate" = yes ; then
 515     CHECK_PROTO(truncate, unistd.h)
 516 fi
 517 if test "$have_ftruncate" = yes ; then
 518     CHECK_PROTO(ftruncate, unistd.h)
 519 fi
 520
 521 dnl  **********************************************************
 522 dnl  check if we have svn libraries to build subversion plugin
 523 dnl  (stolen from kdevelop ;-)
 524 dnl  **********************************************************
 525
 526 AC_MSG_CHECKING(for Subversion svn-config)
 527 AC_ARG_WITH(subversion-dir,
 528                 AS_HELP_STRING([--with-subversion-dir=DIR],[Where Subversion is installed ]),
 529                 [
 530                                 SVNCONFIG="$withval/bin/svn-config"
 531                 ])
 532
 533 if test -z "$SVNCONFIG"; then
 534                 _SVNCONFIG="`svn-config --prefix 2> /dev/null`"
 535                 if test -n "$_SVNCONFIG"; then
 536                                 SVNCONFIG="$_SVNCONFIG/bin/svn-config"
 537                 fi
 538 fi
 539
 540 AC_SUBST(SVNCONFIG)
 541 if test -x "$SVNCONFIG"; then
 542                 SVNLD="`$SVNCONFIG --ldflags 2> /dev/null`"
 543                 SVN_LIB="`$SVNCONFIG --libs --cflags 2> /dev/null` -lsvn_client-1 -lsvn_subr-1"
 544                 dnl ugly hack for subversion svn-config problems in 0.14.x, to be removed when svn-config is fixed
 545                 SVN_INCLUDE="`$SVNCONFIG --includes 2> /dev/null` -I$_SVNCONFIG/include/subversion-1/"
 546                 AC_MSG_RESULT(yes)
 547 else
 548                 AC_MSG_RESULT(not found)
 549
 550                 dnl just a fallback to debian's config so that it works for me :)
 551                 AC_ARG_WITH(svn-include,
 552                                                                 [[  --with-svn-include=DIR   Use the given path to the subversion headers.]],
 553                                                                 [
 554                                                                 if test "$withval" != "yes" -a "$withval" != ""; then
 555                                                                                 SVN_INCLUDES=$withval
 556                                                                 fi
 557                                                                 ])
 558                 if test -z "$SVN_INCLUDES"; then
 559                         SVN_INCLUDES="/usr/local/include /usr/include"
 560                 fi
 561                 AC_MSG_CHECKING([for Subversion headers])
 562                 SVN_INCLUDE=""
 563                 for VALUE in $SVN_INCLUDES ; do
 564                                 if test -f $VALUE/subversion-1/svn_types.h ; then
 565                                                 SVN_INCLUDE=$VALUE/subversion-1
 566                                                 break
 567                                 fi
 568                                 if test -f $VALUE/svn_types.h ; then
 569                                                 SVN_INCLUDE=$VALUE
 570                                                 break
 571                                 fi
 572                 done
 573                 if test $SVN_INCLUDE ; then
 574                                 AC_MSG_RESULT([found])
 575                 else
 576                                 AC_MSG_RESULT([not found])
 577                 fi
 578                 SVN_LIBS="/usr/local/lib64 /usr/local/lib /usr/lib64 /usr/lib"
 579                 AC_ARG_WITH(svn-lib,
 580                                                 [[  --with-svn-lib=DIR  Use the given path to the subversion libraries.]],
 581                                                 [
 582                                                         if test "$withval" != "yes" -a "$withval" != ""; then
 583                                                                 SVN_LIBS=$withval
 584                                                         fi
 585                                                 ])
 586                 AC_MSG_CHECKING([for Subversion libraries])
 587                 SVN_LIB=""
 588                 for VALUE in $SVN_LIBS ; do
 589                                 if ls $VALUE/libsvn_client-1.* 1>/dev/null 2>&1; then
 590                                                 SVN_LIB=$VALUE
 591                                                 break
 592                                 fi
 593                 done
 594                 if test $SVN_LIB ; then
 595                                 AC_MSG_RESULT([found])
 596                 else
 597                                 AC_MSG_RESULT([not found])
 598                 fi
 599 fi
 600
 601 dnl ******************************************************************
 602 dnl Check for extra libs required by subversion.
 603 dnl FIXME: This should actually be done by subversion and not by us.
 604 dnl ******************************************************************
 605
 606 AC_ARG_ENABLE(plugin-subversion,
 607   AS_HELP_STRING([--disable-plugin-subversion],[Disable subversion support in Anjuta.]),
 608   [ if test "$enableval" = "no"; then
 609         user_disabled_subversion=1
 610     fi ],
 611   [ user_disabled_subversion=0 ] )
 612
 613 AC_MSG_CHECKING(if subversion support is disabled)
 614 if test "$user_disabled_subversion" = 1; then
 615         AC_MSG_RESULT(yes)
 616         SVN_INCLUDE=""
 617         SVN_LIB=""
 618 else
 619         AC_MSG_RESULT(no)
 620 fi
 621
 622 if test -n "$SVN_INCLUDE" ; then
 623         dnl ------------------------------------
 624         dnl APR. Required by subversion (devel)
 625         dnl ------------------------------------
 626         have_atr=no
 627         PKG_CHECK_MODULES(APR,                            \
 628                 apr-1, have_apr=yes, have_apr=no)
 629         if test x"$have_apr" = "xno"; then
 630                 SVN_INCLUDE=""
 631         fi
 632
 633         dnl -----------------------------------------
 634         dnl APR util. Required by subversion (devel)
 635         dnl------------------------------------------
 636         have_atr_util=no
 637         PKG_CHECK_MODULES(APR_UTILS,                            \
 638                 apr-util-1, have_apr_util=yes, have_apr_util=no)
 639         if test x"$have_apr_util" = "xno"; then
 640                 SVN_INCLUDE=""
 641         fi
 642
 643         dnl -----------------------------------------
 644         dnl NEON. Required by subversion (devel)
 645         dnl------------------------------------------
 646         have_neon=no
 647         PKG_CHECK_MODULES(NEON,                            \
 648                 neon, have_neon=yes, have_neon=no)
 649         if test x"$have_neon" = "xno"; then
 650                 SVN_INCLUDE=""
 651         fi
 652
 653         dnl Make sure our SVN version is high enough
 654         dnl Eww, eww, eww, this is dirty
 655         AC_MSG_CHECKING([for subversion >= $SUBVERSION_REQUIRED])
 656         AC_LANG([C])
 657         dnl Temporarily set CFLAGS so that include dirs are found
 658         CFLAGS_TMP=$CFLAGS
 659         CFLAGS="-I$SVN_INCLUDE $APR_CFLAGS"
 660         AC_COMPILE_IFELSE(
 661                 [AC_LANG_PROGRAM([[#include <svn_version.h>]],
 662                         [[
 663                                 #if (SVN_VER_MAJOR < $SVN_MAJOR) || (SVN_VER_MINOR < $SVN_MINOR) || (SVN_VER_PATCH < $SVN_PATCH)
 664                                 #       error "Version too low"
 665                                 #endif
 666                         ]])], AC_MSG_RESULT(yes), have_svn_version=no)
 667         if test x"$have_svn_version" = "xno"; then
 668                 AC_MSG_RESULT(no)
 669                 SVN_INCLUDE=""
 670         fi
 671         CFLAGS=$CFLAGS_TMP
 672 fi
 673
 674 dnl ------------------------------------------
 675 dnl Finally prepare subversion build flags
 676 dnl ------------------------------------------
 677
 678 if test -n "$SVN_INCLUDE" ; then
 679         SVN_INCLUDE="-I$SVN_INCLUDE"
 680         if test x != "x$SVN_LIB" ; then
 681             SVN_LIB="-L$SVN_LIB $APR_LIBS $APR_UTILS_LIBS $NEON_LIBS -lsvn_client-1 -lsvn_subr-1"
 682         else
 683             SVN_LIB="$APR_LIBS $APR_UTILS_LIBS $NEON_LIBS -lsvn_client-1 -lsvn_subr-1"
 684         fi
 685         SVN_CFLAGS="$APR_CFLAGS $APR_UTILS_CFLAGS $NEON_CFLAGS"
 686 fi
 687
 688 AM_CONDITIONAL(BUILD_SVN, [test -n "$SVN_INCLUDE"])
 689 AC_SUBST(SVN_INCLUDE)
 690 AC_SUBST(SVN_LIB)
 691 AC_SUBST(SVN_CFLAGS)
 692
 693 dnl ------------------------------------------
 694 dnl Symbol-db shared memory checks
 695 dnl ------------------------------------------
 696
 697 SYMBOL_DB_SHM="/dev/shm"
 698 user_specified_shm=0
 699 AC_MSG_CHECKING(for symbol-db shared memory)
 700 AC_ARG_WITH(symbol-db-shm,
 701                 AS_HELP_STRING([--with-symbol-db-shm=DIR],[Where shared memory is placed ]),
 702                 [
 703                                 user_specified_shm=1
 704                                 SYMBOL_DB_SHM="$withval"
 705                 ])
 706 if test "$user_specified_shm" = 1; then
 707         AC_MSG_RESULT(yes)
 708 else
 709         AC_MSG_RESULT(no)
 710 fi
 711
 712 AC_SUBST(SYMBOL_DB_SHM)
 713
 714 dnl Test using autotest
 715 dnl -----------------------------
 716 AC_CONFIG_TESTDIR(plugins/am-project/tests)
 717 AM_MISSING_PROG([AUTOM4TE], [autom4te])
 718
 719 AC_CONFIG_FILES([
 720 Makefile
 721 po/Makefile.in
 722 libanjuta/Makefile
 723 libanjuta/tests/Makefile
 724 libanjuta/interfaces/Makefile
 725 libanjuta/libanjuta-3.0.pc
 726 libanjuta/anjuta-version.h
 727 src/Makefile
 728 pixmaps/Makefile
 729 pixmaps/16x16/Makefile
 730 pixmaps/22x22/Makefile
 731 pixmaps/24x24/Makefile
 732 pixmaps/32x32/Makefile
 733 pixmaps/48x48/Makefile
 734 pixmaps/scalable/Makefile
 735 data/Makefile
 736 data/welcome.txt
 737 data/templates/Makefile
 738 doc/anjuta.1
 739 doc/anjuta-launcher.1
 740 doc/Makefile
 741 scripts/Makefile
 742 launcher/Makefile
 743 plugins/Makefile
 744 plugins/class-gen/Makefile
 745 plugins/class-gen/templates/Makefile
 746 plugins/patch/Makefile
 747 plugins/document-manager/Makefile
 748 plugins/document-manager/images/Makefile
 749 plugins/message-view/Makefile
 750 plugins/gdb/Makefile
 751 plugins/gdb/images/Makefile
 752 plugins/debug-manager/Makefile
 753 plugins/debug-manager/images/Makefile
 754 plugins/devhelp/Makefile
 755 plugins/devhelp/images/Makefile
 756 plugins/glade/Makefile
 757 plugins/glade/images/Makefile
 758 plugins/js-debugger/Makefile
 759 plugins/file-manager/Makefile
 760 plugins/file-loader/Makefile
 761 plugins/file-wizard/Makefile
 762 plugins/build-basic-autotools/Makefile
 763 plugins/project-manager/Makefile
 764 plugins/symbol-db/benchmark/Makefile
 765 plugins/symbol-db/benchmark/symbol-db/Makefile
 766 plugins/symbol-db/benchmark/libgda/Makefile
 767 plugins/symbol-db/benchmark/sqlite/Makefile
 768 plugins/symbol-db/images/Makefile
 769 plugins/symbol-db/Makefile
 770 plugins/symbol-db/anjuta-tags/Makefile
 771 plugins/project-wizard/Makefile
 772 plugins/snippets-manager/Makefile
 773 plugins/cvs-plugin/Makefile
 774 plugins/subversion/Makefile
 775 plugins/git/Makefile
 776 plugins/git/images/Makefile
 777 plugins/sourceview/Makefile
 778 plugins/terminal/Makefile
 779 plugins/tools/Makefile
 780 plugins/tools/scripts/Makefile
 781 plugins/language-manager/Makefile
 782 plugins/project-import/Makefile
 783 plugins/project-wizard/templates/Makefile
 784 plugins/project-wizard/templates/mkfile/Makefile
 785 plugins/project-wizard/templates/mkfile/src/Makefile
 786 plugins/project-wizard/templates/mkfile/po/Makefile
 787 plugins/project-wizard/templates/minimal/Makefile
 788 plugins/project-wizard/templates/js_minimal/Makefile
 789 plugins/project-wizard/templates/js_minimal/src/Makefile
 790 plugins/project-wizard/templates/terminal/Makefile
 791 plugins/project-wizard/templates/terminal/src/Makefile
 792 plugins/project-wizard/templates/terminal/po/Makefile
 793 plugins/project-wizard/templates/cpp/Makefile
 794 plugins/project-wizard/templates/cpp/src/Makefile
 795 plugins/project-wizard/templates/cpp/po/Makefile
 796 plugins/project-wizard/templates/gtk/Makefile
 797 plugins/project-wizard/templates/gtk/src/Makefile
 798 plugins/project-wizard/templates/gtk/po/Makefile
 799 plugins/project-wizard/templates/gtkapplication/Makefile
 800 plugins/project-wizard/templates/gtkapplication/src/Makefile
 801 plugins/project-wizard/templates/gtkapplication/po/Makefile
 802 plugins/project-wizard/templates/anjuta-plugin/Makefile
 803 plugins/project-wizard/templates/anjuta-plugin/src/Makefile
 804 plugins/project-wizard/templates/anjuta-plugin/po/Makefile
 805 plugins/project-wizard/templates/gtkmm/Makefile
 806 plugins/project-wizard/templates/gtkmm/src/Makefile
 807 plugins/project-wizard/templates/gtkmm/po/Makefile
 808 plugins/project-wizard/templates/gcj/Makefile
 809 plugins/project-wizard/templates/gcj/src/Makefile
 810 plugins/project-wizard/templates/java/Makefile
 811 plugins/project-wizard/templates/java/src/Makefile
 812 plugins/project-wizard/templates/java/po/Makefile
 813 plugins/project-wizard/templates/python/Makefile
 814 plugins/project-wizard/templates/python/src/Makefile
 815 plugins/project-wizard/templates/python/po/Makefile
 816 plugins/project-wizard/templates/pygtk/Makefile
 817 plugins/project-wizard/templates/pygtk/src/Makefile
 818 plugins/project-wizard/templates/pygtk/po/Makefile
 819 plugins/project-wizard/templates/vala-gtk/Makefile
 820 plugins/project-wizard/templates/vala-gtk/src/Makefile
 821 plugins/project-wizard/templates/wxwin/Makefile
 822 plugins/project-wizard/templates/wxwin/src/Makefile
 823 plugins/project-wizard/templates/wxwin/po/Makefile
 824 plugins/project-wizard/templates/xlib/Makefile
 825 plugins/project-wizard/templates/xlib/src/Makefile
 826 plugins/project-wizard/templates/xlib/po/Makefile
 827 plugins/project-wizard/templates/xlib-dock/Makefile
 828 plugins/project-wizard/templates/xlib-dock/src/Makefile
 829 plugins/project-wizard/templates/xlib-dock/po/Makefile
 830 plugins/project-wizard/templates/sdl/Makefile
 831 plugins/project-wizard/templates/sdl/src/Makefile
 832 plugins/project-wizard/templates/sdl/po/Makefile
 833 plugins/project-wizard/templates/library/Makefile
 834 plugins/project-wizard/templates/library/src/Makefile
 835 plugins/project-wizard/templates/library/po/Makefile
 836 plugins/project-wizard/templates/directory/Makefile
 837 plugins/project-wizard/templates/m4/Makefile
 838 plugins/project-wizard/templates/gnome-shell-extension/Makefile
 839 plugins/project-wizard/templates/gnome-shell-extension/src/Makefile
 840 plugins/am-project/Makefile
 841 plugins/am-project/tests/atlocal
 842 plugins/am-project/tests/Makefile
 843 plugins/mk-project/Makefile
 844 plugins/dir-project/Makefile
 845 plugins/language-support-cpp-java/Makefile
 846 plugins/run-program/Makefile
 847 plugins/starter/Makefile
 848 plugins/indentation-c-style/Makefile
 849 plugins/indentation-python-style/Makefile
 850 plugins/language-support-js/Makefile
 851 plugins/language-support-vala/Makefile
 852 plugins/language-support-python/Makefile
 853 plugins/parser-cxx/Makefile
 854 plugins/parser-cxx/cxxparser/Makefile
 855 plugins/python-loader/Makefile
 856 plugins/jhbuild/Makefile
 857 plugins/quick-open/Makefile
 858 anjuta.desktop.in
 859 manuals/Makefile
 860 manuals/reference/Makefile
 861 manuals/reference/libanjuta/Makefile
 862 manuals/reference/libanjuta/version.xml
 863 manuals/anjuta-manual/Makefile
 864 manuals/anjuta-faqs/Makefile
 865 manuals/anjuta-build-tutorial/Makefile
 866 mime/Makefile
 867 ])
 868 AC_OUTPUT
 869 echo " "
 870 echo "-------------------------------------------------------------------"
 871 echo "Conditionally built plugins:"
 872 echo "-------------------------------------------------------------------"
 873 if [ test -n "$SVN_INCLUDE" ]; then
 874         echo "Building subversion plugin: ............................YES"
 875 else
 876         echo "Building subversion plugin: ............................NO"
 877                 echo "        Requires apr (>= 0.9.4); http://subversion.org"
 878                 echo "        Requires apr-util (>= 0.9.4); http://subversion.org"
 879                 echo "        Requires neon (>= 0.28.2); http://subversion.org"
 880                 echo "        Requires subversion (>= 1.5); http://subversion.org"
 881 fi
 882
 883 if [ test x$gladeui_found = xyes ]; then
 884        echo "Building glade plugin: .................................YES"
 885 else
 886        echo "Building glade plugin: .................................NO"
 887        echo "        Requires glade-3 (>= $GLADEUI_REQUIRED)"
 888 fi
 889
 890 if [ test x$devhelp_enabled = xyes ]; then
 891        echo "Building devhelp plugin: ...............................YES"
 892 else
 893        echo "Building devhelp plugin: ...............................NO"
 894        echo "        Requires libdevhelp-3.0 (>= $LIBDEVHELP_REQUIRED)"
 895 fi
 896 if [ test x$enable_vala = xyes ]; then
 897         echo "Building Vala support: .................................YES"
 898 else
 899         echo "Building Vala support: .................................NO"
 900         echo "        Requires libvala (>= $VALA_REQUIRED)"
 901 fi
 902 if [ test x$have_python = xyes]; then
 903         echo "Building python plugin loaeder: ........................YES"
 904 else
 905         echo "Building python plugin loaeder: ........................NO"
 906         echo "        Requires python"
 907 fi
 908 echo "-------------------------------------------------------------------"
 909 echo "AM_CFLAGS = $AM_CFLAGS"
 910 echo "AM_CXXFLAGS = $AM_CXXFLAGS"