configure.in

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3 #
   4 # This file is part of the aMule Project.
   5 #
   6 # Copyright (c) 2003-2011 aMule Team ( admin@amule.org / http://www.amule.org )
   7 #
   8 # Any parts of this program derived from the xMule, lMule or eMule project,
   9 # or contributed by third-party developers are copyrighted by their
  10 # respective authors.
  11 #
  12 # This program is free software; you can redistribute it and/or modify
  13 # it under the terms of the GNU General Public License as published by
  14 # the Free Software Foundation; either version 2 of the License, or
  15 # (at your option) any later version.
  16 #
  17 # This program is distributed in the hope that it will be useful,
  18 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 # GNU General Public License for more details.
  21 #
  22 # You should have received a copy of the GNU General Public License
  23 # along with this program; if not, write to the Free Software
  24 # Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA  02110-1301, USA
  25 #
  26
  27 AC_INIT([aMule],[SVN],[admin@amule.org])
  28 AM_INIT_AUTOMAKE
  29 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES])
  30
  31 AC_PREREQ(2.59)
  32
  33 AC_CONFIG_SRCDIR([src/amule.cpp])
  34 AC_CONFIG_HEADERS([config.h])
  35 AC_CONFIG_MACRO_DIR([m4])
  36 AM_MAINTAINER_MODE
  37
  38 dnl Check host system.
  39 MULE_CHECK_SYSTEM
  40
  41 dnl Checks for programs.
  42 dnl Workaround for these checks may alter CFLAGS and CXXFLAGS, especially if they were empty
  43 MULE_BACKUP([CFLAGS])
  44 MULE_BACKUP([CXXFLAGS])
  45 MULE_BACKUP([BUILD_CFLAGS])
  46 AC_PROG_CXX
  47 AC_PROG_CXXCPP
  48 AC_PROG_CC
  49 AC_PROG_CPP
  50 AS_IF([test "$cross_compiling" = yes], [AC_PROG_BUILD_CC], [BUILD_CC="$CC" ; BUILD_EXEEXT=$EXEEXT])
  51 MULE_RESTORE([CFLAGS])
  52 MULE_RESTORE([CXXFLAGS])
  53 MULE_RESTORE([BUILD_CFLAGS])
  54 AC_PROG_AWK
  55 AC_PROG_EGREP
  56 AC_PROG_MAKE_SET
  57 AC_PROG_LEX
  58 AC_PROG_INSTALL
  59 AC_PROG_RANLIB
  60 AC_PROG_SED
  61 AC_PROG_YACC
  62
  63 dnl Find the right ranlib, even when cross-compiling
  64 dnl And for some other tools for cross compilation
  65 AC_CHECK_TOOL(RANLIB, ranlib)
  66 AC_CHECK_TOOL(STRIP, strip)
  67 AC_CHECK_TOOL(AR, ar)
  68 AC_CHECK_TOOL(LD, ld)
  69
  70 dnl Selectable components
  71 MULE_ARG_ENABLE([monolithic],   [yes],  [disable building of the monolithic aMule app], [MONOLITHIC])
  72 MULE_ARG_ENABLE([amule-daemon], [no],   [compile aMule daemon version], [AMULE_DAEMON])
  73 MULE_ARG_ENABLE([amulecmd],     [no],   [compile aMule command line client], [COMPILE_CMD])
  74 MULE_ARG_ENABLE([webserver],    [no],   [compile aMule WebServer], [WEB])
  75 MULE_ARG_ENABLE([amule-gui],    [no],   [compile aMule remote GUI], [AMULE_GUI])
  76 MULE_ARG_ENABLE([cas],          [no],   [compile C aMule Statistics], [CAS])
  77 MULE_ARG_ENABLE([wxcas],        [no],   [compile aMule GUI Statistics], [WXCAS])
  78 MULE_ARG_ENABLE([ed2k],         [yes],  [don't compile aMule ed2k links handler], [ED2K])
  79 MULE_ARG_ENABLE([alc],          [no],   [compile aMuleLinkCreator GUI version], [ALC])
  80 MULE_ARG_ENABLE([alcc],         [no],   [compile aMuleLinkCreator for console], [ALCC])
  81 MULE_ARG_ENABLE([xas],          [no],   [install xas XChat2 plugin], [XAS])
  82 MULE_ARG_ENABLE([fileview],     [no],   [compile aMule file viewer for console (EXPERIMENTAL)], [FILEVIEW])
  83 MULE_ARG_ENABLE([plasmamule],   [no],   [compile aMule plasma applet and engine])
  84
  85 # Run all the tests with static linkage if we want a statically linked binary
  86 MULE_ARG_ENABLE([static], [no], [produce a statically linked executable])
  87 MULE_IF_ENABLED([static], [MULE_APPEND([LDFLAGS], [-static])])
  88
  89 KDE_CONFIG_OPTIONS
  90 QT_CONFIG_OPTIONS
  91
  92 # Default is yes, because they're most likely compatible.
  93 # However, this is only used when cross-compiling.
  94 AC_ARG_WITH(
  95         [gnu-malloc],
  96         [AS_HELP_STRING([--without-gnu-malloc],
  97                 [Don't assume that we use GNU libc compatible malloc/realloc when cross-compiling])],
  98         [gnumalloc=$withval], [gnumalloc=yes])
  99
 100
 101 # Checking for libs before all other stuff to break
 102 # configure as soon as possible in case of a missing one
 103 # to avoid losing too much time
 104
 105 # Check for gd
 106 MULE_IF_ENABLED([cas], [
 107         MULE_CHECK_GDLIB([2.0.0], [
 108                 CAS_DEFS="-D__GD__"
 109                 MULE_PREPEND([GDLIB_LIBS], [-lgd])
 110         ], [CAS_DEFS=])
 111         AS_IF([test -z "$CAS_DEFS"],
 112                 [MULE_WARNING(
 113                         [gd-lib >= 2.0.0, or a functional gd.h (from gd-devel) not found.
 114                         Please check that gdlib-config is in your default path, check out LD_LIBRARY_PATH or equivalent variable.
 115                         Or this might also be that your gdlib-config has other name.
 116                         Please try again with --with-gdlib-config=/usr/bin/gdlib-config (replace /usr/bin/gdlib-config with a valid path to your gdlib-config).
 117                         If you use compiled packages check if you have devel pack installed.
 118                         To download the latest version check http://www.boutell.com/gd for sources.])])
 119 ])
 120 AC_SUBST([CAS_DEFS])dnl
 121
 122 dnl Tests explicitly requiring C. They test features of the C compiler.
 123 AC_HEADER_STDBOOL
 124 AC_C_CONST
 125 AC_C_INLINE
 126 AC_C_VOLATILE
 127
 128 dnl Use C++ for all other tests, since we use C++ to actually compile the
 129 dnl sources.  There might be differences between the compilers, thus if
 130 dnl something works in C it doesn't automatically mean it also works in C++.
 131 dnl
 132 dnl The only exception is cas which is written in pure C.
 133 AC_LANG_PUSH([C++])
 134
 135
 136 # Check for zlib
 137 MULE_IF_ENABLED_ANY([monolithic, amule-daemon, amulecmd, webserver, amule-gui],
 138         [MULE_CHECK_ZLIB([1.1.4],, [AC_MSG_ERROR([zlib >= 1.1.4 is required for aMule])])])
 139
 140
 141 # Check for libpng
 142 MULE_IF_ENABLED([webserver],
 143         [MULE_CHECK_LIBPNG([1.2.0], [AMULEWEB_DEFS="-DWITH_LIBPNG"], [
 144                 MULE_WARNING(
 145                         [libpng >= 1.2.0 not found.
 146                         amuleweb will be compiled but file download progress bar images will NOT be generated.])
 147                 ])
 148         ])
 149 AC_SUBST([AMULEWEB_DEFS])dnl
 150
 151
 152 # Check for perl File::Copy
 153 AC_MSG_CHECKING([for File::Copy])
 154 AS_IF([perl -e "require File::Copy" 2>/dev/null], [AC_MSG_RESULT([ok])],
 155         [MULE_WARNING(
 156                 [File::Copy perl module is required by the mldonkey_importer script.
 157                 If you want to use this script please install File::Copy from CPAN.])])
 158
 159
 160 # Check for GeoIP (required for IP2Country capability)
 161 MULE_IF_ENABLED_ANY([monolithic, amule-gui], [MULE_CHECK_GEOIP])
 162
 163
 164 # Check for wx
 165 MULE_IF_ENABLED_ANY([monolithic, amule-daemon, amule-gui, amulecmd, webserver, alc, alcc, wxcas, fileview],
 166         [WX_CONFIG_OPTIONS
 167         WX_STANDARD_OPTIONS([toolkit,wxshared,wxdebug,wxversion])
 168         # Force using a static wxWidgets library if the executable is to be linked statically.
 169         MULE_IF_ENABLED([static], [WX_SHARED=0])
 170         # Force using a unicode build of the library
 171         MULE_IF_ENABLED_ANY([monolithic, amule-daemon, amule-gui, amulecmd, webserver, fileview], [WX_UNICODE=1])
 172         DEBUG=$WX_DEBUG
 173         WX_CONVERT_STANDARD_OPTIONS_TO_WXCONFIG_FLAGS
 174         WX_CONFIG_CHECK([2.8.12], [wxWin=1],,, [$WXCONFIG_FLAGS])
 175         AS_IF([test "$wxWin" != 1],
 176                 [AC_MSG_ERROR([
 177                 wxWidgets must be installed on your system but wx-config
 178                 script couldn't be found. Please check that wx-config is
 179                 in path or specified by --with-wx-config=path flag, the
 180                 directory where wxWidgets libraries are installed (returned
 181                 by 'wx-config --libs' command) is in LD_LIBRARY_PATH or
 182                 equivalent variable and wxWidgets version is 2.8.12 or above.
 183                 ])]
 184         )
 185         AS_IF([test "${WX_VERSION_FULL}" = "2.9.0"], [AC_MSG_ERROR([
 186                 This version of wxWidgets is known to not work with aMule.
 187                 Please upgrade to a newer version.]
 188                 )]
 189         )
 190         WX_DETECT_STANDARD_OPTION_VALUES
 191
 192         # We also need wxBase
 193         WX_LIBS=`$WX_CONFIG_WITH_ARGS --libs adv,core,net`
 194         WXBASE_LIBS=`$WX_CONFIG_WITH_ARGS --libs net`
 195         WXBASE_CPPFLAGS="$WX_CPPFLAGS -DwxUSE_GUI=0"
 196
 197         MULERCFLAGS=`$WX_CONFIG_WITH_ARGS --cflags | $AWK ['{ for (i = 1; i <= NF; i++) if (index($i, "-I") != 1 && index($i, "-D") != 1) $i = ""; print }']`
 198 ])
 199 AC_SUBST([WXBASE_LIBS])dnl
 200 AC_SUBST([WXBASE_CPPFLAGS])dnl
 201
 202 MULE_IF_ENABLED_ANY([monolithic, amule-gui, wxcas, alc],
 203 [AS_IF([test "${WX_PORT}" = base],
 204         [AC_MSG_ERROR([
 205                 The selected components need a wxWidgets library with GUI,
 206                 but your installation is base-only.  Please install a GUI
 207                 enabled version of wxWidgets and then retry.
 208         ])]
 209 )])
 210
 211
 212 dnl Resource compiler for W32
 213 AC_ARG_VAR([RC], [Resource Compiler])dnl
 214 AC_ARG_VAR([RCFLAGS], [Resource Compiler Flags])dnl
 215 AS_IF([test ${SYS:-unknown} = win32], [AC_CHECK_TOOL([RC], [windres], [:])])
 216
 217
 218 # Check for libupnp
 219 MULE_ARG_ENABLE([upnp], [yes], [do not compile UPnP code])
 220 MULE_IF_ENABLED_ANY([monolithic, amule-daemon],, [MULE_ENABLEVAR([upnp])=no])
 221 MULE_IF_ENABLED([upnp], [
 222         LIBUPNP_CHECK(
 223                 [1.6.6],
 224                 [MULE_APPEND([LIBUPNP_CPPFLAGS], [-DENABLE_UPNP=1])],
 225                 [MULE_ENABLEVAR([upnp])=disabled
 226                 MULE_WARNING([UPnP code has been disabled because ${libupnp_error}.])]
 227         )
 228 ])dnl
 229
 230
 231 # Check for Crypto++ (requires C++)
 232 MULE_IF_ENABLED_ANY([monolithic, amule-daemon, amule-gui, fileview],
 233 [MULE_CHECK_CRYPTOPP([5.1], [
 234         # Check for CryptoPP >= 5.5
 235         AS_IF([test $CRYPTOPP_VERSION_NUMBER -ge "5005000"], [MULE_APPEND([CRYPTOPP_CPPFLAGS], [-D__WEAK_CRYPTO__])])
 236 ], [
 237         AC_MSG_ERROR([
 238         Could not find crypto++ installation or sources.
 239         Please try again with --with-crypto-prefix=/my_crypto_prefix
 240         (replace /my_crypto_prefix with a valid path to your crypto++
 241         installation or source directory).])
 242 ])])
 243
 244
 245 MULE_COMPILATION_FLAGS
 246
 247
 248 dnl Checks explicitly requiring C++
 249 MULE_IF_ENABLED_ANY([monolithic, amule-daemon, amule-gui, amulecmd, webserver, ed2k, alc, alcc, wxcas, fileview],
 250 [
 251 dnl MULE_CHECK_GLIBCXX
 252 MULE_CHECK_STRICT_ALIASING
 253 MULE_IF_ENABLED_ANY([monolithic, amule-daemon, alc, alcc], [MULE_CHECK_WX_SUPPORTS_LARGEFILE])
 254
 255 # Check if the compiler is broken, wrt. exceptions.
 256 MULE_CHECK_EXCEPTIONS
 257
 258 MULE_CHECK_CXXABI
 259
 260 MULE_IF_ENABLED_ANY([monolithic, amule-daemon, amule-gui, amulecmd, webserver], [MULE_CHECK_BOOST([1.47])])
 261 ])
 262
 263 # Ok, we have all needed libs, now checking for other stuff
 264 AS_IF([test "$LEX" = "flex"], [MULE_CHECK_FLEX_EXTENDED], [HAVE_FLEX_EXTENDED=no])
 265
 266
 267 # Checks for header files.
 268 AC_FUNC_ALLOCA
 269 AC_HEADER_DIRENT
 270 AC_HEADER_STDC
 271 AC_CHECK_HEADERS([argz.h arpa/inet.h errno.h fcntl.h inttypes.h langinfo.h libintl.h limits.h locale.h malloc.h mntent.h netdb.h netinet/in.h stddef.h nl_types.h signal.h stdint.h stdio_ext.h stdlib.h string.h strings.h sys/ioctl.h sys/mntent.h sys/mnttab.h sys/mount.h sys/param.h sys/resource.h sys/select.h sys/socket.h sys/statvfs.h sys/time.h sys/timeb.h sys/types.h unistd.h])
 272 AC_HEADER_SYS_WAIT
 273
 274
 275 # Checks for typedefs, structures, and compiler characteristics.
 276 AC_TYPE_MODE_T
 277 AC_TYPE_OFF_T
 278 AC_TYPE_SIZE_T
 279 AC_HEADER_TIME
 280 AC_STRUCT_TM
 281 AC_TYPE_UID_T
 282 AC_CHECK_TYPES([ptrdiff_t])
 283
 284
 285 # Checks for library functions.
 286 AC_FUNC_CLOSEDIR_VOID
 287 AC_PROG_GCC_TRADITIONAL
 288 AC_FUNC_FORK
 289 AS_IF([test x$SYS != xwin32], [
 290         AC_FUNC_GETMNTENT
 291         AC_FUNC_LSTAT
 292         AC_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK
 293 ])
 294 AC_FUNC_MEMCMP
 295 AC_FUNC_SELECT_ARGTYPES
 296 AC_FUNC_SETVBUF_REVERSED
 297 AC_TYPE_SIGNAL
 298 AC_FUNC_STAT
 299 AC_FUNC_STRFTIME
 300 AC_FUNC_STRTOD
 301 AC_FUNC_VPRINTF
 302 dnl Some other functions that worth checking deeper:
 303 dnl AC_FUNC_CLOSEDIR_VOID
 304 dnl AC_FUNC_MEMCMP
 305 dnl AC_FUNC_MMAP
 306 dnl AC_FUNC_STAT
 307 dnl AC_FUNC_STRTOD
 308 dnl AC_FUNC_SETVBUF_REVERSED
 309 dnl Anyways, do we actually USE them?
 310 AS_IF([test $cross_compiling = yes -a $gnumalloc = yes], [
 311         MULE_WARNING([configure cannot check whether malloc() and realloc() are GNU libc compatible. You have to be ABSOLUTELY sure that they are, otherwise run configure with the --without-gnu-malloc switch.])
 312         ac_cv_func_malloc_0_nonnull=yes
 313         ac_cv_func_realloc_0_nonnull=yes
 314 ])
 315 AC_FUNC_MALLOC
 316 AC_FUNC_REALLOC
 317 AC_CHECK_FUNCS([__argz_count __argz_next __argz_stringify endpwent floor ftruncate getcwd gethostbyaddr gethostbyname gethostname getopt_long getpass getrlimit gettimeofday inet_ntoa localeconv memmove mempcpy memset mkdir nl_langinfo pow select setlocale setrlimit sigaction socket sqrt stpcpy strcasecmp strchr strcspn strdup strerror strncasecmp strstr strtoul])
 318
 319
 320 dnl This must be *before* MULE_CHECK_NLS
 321 MULE_IF_ENABLED_ANY([monolithic, amule-daemon], [MULE_CHECK_MMAP])
 322
 323
 324 # Look for a way to preallocate disk space for files.
 325 MULE_IF_ENABLED_ANY([monolithic, amule-daemon], [MULE_CHECK_FALLOCATE])
 326
 327
 328 dnl Use the C compiler for the gettext library checks
 329 AC_LANG_POP([C++])
 330 # Checking Native Language Support
 331 dnl Sets gettext version.
 332 dnl AM_GNU_GETTEXT_VERSION *must not* be moved away from configure.in!
 333 AM_GNU_GETTEXT_VERSION(0.11.5)
 334 MULE_CHECK_NLS
 335 AC_LANG_PUSH([C++])
 336
 337
 338 # Check for bfd.h (to have proper backtraces without using wxExecute)
 339 dnl This must be *after* MULE_CHECK_NLS
 340 MULE_CHECK_BFD
 341 MULE_CHECK_EXECINFO
 342
 343
 344 # aMule plasma widget
 345 MULE_IF_ENABLED([plasmamule], [PLASMAMULE_CHECKS])
 346
 347
 348 # Check for readline library
 349 MULE_IF_ENABLED_ANY([amulecmd, webserver], [VL_LIB_READLINE])
 350
 351
 352 dnl Tests that should be run in C mode. These tests either test features of the
 353 dnl C compiler or their results will be used in C sources only.
 354 AC_LANG_POP([C++])
 355
 356 # Check for strerror_r
 357 MULE_BACKUP([CPPFLAGS])
 358 MULE_APPEND([CPPFLAGS], [-D_XOPEN_SOURCE=600])
 359 AC_FUNC_STRERROR_R
 360 MULE_RESTORE([CPPFLAGS])
 361
 362
 363 # Other tests
 364
 365 # autoconf >= 2.60 already defines ${docdir}, but we always need it.
 366 AC_MSG_CHECKING([for docdir])
 367 AS_IF([test -z "$docdir"], [docdir="${datadir}/doc/${PACKAGE_NAME}-${PACKAGE_VERSION}"])
 368 AC_SUBST([docdir])dnl
 369 AC_MSG_RESULT([$docdir])
 370
 371
 372 # Try to set the SVN checkout-date
 373 AC_MSG_CHECKING([for SVNDATE])
 374 modified=
 375 MULE_IF(
 376 dnl SVNDATE for tarballs
 377 [test -f "$srcdir/.svn-revision"],
 378         [svndate="rev. `cat $srcdir/.svn-revision`"],
 379
 380 dnl SVNDATE for Subversion checkouts
 381 [test -d "$srcdir"/.svn],
 382         [svndate="rev. `svnversion "$srcdir" | ${SED} -e 'h;s/[[0-9]][[0-9]]*:\(.*\)/\1/;s/\([[0-9]][[0-9]]*\).*/\1/;x;/.*M.*/{x;s/$/+/;b;};x'`"],
 383
 384 dnl SVNDATE for git/git-svn clones
 385 [test -d "$srcdir"/.git],
 386 [
 387         git_revision=`git --git-dir="$srcdir"/.git log --max-count=1 --pretty='tformat:%h'`
 388         if test -n "`git --git-dir="$srcdir"/.git --work-tree="$srcdir" status --porcelain --untracked-files=no`" ; then
 389                 modified="+"
 390         fi
 391         if test -f $srcdir/.git/svn/.metadata ; then
 392                 git_sha=`git --git-dir="$srcdir"/.git log --max-count=1 --pretty='tformat:%H'`
 393                 svndate=`git --git-dir="$srcdir"/.git rev-list ${git_sha} | while read sha; do
 394                         svn_revision=\`git --git-dir="$srcdir"/.git svn find-rev \${sha}\`
 395                         if test -n "\${svn_revision}" ; then
 396                                 if test \${sha} = ${git_sha} ; then
 397                                         echo "rev. \${svn_revision}${modified}"
 398                                 else
 399                                         echo "rev. \${svn_revision}+g${git_revision}${modified}"
 400                                 fi
 401                                 break
 402                         fi
 403                 done`
 404         else
 405                 svndate="rev. g${git_revision}${modified}"
 406         fi
 407 ],
 408
 409 dnl SVNDATE for mercurial/hgsubversion clones
 410 [test -d "$srcdir"/.hg],
 411 [
 412         hg_revision=`hg --cwd "$srcdir" identify --id`
 413         hg_revid=${hg_revision%+}
 414         if test ${hg_revision} != ${hg_revid} ; then
 415                 modified="+"
 416         fi
 417         if test -f "$srcdir"/.hg/svn/uuid ; then
 418                 svndate=`hg --cwd "$srcdir" log --follow --template='r{svnrev} {node|short}\n' | while read svn_revision hg_sha; do
 419                         if test \${svn_revision} != r ; then
 420                                 if test \${hg_sha} = ${hg_revid} ; then
 421                                         echo "rev. \${svn_revision#r}${modified}"
 422                                 else
 423                                         echo "rev. \${svn_revision#r}+h${hg_revision}"
 424                                 fi
 425                                 break
 426                         fi
 427                 done`
 428         else
 429                 svndate="rev. h${hg_revision}"
 430         fi
 431 ])
 432
 433 AC_MSG_RESULT(${svndate:-None required})
 434 AS_IF([test -n "$svndate"], [
 435             AC_DEFINE_UNQUOTED([SVNDATE], ["$svndate"], [The checkout date or svn revision number.])
 436             MULE_ADDFLAG([RC], [-D__PRERELEASE__])
 437 ])
 438 AC_SUBST([SVNDATE], [$svndate])dnl
 439
 440
 441 dnl Set up the denoiser
 442 MULE_DENOISER
 443
 444
 445 # DO NOT MOVE UP... THERE'S A REASON TO BE HERE!!
 446 MULE_CHECK_CCACHE
 447
 448
 449 dnl ---------------------------------------------------------------------------
 450 dnl End of checks, now write the results and report
 451 dnl ---------------------------------------------------------------------------
 452
 453 AM_CONDITIONAL(SYS_WIN32, test x$SYS = xwin32)
 454 AM_CONDITIONAL(NEED_RC, test x$SYS = xwin32 -a "$RC" != ":")
 455 AM_CONDITIONAL(NEED_CORESERVICES, test x$SYS = xdarwin)
 456 AM_CONDITIONAL(COMPILE_NLS, test x$USE_NLS = xyes)
 457 AM_CONDITIONAL(GENERATE_FLEX_HEADER, test x$HAVE_FLEX_EXTENDED = xyes)
 458 AM_CONDITIONAL(INSTALL_SKINS, test MULE_IS_ENABLED_ANY([monolithic, amule-gui]))
 459 AM_CONDITIONAL(PLASMAMULE, test MULE_IS_ENABLED([plasmamule]))
 460
 461 AM_CONDITIONAL([COMPILE_LIB_COMMON],    [test MULE_IS_ENABLED_ANY([monolithic, amule-daemon, amulecmd, webserver, amule-gui, fileview])])
 462 AM_CONDITIONAL([COMPILE_LIB_EC],        [test MULE_IS_ENABLED_ANY([monolithic, amule-daemon, amulecmd, webserver, amule-gui])])
 463
 464 dnl Generate the Makefiles
 465 AC_CONFIG_FILES([Makefile
 466                  docs/Makefile
 467                  docs/man/Makefile
 468                  intl/Makefile
 469                  po/Makefile.in
 470                  src/Makefile
 471                  src/pixmaps/Makefile
 472                  src/pixmaps/flags_xpm/Makefile
 473                  src/libs/Makefile
 474                  src/libs/ec/Makefile
 475                  src/libs/ec/cpp/Makefile
 476                  src/libs/common/Makefile
 477                  src/utils/Makefile
 478                  src/utils/aLinkCreator/Makefile
 479                  src/utils/aLinkCreator/docs/Makefile
 480                  src/utils/aLinkCreator/src/Makefile
 481                  src/utils/cas/Makefile
 482                  src/utils/cas/docs/Makefile
 483                  src/utils/fileview/Makefile
 484                  src/utils/plasmamule/Makefile
 485                  src/utils/wxCas/Makefile
 486                  src/utils/wxCas/docs/Makefile
 487                  src/utils/wxCas/src/Makefile
 488                  src/utils/xas/Makefile
 489                  src/utils/xas/autostart-xas
 490                  src/utils/xas/docs/Makefile
 491                  src/skins/Makefile
 492                  src/webserver/Makefile
 493                  src/webserver/src/Makefile
 494                  src/webserver/default/Makefile
 495                  unittests/Makefile
 496                  unittests/muleunit/Makefile
 497                  unittests/tests/Makefile])
 498
 499 AS_IF([test x$SYS = xwin32], [AC_CONFIG_FILES([version.rc])])
 500 AC_OUTPUT
 501
 502 AS_IF([test -n "$svndate"], [SVN_REVISION=" ($svndate)"], [SVN_REVISION=])
 503
 504 echo
 505 echo
 506 echo "  Configure script has finished system check."
 507 echo
 508 echo "  Configured aMule ${PACKAGE_VERSION}${SVN_REVISION} for '${host}'."
 509 echo
 510 echo "  aMule enabled options:"
 511 echo
 512 echo "  **** aMule Core ****"
 513 echo "  Prefix where aMule should be installed?                    ${prefix:-none}"
 514 echo "  Should aMule be compiled with i18n support?                ${USE_NLS:-no}"
 515 echo "  Should aMule be compiled in debug mode?                    MULE_STATUSOF([debug])"
 516 echo "  Should aMule be compiled with profiling?                   MULE_STATUSOF([profile])"
 517 echo "  Should aMule be compiled with optimizations?               MULE_STATUSOF([optimize])"
 518 echo "  Should aMule be compiled with UPnP support?                MULE_STATUSOF([upnp])"
 519 echo "  Should aMule be compiled with IP2country support?          MULE_STATUSOF([geoip])"
 520 echo "  Should aMule monolithic application be built?              MULE_STATUSOF([monolithic])"
 521 echo "  Should aMule daemon version be built?                      MULE_STATUSOF([amule-daemon])"
 522 echo "  Should aMule remote gui be built?                          MULE_STATUSOF([amule-gui])"
 523
 524 echo
 525 echo "  **** aMule TextClient ****"
 526 echo "  Should aMule Command Line Client be built?                 MULE_STATUSOF([amulecmd])"
 527 echo
 528 echo "  **** aMule WebServer ****"
 529 echo "  Should aMule WebServer be built?                           MULE_STATUSOF([webserver])"
 530 echo
 531 echo "  **** aMule ED2K Links Handler ****"
 532 echo "  Should aMule ED2K Links Handler be built?                  MULE_STATUSOF([ed2k])"
 533 echo
 534 echo "  **** aMuleLinkCreator ****"
 535 echo "  Should aMuleLinkCreator GUI version (alc) be built?        MULE_STATUSOF([alc])"
 536 echo "  Should aMuleLinkCreator for console (alcc) be built?       MULE_STATUSOF([alcc])"
 537 echo
 538 echo "  **** aMule Statistics ****"
 539 echo "  Should C aMule Statistics (CAS) be built?                  MULE_STATUSOF([cas])"
 540 echo "  Should aMule GUI Statistics (wxCas) be built?              MULE_STATUSOF([wxcas])"
 541 echo "  Should xas XChat2 plugin be installed?                     MULE_STATUSOF([xas])"
 542 echo "  Should plasmaMule plasma-applet be build?                  MULE_STATUSOF([plasmamule])"
 543
 544 echo
 545 echo "  **** General Libraries and Tools ****"
 546 echo "  Should ccache support be enabled?                          MULE_STATUSOF([ccache])"
 547 echo "  Libraries aMule will use to build:"
 548 MULE_IF_ENABLED_ANY([monolithic, amule-daemon, amule-gui, amulecmd, webserver, alc, alcc, wxcas, fileview], [
 549         wxinfo="$WX_PORT"
 550         AS_IF([test $WX_DEBUG -eq 1], [wxinfo="$wxinfo,debug"])
 551         AS_IF([test $WX_SHARED -eq 1], [wxinfo="$wxinfo,shared"], [wxinfo="$wxinfo,static"])
 552         echo "                             wxWidgets             ${WX_VERSION_FULL} ($wxinfo)"
 553 ])
 554 AS_IF([test ${with_boost:-no} != no],
 555 [MULE_IF(
 556         [test ${with_boost:-no} = disabled],
 557                 [echo "                             boost                 Not detected"],
 558         [test ${boost_cv_inc_path:-yes} != yes],
 559                 [echo "                             boost                 `echo ${boost_cv_lib_version} | sed -e 's/_/./g'` (in ${boost_cv_inc_path})"],
 560                 [echo "                             boost                 `echo ${boost_cv_lib_version} | sed -e 's/_/./g'`"],
 561 )])
 562 MULE_IF_ENABLED_ANY([monolithic, amule-daemon, amule-gui, fileview],
 563         [echo "                             crypto++              ${CRYPTOPP_VERSION_STRING} (in ${CRYPTOPP_PREFIX})"])
 564 MULE_IF_ENABLED([upnp], [
 565         AS_IF([test -n "$with_libupnp_prefix"], [libupnp_place=" (in $with_libupnp_prefix)"])
 566         echo "                             libupnp               ${LIBUPNP_VERSION:-Not detected}${libupnp_place:-}"
 567 ])
 568 if test ${enable_nls:-yes} = yes; then
 569 AS_IF([test x$USE_NLS = xno],
 570         [libintl_found="Not detected"],
 571         [AS_IF([test x$USE_INCLUDED_LIBINTL = xyes],
 572                 [libintl_found="included"],
 573                 [libintl_found="system"])])
 574 echo "                             libintl               $libintl_found"
 575 fi
 576 MULE_IF_ENABLED([geoip],
 577         [AS_IF([test -z "${with_geoip_headers:-}${with_geoip_lib:-}"], [geoip_style=system], [geoip_style=user])
 578         MULE_IF_ENABLED_ANY([monolithic, amule-gui],
 579                 [echo "                             libGeoIP              ${geoip_style}"])])
 580 MULE_IF_ENABLED([webserver],
 581         [echo "                             libpng                ${LIBPNG_VERSION:-Not detected}"])
 582 MULE_IF_ENABLED([cas],
 583         [echo "                             libgd                 ${GDLIB_VERSION:-Not detected}"])
 584 MULE_IF_ENABLED_ANY([monolithic, amule-daemon, amulecmd, webserver, amule-gui],
 585         [echo "                             zlib                  ${ZLIB_VERSION:-Not detected}"])
 586 MULE_IF_ENABLED([plasmamule],
 587 [echo "                             qt-moc                ${QT_MOC} ${QT_MOC_VERSION}"
 588 echo "                             qt-core-libs          ${QT_CORE_LIBS}"
 589 echo "                             qt-gui-libs           ${QT_GUI_LIBS}"
 590 echo "                             kde4-config           ${KDE4_CONFIG} (${KDE_CONF_VER})"
 591 echo "                             kde-headers           ${KDE_HEADER_DIR}"
 592 echo "                             kde-services-path     ${KDE_SERVICE_PATH}"
 593 echo "                             kde-module-path       ${KDE_MODULE_PATH}"
 594 echo "                             kde-icon-path         ${KDE_ICON_PATH}"
 595 echo "                             kde-mime-path         ${KDE_MIME_PATH}"
 596 echo "                             kde-applinks-path     ${KDE_APPLNK_PATH}"
 597 ])