bin/testadozen.pl

   1 #!/usr/bin/perl
   2
   3 =head1 NAME
   4
   5 testadozen - randomly pick several perls to test a distro
   6
   7 =head1 SYNOPSIS
   8
   9  testadozen [options] distro ...
  10
  11 =head1 OPTIONS
  12
  13 =over 8
  14
  15 =cut
  16
  17 my @opt = <<'=back' =~ /B<--(\S+)>/g;
  18
  19 =item B<--dir=s>
  20
  21 Default: /home/src/perl/repoperls/installed-perls/perl
  22
  23 The directory where the perls are found
  24
  25 =item B<--n=i>
  26
  27 Default: 12
  28
  29 The number of tests to run.
  30
  31 =item B<--pat=s>
  32
  33 Default: v*
  34
  35 Only pick directories matching the glob.
  36
  37 =back
  38
  39 =head1 DESCRIPTION
  40
  41
  42
  43 =cut
  44
  45 use Getopt::Long;
  46 use Hash::Util qw(lock_keys);
  47 use Pod::Usage qw(pod2usage);
  48 use Text::Glob qw(match_glob);
  49 use Time::HiRes qw(sleep);
  50
  51 our %Opt;
  52 lock_keys %Opt, map { /([^=]+)/ } @opt;
  53 GetOptions(\%Opt,
  54            @opt,
  55           ) or pod2usage(1);
  56
  57 my(@distro) = @ARGV or pod2usage(1);
  58
  59 $Opt{n} = 12 unless defined $Opt{n};
  60
  61 $Opt{pat} = "v*" unless defined $Opt{pat};
  62
  63 $Opt{dir} = "/home/src/perl/repoperls/installed-perls/perl" unless defined $Opt{dir};
  64
  65 opendir my $dh, $Opt{dir} or die "Could not open '$Opt{dir}': $!";
  66 my @cand;
  67 for my $dirent (readdir $dh) {
  68     next if $dirent =~ /^\.\.?$/;
  69     if ($Opt{pat}) {
  70         next unless match_glob $Opt{pat}, $dirent;
  71     }
  72     push @cand, $dirent;
  73 }
  74 for (my $i = 0; $i < $Opt{n}; $i++) {
  75     my $j = int rand @cand;
  76     my $dirent = splice @cand, $j, 1;
  77     warn "$dirent\n";
  78     for my $distro (@distro) {
  79         0 == system "$Opt{dir}/$dirent/bin/perl -MCPAN -e 'install q[$distro]'";
  80         sleep 0.2;
  81     }
  82 }
  83
  84 1;