Data/Floating/Classes.hs

   1 {-
   2  - Copyright (C) 2009-2010 Nick Bowler.
   3  -
   4  - License BSD2:  2-clause BSD license.  See LICENSE for full terms.
   5  - This is free software: you are free to change and redistribute it.
   6  - There is NO WARRANTY, to the extent permitted by law.
   7  -}
   8
   9 -- | Generic classes for floating point types.  The interface is loosely based
  10 -- off of the C math library.
  11 module Data.Floating.Classes where
  12
  13 import Prelude hiding (Floating(..), RealFloat(..), RealFrac(..), Ord(..))
  14 import Data.Ratio
  15 import Data.Poset
  16
  17 -- | Classification of floating point values.
  18 data FPClassification = FPInfinite | FPNaN | FPNormal | FPSubNormal | FPZero
  19     deriving (Show, Read, Eq, Enum, Bounded)
  20
  21 -- | Class for types which can be rounded to integers.  The rounding functions
  22 -- in the Prelude are inadequate for floating point because they shoehorn their
  23 -- results into an integral type.
  24 --
  25 -- Minimal complete definition: 'toIntegral' and 'round'.
  26 class (Fractional a, Poset a) => Roundable a where
  27     -- | Discards the fractional component from a value.  Results in 'Nothing'
  28     -- if the result cannot be represented as an integer, such as if the input
  29     -- is infinite or NaN.
  30     toIntegral :: Integral b => a -> Maybe b
  31     ceiling    :: a -> a
  32     floor      :: a -> a
  33     truncate   :: a -> a
  34     round      :: a -> a
  35
  36     floor x
  37         | round x == x = x
  38         | otherwise = round $ x - fromRational (1%2)
  39     ceiling x
  40         | round x == x = x
  41         | otherwise = round $ x + fromRational (1%2)
  42     truncate x
  43         | x < 0 = ceiling x
  44         | x > 0 = floor x
  45         | otherwise = x
  46
  47 -- | Class for floating point types (real or complex-valued).
  48 --
  49 -- Minimal complete definition: everything.
  50 class Fractional a => Floating a where
  51     (**)  :: a -> a -> a
  52     sqrt  :: a -> a
  53     acos  :: a -> a
  54     asin  :: a -> a
  55     atan  :: a -> a
  56     cos   :: a -> a
  57     sin   :: a -> a
  58     tan   :: a -> a
  59     acosh :: a -> a
  60     asinh :: a -> a
  61     atanh :: a -> a
  62     cosh  :: a -> a
  63     sinh  :: a -> a
  64     tanh  :: a -> a
  65     exp   :: a -> a
  66     log   :: a -> a
  67
  68 -- | Class for real-valued floating point types.
  69 --
  70 -- Minimal complete definition: all except 'pi', 'infinity' and 'nan'.
  71 class Floating a => RealFloat a where
  72     fma       :: a -> a -> a -> a
  73     copysign  :: a -> a -> a
  74     nextafter :: a -> a -> a
  75     atan2     :: a -> a -> a
  76     fmod      :: a -> a -> a
  77     frem      :: a -> a -> a
  78     fquotRem  :: a -> a -> (Int, a)
  79     hypot     :: a -> a -> a
  80     cbrt      :: a -> a
  81     exp2      :: a -> a
  82     expm1     :: a -> a
  83     log10     :: a -> a
  84     log1p     :: a -> a
  85     log2      :: a -> a
  86     logb      :: a -> a
  87     erf       :: a -> a
  88     erfc      :: a -> a
  89     lgamma    :: a -> a
  90     tgamma    :: a -> a
  91     nearbyint :: a -> a
  92     classify  :: a -> FPClassification
  93     infinity  :: a
  94     nan       :: a
  95     pi        :: a
  96
  97     infinity = 1/0
  98     nan      = 0/0
  99     pi       = 4 * atan 1