bin/analysis-jobqueue-rm.pl

   1 #!/usr/bin/perl
   2
   3 # use 5.010;
   4 use strict;
   5 use warnings;
   6
   7 =head1 NAME
   8
   9 analysis-jobqueue-rm.pl -- Remove one job from the redis jobqueue on analysis
  10
  11 =head1 SYNOPSIS
  12
  13  $0 jobnumber [jobnumber...]
  14
  15 =head1 OPTIONS
  16
  17 =over 8
  18
  19 =cut
  20
  21 my @opt = <<'=back' =~ /B<--(\S+)>/g;
  22
  23 =item B<--help|h!>
  24
  25 This help
  26
  27 =item B<--dry-run|n!>
  28
  29 Don't do anything, just tell what you would do
  30
  31 =back
  32
  33 =head1 DESCRIPTION
  34
  35 Remove a job by number. Does just this if argument is 639408:
  36
  37  2015-08-03 21:31  redis-cli get analysis:jobqueue:jobs:639408:hex
  38  2015-08-03 21:31  redis-cli get analysis:jobqueue:jobs:639408:descr
  39  2015-08-03 21:32  redis-cli del analysis:jobqueue:jobs:40aebf9db9a664e052e4b886d0c724bbce3cf4d4:id
  40  2015-08-03 21:32  redis-cli del analysis:jobqueue:jobs:639408:hex
  41  2015-08-03 21:32  redis-cli del analysis:jobqueue:jobs:639408:descr
  42  2015-08-03 21:33  redis-cli srem analysis:jobqueue:runningjobs 639408
  43
  44 =cut
  45
  46
  47 use FindBin;
  48 use lib "$FindBin::Bin/../lib";
  49 BEGIN {
  50     push @INC, qw(       );
  51 }
  52
  53 use Dumpvalue;
  54 use File::Basename qw(dirname);
  55 use File::Path qw(mkpath);
  56 use File::Spec;
  57 use File::Temp;
  58 use Getopt::Long;
  59 use Pod::Usage;
  60 use Hash::Util qw(lock_keys);
  61
  62 our %Opt;
  63 lock_keys %Opt, map { /([^=|!]+)/ } @opt;
  64 GetOptions(\%Opt,
  65            @opt,
  66           ) or pod2usage(1);
  67 if ($Opt{help}) {
  68     pod2usage(0);
  69 }
  70
  71 use Redis;
  72 use Time::HiRes qw(sleep);
  73 my $redis = Redis->new(reconnect => 120, every => 1000);
  74 @ARGV or pod2usage(1);
  75 for my $job_id (@ARGV) {
  76     if (my $hex = $redis->get("analysis:jobqueue:jobs:$job_id:hex")) {
  77         my $descr = $redis->get("analysis:jobqueue:jobs:$job_id:descr");
  78         warn "found job_id $job_id, hex $hex, descr $descr\n";
  79         next if $Opt{"dry-run"};
  80         for my $del_frag ("$hex\:id", "$job_id\:hex", "$job_id\:descr") {
  81             my $del = "analysis:jobqueue:jobs:$del_frag";
  82             my $ret = $redis->del($del);
  83             warn "del $del => ret $ret\n";
  84             die "Could not delete $del, giving up" unless $ret;
  85         }
  86         my $srem = "analysis:jobqueue:runningjobs";
  87         my $ret = $redis->srem($srem, $job_id);
  88         warn "srem $srem $job_id => ret $ret\n";
  89         die "Could not srem $srem $job_id, giving up" unless $ret;
  90     } else {
  91         die "Failing: Job_id $job_id unknown";
  92     }
  93 }
  94
  95 # Local Variables:
  96 # mode: cperl
  97 # cperl-indent-level: 4
  98 # End: